[99] | 1 | ; Project name : XTIDE Universal BIOS |
---|
[3] | 2 | ; Description : Functions for accessing ATA information read with |
---|
| 3 | ; IDENTIFY DEVICE command. |
---|
| 4 | |
---|
[376] | 5 | ; |
---|
| 6 | ; XTIDE Universal BIOS and Associated Tools |
---|
| 7 | ; Copyright (C) 2009-2010 by Tomi Tilli, 2011-2012 by XTIDE Universal BIOS Team. |
---|
| 8 | ; |
---|
| 9 | ; This program is free software; you can redistribute it and/or modify |
---|
| 10 | ; it under the terms of the GNU General Public License as published by |
---|
| 11 | ; the Free Software Foundation; either version 2 of the License, or |
---|
| 12 | ; (at your option) any later version. |
---|
| 13 | ; |
---|
| 14 | ; This program is distributed in the hope that it will be useful, |
---|
| 15 | ; but WITHOUT ANY WARRANTY; without even the implied warranty of |
---|
| 16 | ; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
---|
| 17 | ; GNU General Public License for more details. |
---|
| 18 | ; Visit http://www.gnu.org/licenses/old-licenses/gpl-2.0.html |
---|
| 19 | ; |
---|
| 20 | |
---|
[3] | 21 | ; Section containing code |
---|
| 22 | SECTION .text |
---|
| 23 | |
---|
[363] | 24 | %ifdef MODULE_ADVANCED_ATA |
---|
| 25 | ;-------------------------------------------------------------------- |
---|
[364] | 26 | ; AtaID_GetMaxPioModeToAXandMinCycleTimeToCX |
---|
[363] | 27 | ; Parameters: |
---|
| 28 | ; ES:SI: Ptr to 512-byte ATA information read from the drive |
---|
| 29 | ; Returns: |
---|
[364] | 30 | ; AL: Max supported PIO mode |
---|
| 31 | ; AH: FLGH_DPT_IORDY if IORDY supported, zero otherwise |
---|
| 32 | ; CX: Minimum Cycle Time in nanosecs |
---|
[363] | 33 | ; Corrupts registers: |
---|
| 34 | ; BX |
---|
| 35 | ;-------------------------------------------------------------------- |
---|
[364] | 36 | AtaID_GetMaxPioModeToAXandMinCycleTimeToCX: |
---|
[363] | 37 | ; Get PIO mode and cycle time for PIO 0...2 |
---|
| 38 | mov bx, [es:si+ATA1.bPioMode] |
---|
[370] | 39 | mov ax, bx ; AH = 0, AL = PIO mode 0, 1 or 2 |
---|
[363] | 40 | shl bx, 1 ; Shift for WORD lookup |
---|
[364] | 41 | mov cx, [cs:bx+.rgwPio0to2CycleTimeInNanosecs] |
---|
[363] | 42 | |
---|
[364] | 43 | ; Check if IORDY is supported |
---|
| 44 | test BYTE [es:si+ATA2.wCaps+1], A2_wCaps_IORDY >> 8 |
---|
| 45 | jz SHORT .ReturnPioTimings ; No PIO 3 or higher if no IORDY |
---|
| 46 | mov ah, FLGH_DPT_IORDY |
---|
| 47 | |
---|
[363] | 48 | ; Check if Advanced PIO modes are supported (3 and above) |
---|
| 49 | test BYTE [es:si+ATA2.wFields], A2_wFields_64to70 |
---|
| 50 | jz SHORT .ReturnPioTimings |
---|
| 51 | |
---|
| 52 | ; Get Advanced PIO mode |
---|
[364] | 53 | ; (Hard Disks supports up to 4 but CF cards can support 5 and 6) |
---|
[370] | 54 | mov bl, [es:si+ATA2.bPIOSupp] |
---|
[363] | 55 | .CheckNextFlag: |
---|
| 56 | inc ax |
---|
[370] | 57 | shr bl, 1 |
---|
[363] | 58 | jnz SHORT .CheckNextFlag |
---|
[364] | 59 | MIN_U al, 6 ; Make sure not above lookup tables |
---|
| 60 | mov cx, [es:si+ATA2.wPIOMinCyF] ; Advanced modes use IORDY |
---|
[363] | 61 | .ReturnPioTimings: |
---|
| 62 | ret |
---|
| 63 | |
---|
| 64 | .rgwPio0to2CycleTimeInNanosecs: |
---|
| 65 | dw PIO_0_MIN_CYCLE_TIME_NS |
---|
| 66 | dw PIO_1_MIN_CYCLE_TIME_NS |
---|
| 67 | dw PIO_2_MIN_CYCLE_TIME_NS |
---|
| 68 | |
---|
| 69 | |
---|
| 70 | ;-------------------------------------------------------------------- |
---|
[364] | 71 | ; AtaID_GetRecoveryTimeToAXfromPioModeInBXandCycleTimeInCX |
---|
[363] | 72 | ; Parameters: |
---|
[364] | 73 | ; BX: PIO Mode |
---|
| 74 | ; CX: PIO Cycle Time in nanosecs |
---|
[363] | 75 | ; Returns: |
---|
[364] | 76 | ; AX: Active Time in nanosecs |
---|
[363] | 77 | ; Corrupts registers: |
---|
[364] | 78 | ; BX, CX |
---|
[363] | 79 | ;-------------------------------------------------------------------- |
---|
[364] | 80 | AtaID_GetRecoveryTimeToAXfromPioModeInBXandCycleTimeInCX: |
---|
| 81 | call AtaID_GetActiveTimeToAXfromPioModeInBX |
---|
| 82 | mov bl, [cs:bx+.rgbPioModeToAddressValidTimeNs] |
---|
| 83 | sub cx, bx ; Cycle Time (t0) - Address Valid Time (t1) |
---|
| 84 | sub cx, ax ; - Active Time (t2) |
---|
| 85 | xchg ax, cx ; AX = Recovery Time (t2i) |
---|
[363] | 86 | ret |
---|
| 87 | |
---|
| 88 | .rgbPioModeToAddressValidTimeNs: |
---|
| 89 | db PIO_0_MIN_ADDRESS_VALID_NS |
---|
| 90 | db PIO_1_MIN_ADDRESS_VALID_NS |
---|
| 91 | db PIO_2_MIN_ADDRESS_VALID_NS |
---|
| 92 | db PIO_3_MIN_ADDRESS_VALID_NS |
---|
| 93 | db PIO_4_MIN_ADDRESS_VALID_NS |
---|
[364] | 94 | db PIO_5_MIN_ADDRESS_VALID_NS |
---|
| 95 | db PIO_6_MIN_ADDRESS_VALID_NS |
---|
[363] | 96 | |
---|
[364] | 97 | |
---|
| 98 | ;-------------------------------------------------------------------- |
---|
| 99 | ; AtaID_GetActiveTimeToAXfromPioModeInBX |
---|
| 100 | ; Parameters: |
---|
| 101 | ; BX: PIO Mode |
---|
| 102 | ; Returns: |
---|
| 103 | ; AX: Active Time in nanosecs |
---|
| 104 | ; Corrupts registers: |
---|
| 105 | ; Nothing |
---|
| 106 | ;-------------------------------------------------------------------- |
---|
| 107 | AtaID_GetActiveTimeToAXfromPioModeInBX: |
---|
| 108 | shl bx, 1 |
---|
| 109 | mov ax, [cs:bx+.rgwPioModeToActiveTimeNs] |
---|
| 110 | shr bx, 1 |
---|
| 111 | ret |
---|
| 112 | |
---|
[363] | 113 | .rgwPioModeToActiveTimeNs: |
---|
| 114 | dw PIO_0_MIN_ACTIVE_TIME_NS |
---|
| 115 | dw PIO_1_MIN_ACTIVE_TIME_NS |
---|
| 116 | dw PIO_2_MIN_ACTIVE_TIME_NS |
---|
| 117 | dw PIO_3_MIN_ACTIVE_TIME_NS |
---|
| 118 | dw PIO_4_MIN_ACTIVE_TIME_NS |
---|
[364] | 119 | dw PIO_5_MIN_ACTIVE_TIME_NS |
---|
| 120 | dw PIO_6_MIN_ACTIVE_TIME_NS |
---|
[363] | 121 | |
---|
| 122 | %endif ; MODULE_ADVANCED_ATA |
---|