1 | ; Project name : XTIDE Universal BIOS |
---|
2 | ; Description : Functions for creating Disk Parameter Table. |
---|
3 | |
---|
4 | ; |
---|
5 | ; XTIDE Universal BIOS and Associated Tools |
---|
6 | ; Copyright (C) 2009-2010 by Tomi Tilli, 2011-2013 by XTIDE Universal BIOS Team. |
---|
7 | ; |
---|
8 | ; This program is free software; you can redistribute it and/or modify |
---|
9 | ; it under the terms of the GNU General Public License as published by |
---|
10 | ; the Free Software Foundation; either version 2 of the License, or |
---|
11 | ; (at your option) any later version. |
---|
12 | ; |
---|
13 | ; This program is distributed in the hope that it will be useful, |
---|
14 | ; but WITHOUT ANY WARRANTY; without even the implied warranty of |
---|
15 | ; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
---|
16 | ; GNU General Public License for more details. |
---|
17 | ; Visit http://www.gnu.org/licenses/old-licenses/gpl-2.0.html |
---|
18 | ; |
---|
19 | |
---|
20 | ; Section containing code |
---|
21 | SECTION .text |
---|
22 | |
---|
23 | ;-------------------------------------------------------------------- |
---|
24 | ; Creates new Disk Parameter Table for detected hard disk. |
---|
25 | ; Drive is then fully accessible using any BIOS function. |
---|
26 | ; |
---|
27 | ; CreateDPT_FromAtaInformation |
---|
28 | ; Parameters: |
---|
29 | ; BH: Drive Select byte for Drive and Head Register |
---|
30 | ; DX: Autodetected port (for devices that support autodetection) |
---|
31 | ; ES:SI: Ptr to 512-byte ATA information read from the drive |
---|
32 | ; CS:BP: Ptr to IDEVARS for the controller |
---|
33 | ; DS: RAMVARS segment |
---|
34 | ; ES: BDA Segment |
---|
35 | ; Returns: |
---|
36 | ; DS:DI: Ptr to Disk Parameter Table (if successful) |
---|
37 | ; CF: Cleared if DPT created successfully |
---|
38 | ; Set if any error |
---|
39 | ; Corrupts registers: |
---|
40 | ; AX, BX, CX, DH |
---|
41 | ;-------------------------------------------------------------------- |
---|
42 | CreateDPT_FromAtaInformation: |
---|
43 | call FindDPT_ForNewDriveToDSDI |
---|
44 | ; Fall to .InitializeDPT |
---|
45 | |
---|
46 | ;-------------------------------------------------------------------- |
---|
47 | ; .InitializeDPT |
---|
48 | ; Parameters: |
---|
49 | ; BH: Drive Select byte for Drive and Head Register |
---|
50 | ; DX: Autodetected port (for devices that support autodetection) |
---|
51 | ; DS:DI: Ptr to Disk Parameter Table |
---|
52 | ; CS:BP: Ptr to IDEVARS for the controller |
---|
53 | ; Returns: |
---|
54 | ; Nothing |
---|
55 | ; Corrupts registers: |
---|
56 | ; AX |
---|
57 | ;-------------------------------------------------------------------- |
---|
58 | .InitializeDPT: |
---|
59 | call CreateDPT_StoreIdevarsOffsetAndBasePortFromCSBPtoDPTinDSDI |
---|
60 | ; Fall to .StoreDriveSelectAndDriveControlByte |
---|
61 | |
---|
62 | ;-------------------------------------------------------------------- |
---|
63 | ; .StoreDriveSelectAndDriveControlByte |
---|
64 | ; Parameters: |
---|
65 | ; BH: Drive Select byte for Drive and Head Register |
---|
66 | ; DS:DI: Ptr to Disk Parameter Table |
---|
67 | ; ES:SI: Ptr to 512-byte ATA information read from the drive |
---|
68 | ; CS:BP: Ptr to IDEVARS for the controller |
---|
69 | ; Returns: |
---|
70 | ; Nothing |
---|
71 | ; Corrupts registers: |
---|
72 | ; AX |
---|
73 | ;-------------------------------------------------------------------- |
---|
74 | .StoreDriveSelectAndDriveControlByte: |
---|
75 | mov al, bh |
---|
76 | and ax, BYTE FLG_DRVNHEAD_DRV ; AL now has Master/Slave bit |
---|
77 | %ifdef MODULE_IRQ |
---|
78 | cmp [cs:bp+IDEVARS.bIRQ], ah ; Interrupts enabled? |
---|
79 | jz SHORT .StoreFlags ; If not, do not set interrupt flag |
---|
80 | or al, FLGL_DPT_ENABLE_IRQ |
---|
81 | .StoreFlags: |
---|
82 | %endif |
---|
83 | mov [di+DPT.wFlags], ax |
---|
84 | ; Fall to .StoreCHSparametersAndAddressingMode |
---|
85 | |
---|
86 | ;-------------------------------------------------------------------- |
---|
87 | ; .StoreCHSparametersAndAddressingMode |
---|
88 | ; Parameters: |
---|
89 | ; DS:DI: Ptr to Disk Parameter Table |
---|
90 | ; ES:SI: Ptr to 512-byte ATA information read from the drive |
---|
91 | ; CS:BP: Ptr to IDEVARS for the controller |
---|
92 | ; Returns: |
---|
93 | ; Nothing |
---|
94 | ; Corrupts registers: |
---|
95 | ; AX, BX, CX, DX |
---|
96 | ;-------------------------------------------------------------------- |
---|
97 | .StoreCHSparametersAndAddressingMode: |
---|
98 | ; Check if CHS defined in ROMVARS |
---|
99 | call GetUserDefinedCapacityToBXAXandFlagsToCXandModeToDXfromROMVARS |
---|
100 | test cl, FLG_DRVPARAMS_USERCHS |
---|
101 | jz SHORT .AutodetectPCHSvalues |
---|
102 | |
---|
103 | ; Translate P-CHS to L-CHS |
---|
104 | call AtaGeometry_GetLCHStoAXBLBHfromPCHSinAXBLBHandTranslateModeInDX |
---|
105 | jmp SHORT .StoreLCHStoDPT |
---|
106 | .AutodetectPCHSvalues: |
---|
107 | call AtaGeometry_GetLCHStoAXBLBHfromAtaInfoInESSIandTranslateModeInDX |
---|
108 | |
---|
109 | .StoreLCHStoDPT: |
---|
110 | eSHL_IM dl, TRANSLATEMODE_FIELD_POSITION |
---|
111 | or cl, dl |
---|
112 | or [di+DPT.bFlagsLow], cl ; Shift count and addressing mode |
---|
113 | mov [di+DPT.wLchsCylinders], ax |
---|
114 | mov [di+DPT.wLchsHeadsAndSectors], bx |
---|
115 | |
---|
116 | ; Store P-CHS to DPT |
---|
117 | call AtaGeometry_GetPCHStoAXBLBHfromAtaInfoInESSI |
---|
118 | mov [di+DPT.bPchsHeads], bl |
---|
119 | %ifdef MODULE_EBIOS |
---|
120 | mov [di+DPT.bPchsSectorsPerTrack], bh |
---|
121 | |
---|
122 | ; This is what Award BIOS from 1997 Pentium motherboard does. I can't think |
---|
123 | ; of any good reason to do the same but let's keep this here just in case, |
---|
124 | ; at least for a while. |
---|
125 | %if 0 |
---|
126 | %ifdef RESERVE_DIAGNOSTIC_CYLINDER |
---|
127 | ; Do not store P-Cylinders, instead calculate it from L-CHS total sector count. |
---|
128 | ; Read AH=48h_GetExtendedDriveParameters.asm for more info. |
---|
129 | xchg ax, bx |
---|
130 | mul ah |
---|
131 | push ax ; P-Heads * P-Sectors per track |
---|
132 | call AH15h_GetSectorCountToBXDXAX |
---|
133 | pop bx |
---|
134 | div bx ; AX = Calculated cylinders |
---|
135 | %endif ; RESERVE_DIAGNOSTIC_CYLINDER |
---|
136 | %endif ; 0 |
---|
137 | |
---|
138 | mov [di+DPT.wPchsCylinders], ax |
---|
139 | ; Fall to .StoreNumberOfLbaSectors |
---|
140 | |
---|
141 | ;-------------------------------------------------------------------- |
---|
142 | ; .StoreNumberOfLbaSectors |
---|
143 | ; Parameters: |
---|
144 | ; DS:DI: Ptr to Disk Parameter Table |
---|
145 | ; ES:SI: Ptr to 512-byte ATA information read from the drive |
---|
146 | ; CS:BP: Ptr to IDEVARS for the controller |
---|
147 | ; Returns: |
---|
148 | ; Nothing |
---|
149 | ; Corrupts registers: |
---|
150 | ; AX, BX, CX, DX |
---|
151 | ;-------------------------------------------------------------------- |
---|
152 | ; Check if LBA supported |
---|
153 | test BYTE [es:si+ATA1.wCaps+1], A1_wCaps_LBA>>8 |
---|
154 | jz SHORT .NoLbaSupportedSoNoEBIOS |
---|
155 | |
---|
156 | ; Store LBA 28/48 total sector count |
---|
157 | call AtaGeometry_GetLbaSectorCountToBXDXAXfromAtaInfoInESSI |
---|
158 | call StoreLba48AddressingFromCLandTotalSectorCountFromBXDXAX |
---|
159 | |
---|
160 | ; If we have 15,482,880 or less sectors, we multiply P-CHS values |
---|
161 | ; and use that as total sector count. |
---|
162 | ; Read AH=48h_GetExtendedDriveParameters.asm for more info. |
---|
163 | sub ax, 4001h |
---|
164 | sbb dx, 0ECh |
---|
165 | sbb bx, BYTE 0 |
---|
166 | jnc SHORT .NoNeedToUseCHSsectorCount ; More than EC4000h |
---|
167 | |
---|
168 | mov al, [di+DPT.bPchsHeads] |
---|
169 | mul BYTE [di+DPT.bPchsSectorsPerTrack] |
---|
170 | mul WORD [di+DPT.wPchsCylinders] |
---|
171 | xor bx, bx |
---|
172 | call StoreLba48AddressingFromCLandTotalSectorCountFromBXDXAX |
---|
173 | |
---|
174 | ; Load user defined LBA |
---|
175 | .NoNeedToUseCHSsectorCount: |
---|
176 | call GetUserDefinedCapacityToBXAXandFlagsToCXandModeToDXfromROMVARS |
---|
177 | test cl, FLG_DRVPARAMS_USERLBA |
---|
178 | jz SHORT .KeepTotalSectorsFromAtaID |
---|
179 | |
---|
180 | ; Compare user defined and ATA-ID sector count and select smaller |
---|
181 | mov dx, bx |
---|
182 | xor bx, bx ; User defined LBA now in BX:DX:AX |
---|
183 | cmp bx, [di+DPT.twLbaSectors+4] |
---|
184 | jb SHORT .StoreUserDefinedSectorCountToDPT |
---|
185 | cmp dx, [di+DPT.twLbaSectors+2] |
---|
186 | jb SHORT .StoreUserDefinedSectorCountToDPT |
---|
187 | ja SHORT .KeepTotalSectorsFromAtaID |
---|
188 | cmp ax, [di+DPT.twLbaSectors] |
---|
189 | jae SHORT .KeepTotalSectorsFromAtaID |
---|
190 | .StoreUserDefinedSectorCountToDPT: |
---|
191 | ; CL bit FLGL_DPT_LBA48 is clear at this point |
---|
192 | call StoreLba48AddressingFromCLandTotalSectorCountFromBXDXAX |
---|
193 | |
---|
194 | .KeepTotalSectorsFromAtaID: |
---|
195 | .NoLbaSupportedSoNoEBIOS: |
---|
196 | %endif ; MODULE_EBIOS |
---|
197 | ; Fall to .StoreBlockMode |
---|
198 | |
---|
199 | ;-------------------------------------------------------------------- |
---|
200 | ; .StoreBlockMode |
---|
201 | ; Parameters: |
---|
202 | ; DS:DI: Ptr to Disk Parameter Table |
---|
203 | ; ES:SI: Ptr to 512-byte ATA information read from the drive |
---|
204 | ; CS:BP: Ptr to IDEVARS for the controller |
---|
205 | ; Returns: |
---|
206 | ; Nothing |
---|
207 | ; Corrupts registers: |
---|
208 | ; Nothing |
---|
209 | ;-------------------------------------------------------------------- |
---|
210 | .StoreBlockMode: |
---|
211 | cmp BYTE [es:si+ATA1.bBlckSize], 1 ; Max block size in sectors |
---|
212 | jbe SHORT .BlockModeTransfersNotSupported |
---|
213 | or BYTE [di+DPT.bFlagsHigh], FLGH_DPT_BLOCK_MODE_SUPPORTED |
---|
214 | .BlockModeTransfersNotSupported: |
---|
215 | ; Fall to .StoreDeviceSpecificParameters |
---|
216 | |
---|
217 | ;-------------------------------------------------------------------- |
---|
218 | ; .StoreDeviceSpecificParameters |
---|
219 | ; Parameters: |
---|
220 | ; DS:DI: Ptr to Disk Parameter Table |
---|
221 | ; ES:SI: Ptr to 512-byte ATA information read from the drive |
---|
222 | ; CS:BP: Ptr to IDEVARS for the controller |
---|
223 | ; Returns: |
---|
224 | ; Nothing |
---|
225 | ; Corrupts registers: |
---|
226 | ; AX, BX, CX, DX |
---|
227 | ;-------------------------------------------------------------------- |
---|
228 | .StoreDeviceSpecificParameters: |
---|
229 | call Device_FinalizeDPT |
---|
230 | |
---|
231 | ;---------------------------------------------------------------------- |
---|
232 | ; Update drive counts (hard and floppy) |
---|
233 | ;---------------------------------------------------------------------- |
---|
234 | |
---|
235 | %ifdef MODULE_SERIAL_FLOPPY |
---|
236 | ; |
---|
237 | ; These two instructions serve two purposes: |
---|
238 | ; 1. If the drive is a floppy drive (CF set), then we effectively increment the counter. |
---|
239 | ; 2. If this is a hard disk, and there have been any floppy drives previously added, then the hard disk is |
---|
240 | ; effectively discarded. This is more of a safety check then code that should ever normally be hit (see below). |
---|
241 | ; Since the floppy DPT's come after the hard disk DPT's, without expensive (code size) code to relocate a DPT, |
---|
242 | ; this was necessary. Now, this situation shouldn't happen in normal operation, for a couple of reasons: |
---|
243 | ; A. xtidecfg always puts configured serial ports at the end of the IDEVARS list |
---|
244 | ; B. the auto serial code is always executed last |
---|
245 | ; C. the serial server always returns floppy drives last |
---|
246 | ; |
---|
247 | adc byte [RAMVARS.xlateVars+XLATEVARS.bFlopCreateCnt], 0 |
---|
248 | jnz .AllDone |
---|
249 | %else |
---|
250 | ; |
---|
251 | ; Even without floppy support enabled, we shouldn't try to mount a floppy image as a hard disk, which |
---|
252 | ; could lead to unpredictable results since no MBR will be present, etc. The server doesn't know that |
---|
253 | ; floppies are supported, so it is important to still fail here if a floppy is seen during the drive scan. |
---|
254 | ; |
---|
255 | jc .AllDone |
---|
256 | %endif |
---|
257 | |
---|
258 | inc BYTE [RAMVARS.bDrvCnt] ; Increment drive count to RAMVARS |
---|
259 | |
---|
260 | .AllDone: |
---|
261 | clc |
---|
262 | ret |
---|
263 | |
---|
264 | |
---|
265 | ;-------------------------------------------------------------------- |
---|
266 | ; CreateDPT_StoreIdevarsOffsetAndBasePortFromCSBPtoDPTinDSDI |
---|
267 | ; Parameters: |
---|
268 | ; DX: Autodetected port (for devices that support autodetection) |
---|
269 | ; DS:DI: Ptr to Disk Parameter Table |
---|
270 | ; CS:BP: Ptr to IDEVARS for the controller |
---|
271 | ; Returns: |
---|
272 | ; Nothing |
---|
273 | ; Corrupts registers: |
---|
274 | ; AX |
---|
275 | ;-------------------------------------------------------------------- |
---|
276 | CreateDPT_StoreIdevarsOffsetAndBasePortFromCSBPtoDPTinDSDI: |
---|
277 | mov [di+DPT.bIdevarsOffset], bp ; IDEVARS must start in first 256 bytes of ROM |
---|
278 | |
---|
279 | %ifdef MODULE_8BIT_IDE_ADVANCED |
---|
280 | call DetectDrives_DoesIdevarsInCSBPbelongToXTCF |
---|
281 | jne SHORT .DeviceUsesPortSpecifiedInIDEVARS |
---|
282 | mov [di+DPT.wBasePort], dx |
---|
283 | ret |
---|
284 | .DeviceUsesPortSpecifiedInIDEVARS: |
---|
285 | %endif ; MODULE_8BIT_IDE_ADVANCED |
---|
286 | |
---|
287 | mov ax, [cs:bp+IDEVARS.wBasePort] |
---|
288 | mov [di+DPT.wBasePort], ax |
---|
289 | ret |
---|
290 | |
---|
291 | |
---|
292 | ;-------------------------------------------------------------------- |
---|
293 | ; GetUserDefinedCapacityToBXAXandFlagsToCXandModeToDXfromROMVARS |
---|
294 | ; Parameters: |
---|
295 | ; DS:DI: Ptr to Disk Parameter Table |
---|
296 | ; Returns: |
---|
297 | ; AX: User defined P-CHS Cylinders or LBA low word |
---|
298 | ; BX: User defined P-CHS Heads and Sectors or LBA high word |
---|
299 | ; DX: Translate mode or TRANSLATEMODE_AUTO |
---|
300 | ; CX: FLG_DRVPARAMS_USERCHS if user defined CHS in BX:AX |
---|
301 | ; FLG_DRVPARAMS_USERLBA if user defined LBA in BX:AX |
---|
302 | ; Zero if user has not defined capacity |
---|
303 | ; Corrupts registers: |
---|
304 | ; Nothing |
---|
305 | ;-------------------------------------------------------------------- |
---|
306 | GetUserDefinedCapacityToBXAXandFlagsToCXandModeToDXfromROMVARS: |
---|
307 | call AccessDPT_GetPointerToDRVPARAMStoCSBX |
---|
308 | |
---|
309 | ; Get settings |
---|
310 | mov cx, [cs:bx+DRVPARAMS.wFlags] |
---|
311 | mov dx, cx |
---|
312 | and cx, BYTE FLG_DRVPARAMS_USERCHS | FLG_DRVPARAMS_USERLBA |
---|
313 | and dx, BYTE MASK_DRVPARAMS_TRANSLATEMODE |
---|
314 | eSHR_IM dx, TRANSLATEMODE_FIELD_POSITION |
---|
315 | |
---|
316 | ; Get capacity |
---|
317 | mov ax, [cs:bx+DRVPARAMS.wCylinders] ; Or .dwMaximumLBA |
---|
318 | mov bx, [cs:bx+DRVPARAMS.wHeadsAndSectors] ; Or .dwMaximumLBA+2 |
---|
319 | ret |
---|
320 | |
---|
321 | |
---|
322 | %ifdef MODULE_EBIOS |
---|
323 | ;-------------------------------------------------------------------- |
---|
324 | ; StoreLba48AddressingFromCLandTotalSectorCountFromBXDXAX |
---|
325 | ; Parameters: |
---|
326 | ; BX:DX:AX: Total Sector Count |
---|
327 | ; CL: FLGL_DPT_LBA48 if LBA48 supported |
---|
328 | ; DS:DI: Ptr to Disk Parameter Table |
---|
329 | ; Returns: |
---|
330 | ; Nothing |
---|
331 | ; Corrupts registers: |
---|
332 | ; CL |
---|
333 | ;-------------------------------------------------------------------- |
---|
334 | StoreLba48AddressingFromCLandTotalSectorCountFromBXDXAX: |
---|
335 | or cl, FLGL_DPT_LBA_AND_EBIOS_SUPPORTED |
---|
336 | and BYTE [di+DPT.bFlagsLow], ~FLGL_DPT_LBA48 |
---|
337 | or [di+DPT.bFlagsLow], cl |
---|
338 | mov [di+DPT.twLbaSectors], ax |
---|
339 | mov [di+DPT.twLbaSectors+2], dx |
---|
340 | mov [di+DPT.twLbaSectors+4], bx |
---|
341 | ret |
---|
342 | %endif ; MODULE_EBIOS |
---|