source: xtideuniversalbios/trunk/XTIDE_Universal_BIOS/Src/Initialization/DetectPrint.asm @ 242

Last change on this file since 242 was 242, checked in by krille_n_@…, 12 years ago

Changes:

  • Optimizations (both for size and speed) in IdeTransfer.asm and MemIdeTransfer.asm
  • Fixed a bug where the SingleByteRead/Write functions in IdeTransfer.asm would fail on 128 sector transfers.
  • Fixed some typos and errors in general, comments etc.
File size: 4.7 KB
Line 
1; Project name  :   XTIDE Universal BIOS
2; Description   :   Functions for printing drive detection strings.
3
4; Section containing code
5SECTION .text
6
7;--------------------------------------------------------------------
8; Prints BIOS name and segment address where it is found.
9;
10; DetectPrint_RomFoundAtSegment
11;   Parameters:
12;       Nothing
13;   Returns:
14;       Nothing
15;   Corrupts registers:
16;       AX, SI, DI
17;--------------------------------------------------------------------
18DetectPrint_RomFoundAtSegment:
19    push    bp
20    mov     bp, sp
21    mov     si, g_szRomAt
22    ePUSH_T ax, ROMVARS.szTitle         ; Bios title string
23    push    cs                          ; BIOS segment
24
25DetectPrint_BootMenuPrint_FormatCSSIfromParamsInSSBP_Relay:
26    jmp     BootMenuPrint_FormatCSSIfromParamsInSSBP
27
28
29;--------------------------------------------------------------------
30; DetectPrint_StartDetectWithMasterOrSlaveStringInAXandIdeVarsInCSBP
31;   Parameters:
32;       CS:CX:  Ptr to "Master" or "Slave" string
33;       CS:BP:  Ptr to IDEVARS
34;       SI:     Ptr to template string
35;   Returns:
36;       Nothing
37;   Corrupts registers:
38;       AX, SI, DI, CX
39;--------------------------------------------------------------------
40DetectPrint_StartDetectWithMasterOrSlaveStringInAXandIdeVarsInCSBP:
41
42    mov     ax, [cs:bp+IDEVARS.wPort]       ; for IDE: AX=port address, DH=.bDevice
43    mov     dx, [cs:bp+IDEVARS.bDevice-1]   ; for Serial: AL=port address>>2, AH=baud rate
44                                            ;             DL=COM number character, DH=.bDevice
45
46    push    bp                              ; setup stack for call to
47    mov     bp, sp                          ; BootMenuPrint_FormatCSSIfromParamsInSSBP
48
49    push    cx                              ; Push "Master" or "Slave"
50
51    mov     cl, (g_szDetectPort-$$) & 0xff  ; Setup print string for standard IDE
52                                            ; Note that we modify only the low order bits of CX a lot here,
53                                            ; saving code space rather than reloading CX completely.
54                                            ; This optimization requires that all the g_szDetect* strings are
55                                            ; on the same 256 byte page, which is checked in strings.asm.
56
57    cmp     dx, DEVICE_SERIAL_PORT << 8     ; Check if this is a serial device,
58                                            ; And also check if DL is zero, check with the jz below
59                                            ; This optimization requires that DEVICE_SERIAL_PORT be
60                                            ; the highest value in the DEVICE_* series, ensuring that
61                                            ; anything less in the high order bits is a different device.
62
63    jb      .pushAndPrint                   ; CX = string to print, AX = port address, DX won't be used
64
65    mov     cl, (g_szDetectCOM-$$) & 0xff   ; Setup print string for COM ports
66    push    cx                              ; And push now.  We use the fact that format strings can contain
67                                            ; themselves format strings.
68
69    push    dx                              ; Push COM number character
70                                            ; If the string is going to be "Auto", we will push a NULL (zero)
71                                            ; here for the COM port number, which will be eaten by the
72                                            ; print routine (DisplayPrint_CharacterFromAL), resulting in
73                                            ; just "COM" being printed without a character after it.
74
75    mov     cl, (g_szDetectCOMAuto-$$) & 0xff   ; Setup secondary print string for "Auto"
76
77    jz      .pushAndPrint                   ; CX = string to print, AX and DX won't be used
78
79    mov     cl, (g_szDetectCOMLarge-$$) & 0xff  ; Setup secondary print string for "COMn/xx.yK"
80
81    mov     al,ah                           ; baud rate divisor to AL
82    cbw                                     ; clear AH, AL will always be less than 128
83    xchg    si,ax                           ; move AX to SI for divide
84    mov     ax,1152                         ; baud rate to display is 115200/divisor, the "00" is handled
85                                            ; in the print strings
86    cwd                                     ; clear top 16-bits of dividend
87    div     si                              ; and divide...  Now AX = baud rate/100, DX = 0 (always a clean divide)
88
89    mov     si,10                           ; Now separate the whole portion from the fractional for "K" display
90    div     si                              ; and divide...  Now AX = baud rate/1000, DX = low order digit
91
92    cmp     ax,si                           ; < 10: "2400", "9600", etc.; >= 10: "19.2K", "38.4K", etc.
93    jae     .pushAndPrint
94
95    mov     cl, (g_szDetectCOMSmall-$$) & 0xff  ; Setup secondary print string for "COMn/XXy00"
96
97.pushAndPrint:
98    push    cx                              ; Push print string
99    push    ax                              ; Push high order digits, or port address, or N/A
100    push    dx                              ; Push low order digit, or N/A
101
102    mov     si, g_szDetectOuter             ; Finally load SI with wrapper string "IDE %s at %s: "
103
104    jmp     short DetectPrint_BootMenuPrint_FormatCSSIfromParamsInSSBP_Relay
105
106
107;--------------------------------------------------------------------
108; DetectPrint_DriveNameFromBootnfoInESBX
109;   Parameters:
110;       ES:BX:  Ptr to BOOTNFO (if drive found)
111;   Returns:
112;       Nothing
113;   Corrupts registers:
114;       AX, SI
115;--------------------------------------------------------------------
116DetectPrint_DriveNameFromBootnfoInESBX:
117    push    di
118    push    bx
119
120    lea     si, [bx+BOOTNFO.szDrvName]
121    mov     bx, es
122    CALL_DISPLAY_LIBRARY PrintNullTerminatedStringFromBXSI
123    CALL_DISPLAY_LIBRARY PrintNewlineCharacters
124
125    pop     bx
126    pop     di
127    ret
128
Note: See TracBrowser for help on using the repository browser.