source: xtideuniversalbios/trunk/XTIDE_Universal_BIOS/Src/Handlers/Int13h/AH9h_HInit.asm@ 513

Last change on this file since 513 was 505, checked in by krille_n_@…, 11 years ago

Changes:

  • Reverted the changes to MenuEvents.inc done in r492 since they broke the F1 key function in XTIDECFG.
  • Added a tail-call optimized variant of the CALL_DISPLAY_LIBRARY macro (JMP_DISPLAY_LIBRARY).
  • Put a block size limit in AH1Eh_ChangeXTCFmodeBasedOnControlRegisterInAL. I think it's needed but if not, it's easy to remove.
  • Other optimizations and fixes.
File size: 9.6 KB
Line 
1; Project name : XTIDE Universal BIOS
2; Description : Int 13h function AH=9h, Initialize Drive Parameters.
3
4;
5; XTIDE Universal BIOS and Associated Tools
6; Copyright (C) 2009-2010 by Tomi Tilli, 2011-2012 by XTIDE Universal BIOS Team.
7;
8; This program is free software; you can redistribute it and/or modify
9; it under the terms of the GNU General Public License as published by
10; the Free Software Foundation; either version 2 of the License, or
11; (at your option) any later version.
12;
13; This program is distributed in the hope that it will be useful,
14; but WITHOUT ANY WARRANTY; without even the implied warranty of
15; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
16; GNU General Public License for more details.
17; Visit http://www.gnu.org/licenses/old-licenses/gpl-2.0.html
18;
19
20; Section containing code
21SECTION .text
22
23;--------------------------------------------------------------------
24; STORE_ERROR_FLAG_TO_DPT
25; Parameters:
26; %1: Error flag to set
27; AH: BIOS Error Code
28; DS:DI: Ptr to DPT
29; CF: Set if error code in AH
30; Returns:
31; CF: Clear if no error
32; Set if error flag was set
33; Corrupts registers:
34; Nothing
35;--------------------------------------------------------------------
36%macro STORE_ERROR_FLAG_TO_DPT 1
37 mov al, %1
38 call SetErrorFlagFromALwithErrorCodeInAH
39%endmacro
40
41
42;--------------------------------------------------------------------
43; Int 13h function AH=9h, Initialize Drive Parameters.
44;
45; AH9h_HandlerForInitializeDriveParameters
46; Parameters:
47; DL: Translated Drive number
48; DS:DI: Ptr to DPT (in RAMVARS segment)
49; SS:BP: Ptr to IDEPACK
50; Returns with INTPACK:
51; AH: Int 13h return status
52; CF: 0 if successful, 1 if error
53;--------------------------------------------------------------------
54AH9h_HandlerForInitializeDriveParameters:
55%ifndef USE_186
56 call AH9h_InitializeDriveForUse
57 jmp Int13h_ReturnFromHandlerAfterStoringErrorCodeFromAH
58%else
59 push Int13h_ReturnFromHandlerAfterStoringErrorCodeFromAH
60 ; Fall to AH9h_InitializeDriveForUse
61%endif
62
63
64;--------------------------------------------------------------------
65; Initialize drive to be ready for use.
66;
67; AH9h_InitializeDriveForUse
68; Parameters:
69; DS:DI: Ptr to DPT (in RAMVARS segment)
70; SS:BP: Ptr to IDEPACK
71; Returns:
72; AH: Int 13h return status
73; CF: 0 if successful, 1 if error
74; Corrupts registers:
75; AL, BX, CX, DX
76;--------------------------------------------------------------------
77AH9h_InitializeDriveForUse:
78 xor ax, ax ; Clear AH to assume no errors
79
80%ifdef MODULE_ADVANCED_ATA
81 ; Clear Initialization Error flags from DPT
82 mov [di+DPT.bInitError], al
83%endif
84
85%ifdef MODULE_SERIAL
86 ; No need to do this for serial devices
87 test BYTE [di+DPT.bFlagsHigh], FLGH_DPT_SERIAL_DEVICE ; Clears CF
88 jz SHORT .ContinueInitialization
89 ret ; With AH and CF cleared
90.ContinueInitialization:
91%endif
92
93 push es
94 push si
95
96
97;;; SelectDrive
98 ; Try to select drive and wait until ready
99 call AccessDPT_GetDriveSelectByteForOldInt13hToAL
100 mov [bp+IDEPACK.bDrvAndHead], al
101 call Device_SelectDrive
102 STORE_ERROR_FLAG_TO_DPT FLG_INITERROR_FAILED_TO_SELECT_DRIVE
103%ifdef USE_386
104 jc .ReturnWithErrorCodeInAH
105%else
106 jnc SHORT .ContinueInitializationSinceDriveSelectedSuccesfully
107 jmp .ReturnWithErrorCodeInAH
108.ContinueInitializationSinceDriveSelectedSuccesfully:
109%endif
110
111
112;;; Set XT-CF mode
113%ifdef MODULE_8BIT_IDE_ADVANCED
114 call AccessDPT_GetIdevarsToCSBX
115 mov al, [cs:bx+IDEVARS.bXTCFcontrolRegister]
116 call AH9h_SetModeFromALtoXTCF
117 STORE_ERROR_FLAG_TO_DPT FLG_INITERROR_FAILED_TO_SET_XTCF_MODE
118.DoNotSetXTCFmode:
119%endif ; MODULE_8BIT_IDE_ADVANCED
120
121%ifdef MODULE_8BIT_IDE
122;;; Set 8-bit PIO mode
123 call AH9h_Enable8bitModeForDevice8bitAta
124 STORE_ERROR_FLAG_TO_DPT FLG_INITERROR_FAILED_TO_SET_8BIT_MODE
125.DoNotSet8bitMode:
126%endif ; MODULE_8BIT_IDE
127
128
129;;; InitializeDeviceParameters
130 ; Initialize CHS parameters if LBA is not used and
131 ; user has specified P-CHS parameters
132 test BYTE [di+DPT.bFlagsLow], FLGL_DPT_ASSISTED_LBA
133 jnz SHORT .SkipInitializeDeviceParameters ; No need to initialize CHS parameters if LBA mode enabled
134 call AccessDPT_GetPointerToDRVPARAMStoCSBX
135 test BYTE [cs:bx+DRVPARAMS.wFlags], FLG_DRVPARAMS_USERCHS ; User specified P-CHS?
136 jz SHORT .SkipInitializeDeviceParameters
137
138 ; Initialize Logical Sectors per Track and Max Head number
139 mov ax, [cs:bx+DRVPARAMS.wHeadsAndSectors]
140 dec ax ; Max Head number
141 xchg al, ah ; Heads now in AH
142 mov dx, ax ; Sectors per Track now in DL
143 mov al, COMMAND_INITIALIZE_DEVICE_PARAMETERS
144 mov bx, TIMEOUT_AND_STATUS_TO_WAIT(TIMEOUT_BSY, FLG_STATUS_BSY)
145 call Idepack_StoreNonExtParametersAndIssueCommandFromAL
146 STORE_ERROR_FLAG_TO_DPT FLG_INITERROR_FAILED_TO_INITIALIZE_CHS_PARAMETERS
147.SkipInitializeDeviceParameters:
148
149
150;;; SetWriteCache
151 ; Enable or Disable Write Cache
152 call AccessDPT_GetPointerToDRVPARAMStoCSBX
153 mov bl, [cs:bx+DRVPARAMS.wFlags]
154 push bx ; Save .wFlags for later use in InitializeBlockMode
155 and bx, BYTE MASK_DRVPARAMS_WRITECACHE
156 jz SHORT .SkipSetWriteCache ; DEFAULT_WRITE_CACHE
157 mov si, [cs:bx+.rgbWriteCacheCommands]
158 call AH23h_SetControllerFeatures
159 STORE_ERROR_FLAG_TO_DPT FLG_INITERROR_FAILED_TO_SET_WRITE_CACHE
160.SkipSetWriteCache:
161
162
163;;; RecalibrateDrive
164 ; Recalibrate drive by seeking to cylinder 0
165 call AH11h_RecalibrateDrive
166 STORE_ERROR_FLAG_TO_DPT FLG_INITERROR_FAILED_TO_RECALIBRATE_DRIVE
167
168
169;;; InitializeBlockMode
170 ; Initialize block mode transfers
171 pop ax ; Restore .wFlags saved in SetWriteCache
172 test BYTE [di+DPT.bFlagsHigh], FLGH_DPT_BLOCK_MODE_SUPPORTED
173 jz SHORT .BlockModeNotSupportedOrDisabled
174 test al, FLG_DRVPARAMS_BLOCKMODE
175 jz SHORT .BlockModeNotSupportedOrDisabled
176
177 ; Try block sizes until we find largest possible supported by drive
178 mov bl, 128
179.TryNextBlockSize:
180 mov al, bl
181 call AH24h_SetBlockSize ; Stores block size to DPT
182 jnc SHORT .SupportedBlockSizeFound
183 shr bl, 1
184 jnc SHORT .TryNextBlockSize
185 STORE_ERROR_FLAG_TO_DPT FLG_INITERROR_FAILED_TO_SET_BLOCK_MODE
186.BlockModeNotSupportedOrDisabled:
187.SupportedBlockSizeFound:
188
189
190%ifdef MODULE_ADVANCED_ATA
191;;; InitializePioMode
192 ; Initialize fastest supported PIO mode
193 mov dl, PIO_DEFAULT_MODE_DISABLE_IORDY
194 test BYTE [di+DPT.bFlagsHigh], FLGH_DPT_IORDY
195 jz SHORT .IordyNotSupported
196
197 ; Advanced PIO mode 3 and above
198 mov dl, [di+DPT_ADVANCED_ATA.bPioMode]
199 or dl, PIO_FLOW_CONTROL_MODE_xxx
200
201.IordyNotSupported:
202 mov si, FEATURE_SET_TRANSFER_MODE
203 call AH23h_SetControllerFeatures
204 STORE_ERROR_FLAG_TO_DPT FLG_INITERROR_FAILED_TO_SET_PIO_MODE
205%endif ; MODULE_ADVANCED_ATA
206
207
208%ifdef MODULE_FEATURE_SETS
209;;; InitStandbyTimer
210 ; Initialize the standby timer (if supported)
211 test BYTE [di+DPT.bFlagsHigh], FLGH_DPT_POWER_MANAGEMENT_SUPPORTED
212 jz SHORT .NoPowerManagementSupport
213
214 mov al, COMMAND_IDLE
215 mov dl, [cs:ROMVARS.bIdleTimeout]
216 mov bx, TIMEOUT_AND_STATUS_TO_WAIT(TIMEOUT_BSY, FLG_STATUS_BSY)
217 call Idepack_StoreNonExtParametersAndIssueCommandFromAL
218 STORE_ERROR_FLAG_TO_DPT FLG_INITERROR_FAILED_TO_INITIALIZE_STANDBY_TIMER
219.NoPowerManagementSupport:
220%endif ; MODULE_FEATURE_SETS
221
222
223 ; There might have been several errors so just return one error code for them all
224.ReturnWithErrorCodeInAH:
225%ifdef MODULE_ADVANCED_ATA
226 mov ah, [di+DPT.bInitError]
227 test ah, ah ; Clears CF
228 jz SHORT .ReturnWithSuccess
229 mov ah, RET_HD_RESETFAIL
230 stc
231.ReturnWithSuccess:
232%endif
233
234 pop si
235 pop es
236 ret
237
238
239.rgbWriteCacheCommands:
240 db 0 ; DEFAULT_WRITE_CACHE
241 db FEATURE_DISABLE_WRITE_CACHE ; DISABLE_WRITE_CACHE
242 db FEATURE_ENABLE_WRITE_CACHE ; ENABLE_WRITE_CACHE
243
244
245
246;--------------------------------------------------------------------
247; SetErrorFlagFromALwithErrorCodeInAH
248; Parameters:
249; AH: BIOS Error Code
250; AL: Error flag to set
251; DS:DI: Ptr to DPT
252; CF: Set if error code in AH
253; Clear if AH = 0
254; Returns:
255; CF: Clear if no error
256; Set if error flag was set
257; Corrupts registers:
258; Nothing
259;--------------------------------------------------------------------
260IgnoreInvalidCommandError:
261 xor ah, ah ; Clears CF
262SetErrorFlagFromALwithErrorCodeInAH:
263 jnc SHORT .NoErrorFlagToSet
264 cmp ah, RET_HD_INVALID
265 jbe SHORT IgnoreInvalidCommandError
266
267 or [di+DPT.bInitError], al
268 stc
269.NoErrorFlagToSet:
270 ret
271
272
273%ifdef MODULE_8BIT_IDE_ADVANCED
274;--------------------------------------------------------------------
275; AH9h_SetModeFromALtoXTCF
276; Parameters:
277; AL: XT-CF Mode to set
278; DS:DI: Ptr to DPT (in RAMVARS segment)
279; SS:BP: Ptr to IDEPACK
280; Returns:
281; AH: Int 13h return status
282; CF: Clear if successful or device is not XT-CF
283; Set if failed to set mode for XT-CF
284; Corrupts registers:
285; AL, BX, CX, DX, SI
286;--------------------------------------------------------------------
287AH9h_SetModeFromALtoXTCF:
288 call AccessDPT_IsThisDeviceXTCF
289 jne SHORT IgnoreInvalidCommandError
290 jmp AH1Eh_ChangeXTCFmodeBasedOnControlRegisterInAL
291%endif ; MODULE_8BIT_IDE_ADVANCED
292
293%ifdef MODULE_8BIT_IDE
294;--------------------------------------------------------------------
295; AH9h_Enable8bitModeForDevice8bitAta
296; Parameters:
297; DS:DI: Ptr to DPT (in RAMVARS segment)
298; SS:BP: Ptr to IDEPACK
299; Returns:
300; AH: Int 13h return status
301; CF: Clear if successful or device is not DEVICE_8BIT_ATA
302; Set if failed to set 8-bit mode for DEVICE_8BIT_ATA
303; Corrupts registers:
304; AL, BX, CX, DX, SI
305;--------------------------------------------------------------------
306AH9h_Enable8bitModeForDevice8bitAta:
307 cmp BYTE [di+DPT_ATA.bDevice], DEVICE_8BIT_ATA
308 jne SHORT IgnoreInvalidCommandError
309 jmp AH23h_Enable8bitPioMode
310%endif
Note: See TracBrowser for help on using the repository browser.