source: xtideuniversalbios/trunk/XTIDE_Universal_BIOS/Src/Handlers/Int13h/AH9h_HInit.asm @ 521

Last change on this file since 521 was 521, checked in by aitotat@…, 9 years ago

Changes to XTIDE Universal BIOS:

  • Hopefully fixed problems with recent changes to AH=00h.
  • Timeout error code is no longer displayed when trying to boot from floppy drive.
File size: 9.6 KB
Line 
1; Project name  :   XTIDE Universal BIOS
2; Description   :   Int 13h function AH=9h, Initialize Drive Parameters.
3
4;
5; XTIDE Universal BIOS and Associated Tools
6; Copyright (C) 2009-2010 by Tomi Tilli, 2011-2012 by XTIDE Universal BIOS Team.
7;
8; This program is free software; you can redistribute it and/or modify
9; it under the terms of the GNU General Public License as published by
10; the Free Software Foundation; either version 2 of the License, or
11; (at your option) any later version.
12;
13; This program is distributed in the hope that it will be useful,
14; but WITHOUT ANY WARRANTY; without even the implied warranty of
15; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
16; GNU General Public License for more details.
17; Visit http://www.gnu.org/licenses/old-licenses/gpl-2.0.html
18;
19
20; Section containing code
21SECTION .text
22
23;--------------------------------------------------------------------
24; STORE_ERROR_FLAG_TO_DPT
25;   Parameters:
26;       %1:     Error flag to set
27;       AH:     BIOS Error Code
28;       DS:DI:  Ptr to DPT
29;       CF:     Set if error code in AH
30;   Returns:
31;       CF:     Clear if no error
32;               Set if error flag was set
33;   Corrupts registers:
34;       Nothing
35;--------------------------------------------------------------------
36%macro STORE_ERROR_FLAG_TO_DPT 1
37    mov     al, %1
38    call    SetErrorFlagFromALwithErrorCodeInAH
39%endmacro
40
41
42;--------------------------------------------------------------------
43; Int 13h function AH=9h, Initialize Drive Parameters.
44;
45; AH9h_HandlerForInitializeDriveParameters
46;   Parameters:
47;       DL:     Translated Drive number
48;       DS:DI:  Ptr to DPT (in RAMVARS segment)
49;       SS:BP:  Ptr to IDEPACK
50;   Returns with INTPACK:
51;       AH:     Int 13h return status
52;       CF:     0 if successful, 1 if error
53;--------------------------------------------------------------------
54AH9h_HandlerForInitializeDriveParameters:
55%ifndef USE_186
56    call    AH9h_InitializeDriveForUse
57    jmp     Int13h_ReturnFromHandlerAfterStoringErrorCodeFromAH
58%else
59    push    Int13h_ReturnFromHandlerAfterStoringErrorCodeFromAH
60    ; Fall to AH9h_InitializeDriveForUse
61%endif
62
63
64;--------------------------------------------------------------------
65; Initialize drive to be ready for use.
66;
67; AH9h_InitializeDriveForUse
68;   Parameters:
69;       DS:DI:  Ptr to DPT (in RAMVARS segment)
70;       SS:BP:  Ptr to IDEPACK
71;   Returns:
72;       AH:     Int 13h return status
73;       CF:     0 if successful, 1 if error
74;   Corrupts registers:
75;       AL, CX
76;--------------------------------------------------------------------
77AH9h_InitializeDriveForUse:
78    xor     ax, ax              ; Clear AH to assume no errors
79
80%ifdef MODULE_ADVANCED_ATA
81    ; Clear Initialization Error flags from DPT
82    mov     [di+DPT.bInitError], al
83%endif
84
85%ifdef MODULE_SERIAL
86    ; No need to do this for serial devices
87    test    BYTE [di+DPT.bFlagsHigh], FLGH_DPT_SERIAL_DEVICE    ; Clears CF
88    jz      SHORT .ContinueInitialization
89    ret     ; With AH and CF cleared
90.ContinueInitialization:
91%endif
92
93    push    es
94    push    si
95    push    dx
96    push    bx
97
98
99;;; SelectDrive
100    ; Try to select drive and wait until ready
101    call    AccessDPT_GetDriveSelectByteForOldInt13hToAL
102    mov     [bp+IDEPACK.bDrvAndHead], al
103    call    Device_SelectDrive
104    STORE_ERROR_FLAG_TO_DPT     FLG_INITERROR_FAILED_TO_SELECT_DRIVE
105%ifdef USE_386
106    jc      .ReturnWithErrorCodeInAH
107%else
108    jnc     SHORT .ContinueInitializationSinceDriveSelectedSuccesfully
109    jmp     .ReturnWithErrorCodeInAH
110.ContinueInitializationSinceDriveSelectedSuccesfully:
111%endif
112
113
114;;; Set XT-CF mode
115%ifdef MODULE_8BIT_IDE_ADVANCED
116    call    AccessDPT_GetIdevarsToCSBX
117    mov     al, [cs:bx+IDEVARS.bXTCFcontrolRegister]
118    call    AH9h_SetModeFromALtoXTCF
119    STORE_ERROR_FLAG_TO_DPT     FLG_INITERROR_FAILED_TO_SET_XTCF_MODE
120.DoNotSetXTCFmode:
121%endif  ; MODULE_8BIT_IDE_ADVANCED
122
123%ifdef MODULE_8BIT_IDE
124;;; Set 8-bit PIO mode
125    call    AH9h_Enable8bitModeForDevice8bitAta
126    STORE_ERROR_FLAG_TO_DPT     FLG_INITERROR_FAILED_TO_SET_8BIT_MODE
127.DoNotSet8bitMode:
128%endif ; MODULE_8BIT_IDE
129
130
131;;; InitializeDeviceParameters
132    ; Initialize CHS parameters if LBA is not used and
133    ; user has specified P-CHS parameters
134    test    BYTE [di+DPT.bFlagsLow], FLGL_DPT_ASSISTED_LBA
135    jnz     SHORT .SkipInitializeDeviceParameters       ; No need to initialize CHS parameters if LBA mode enabled
136    call    AccessDPT_GetPointerToDRVPARAMStoCSBX
137    test    BYTE [cs:bx+DRVPARAMS.wFlags], FLG_DRVPARAMS_USERCHS    ; User specified P-CHS?
138    jz      SHORT .SkipInitializeDeviceParameters
139
140    ; Initialize Logical Sectors per Track and Max Head number
141    mov     ax, [cs:bx+DRVPARAMS.wHeadsAndSectors]
142    dec     ax                          ; Max Head number
143    xchg    al, ah                      ; Heads now in AH
144    mov     dx, ax                      ; Sectors per Track now in DL
145    mov     al, COMMAND_INITIALIZE_DEVICE_PARAMETERS
146    mov     bx, TIMEOUT_AND_STATUS_TO_WAIT(TIMEOUT_BSY, FLG_STATUS_BSY)
147    call    Idepack_StoreNonExtParametersAndIssueCommandFromAL
148    STORE_ERROR_FLAG_TO_DPT     FLG_INITERROR_FAILED_TO_INITIALIZE_CHS_PARAMETERS
149.SkipInitializeDeviceParameters:
150
151
152;;; SetWriteCache
153    ; Enable or Disable Write Cache
154    call    AccessDPT_GetPointerToDRVPARAMStoCSBX
155    mov     bl, [cs:bx+DRVPARAMS.wFlags]
156    push    bx  ; Save .wFlags for later use in InitializeBlockMode
157    and     bx, BYTE MASK_DRVPARAMS_WRITECACHE
158    jz      SHORT .SkipSetWriteCache        ; DEFAULT_WRITE_CACHE
159    mov     si, [cs:bx+.rgbWriteCacheCommands]
160    call    AH23h_SetControllerFeatures
161    STORE_ERROR_FLAG_TO_DPT     FLG_INITERROR_FAILED_TO_SET_WRITE_CACHE
162.SkipSetWriteCache:
163
164
165;;; RecalibrateDrive
166    ; Recalibrate drive by seeking to cylinder 0
167    call    AH11h_RecalibrateDrive
168    STORE_ERROR_FLAG_TO_DPT     FLG_INITERROR_FAILED_TO_RECALIBRATE_DRIVE
169
170
171;;; InitializeBlockMode
172    ; Initialize block mode transfers
173    pop     ax  ; Restore .wFlags saved in SetWriteCache
174    test    BYTE [di+DPT.bFlagsHigh], FLGH_DPT_BLOCK_MODE_SUPPORTED
175    jz      SHORT .BlockModeNotSupportedOrDisabled
176    test    al, FLG_DRVPARAMS_BLOCKMODE
177    jz      SHORT .BlockModeNotSupportedOrDisabled
178
179    ; Try block sizes until we find largest possible supported by drive
180    mov     bl, 128
181.TryNextBlockSize:
182    mov     al, bl
183    call    AH24h_SetBlockSize  ; Stores block size to DPT
184    jnc     SHORT .SupportedBlockSizeFound
185    shr     bl, 1
186    jnc     SHORT .TryNextBlockSize
187    STORE_ERROR_FLAG_TO_DPT     FLG_INITERROR_FAILED_TO_SET_BLOCK_MODE
188.BlockModeNotSupportedOrDisabled:
189.SupportedBlockSizeFound:
190
191
192%ifdef MODULE_ADVANCED_ATA
193;;; InitializePioMode
194    ; Initialize fastest supported PIO mode
195    mov     dl, PIO_DEFAULT_MODE_DISABLE_IORDY
196    test    BYTE [di+DPT.bFlagsHigh], FLGH_DPT_IORDY
197    jz      SHORT .IordyNotSupported
198
199    ; Advanced PIO mode 3 and above
200    mov     dl, [di+DPT_ADVANCED_ATA.bPioMode]
201    or      dl, PIO_FLOW_CONTROL_MODE_xxx
202
203.IordyNotSupported:
204    mov     si, FEATURE_SET_TRANSFER_MODE
205    call    AH23h_SetControllerFeatures
206    STORE_ERROR_FLAG_TO_DPT     FLG_INITERROR_FAILED_TO_SET_PIO_MODE
207%endif ; MODULE_ADVANCED_ATA
208
209
210%ifdef MODULE_FEATURE_SETS
211;;; InitStandbyTimer
212    ; Initialize the standby timer (if supported)
213    test    BYTE [di+DPT.bFlagsHigh], FLGH_DPT_POWER_MANAGEMENT_SUPPORTED
214    jz      SHORT .NoPowerManagementSupport
215
216    mov     al, COMMAND_IDLE
217    mov     dl, [cs:ROMVARS.bIdleTimeout]
218    mov     bx, TIMEOUT_AND_STATUS_TO_WAIT(TIMEOUT_BSY, FLG_STATUS_BSY)
219    call    Idepack_StoreNonExtParametersAndIssueCommandFromAL
220    STORE_ERROR_FLAG_TO_DPT     FLG_INITERROR_FAILED_TO_INITIALIZE_STANDBY_TIMER
221.NoPowerManagementSupport:
222%endif ; MODULE_FEATURE_SETS
223
224
225    ; There might have been several errors so just return one error code for them all
226.ReturnWithErrorCodeInAH:
227%ifdef MODULE_ADVANCED_ATA
228    mov     ah, [di+DPT.bInitError]
229    test    ah, ah  ; Clears CF
230    jz      SHORT .ReturnWithSuccess
231    mov     ah, RET_HD_RESETFAIL
232    stc
233.ReturnWithSuccess:
234%endif
235
236    pop     bx
237    pop     dx
238    pop     si
239    pop     es
240    ret
241
242
243.rgbWriteCacheCommands:
244    db      0                               ; DEFAULT_WRITE_CACHE
245    db      FEATURE_DISABLE_WRITE_CACHE     ; DISABLE_WRITE_CACHE
246    db      FEATURE_ENABLE_WRITE_CACHE      ; ENABLE_WRITE_CACHE
247
248
249
250;--------------------------------------------------------------------
251; SetErrorFlagFromALwithErrorCodeInAH
252;   Parameters:
253;       AH:     BIOS Error Code
254;       AL:     Error flag to set
255;       DS:DI:  Ptr to DPT
256;       CF:     Set if error code in AH
257;               Clear if AH = 0
258;   Returns:
259;       CF:     Clear if no error
260;               Set if error flag was set
261;   Corrupts registers:
262;       Nothing
263;--------------------------------------------------------------------
264IgnoreInvalidCommandError:
265    xor     ah, ah  ; Clears CF
266SetErrorFlagFromALwithErrorCodeInAH:
267    jnc     SHORT .NoErrorFlagToSet
268    cmp     ah, RET_HD_INVALID
269    jbe     SHORT IgnoreInvalidCommandError
270
271    or      [di+DPT.bInitError], al
272    stc
273.NoErrorFlagToSet:
274    ret
275
276
277%ifdef MODULE_8BIT_IDE_ADVANCED
278;--------------------------------------------------------------------
279; AH9h_SetModeFromALtoXTCF
280;   Parameters:
281;       AL:     XT-CF Mode to set
282;       DS:DI:  Ptr to DPT (in RAMVARS segment)
283;       SS:BP:  Ptr to IDEPACK
284;   Returns:
285;       AH:     Int 13h return status
286;       CF:     Clear if successful or device is not XT-CF
287;               Set if failed to set mode for XT-CF
288;   Corrupts registers:
289;       AL, BX, CX, DX, SI
290;--------------------------------------------------------------------
291AH9h_SetModeFromALtoXTCF:
292    call    AccessDPT_IsThisDeviceXTCF
293    jne     SHORT IgnoreInvalidCommandError
294    jmp     AH1Eh_ChangeXTCFmodeBasedOnControlRegisterInAL
295%endif ; MODULE_8BIT_IDE_ADVANCED
296
297%ifdef MODULE_8BIT_IDE
298;--------------------------------------------------------------------
299; AH9h_Enable8bitModeForDevice8bitAta
300;   Parameters:
301;       DS:DI:  Ptr to DPT (in RAMVARS segment)
302;       SS:BP:  Ptr to IDEPACK
303;   Returns:
304;       AH:     Int 13h return status
305;       CF:     Clear if successful or device is not DEVICE_8BIT_ATA
306;               Set if failed to set 8-bit mode for DEVICE_8BIT_ATA
307;   Corrupts registers:
308;       AL, BX, CX, DX, SI
309;--------------------------------------------------------------------
310AH9h_Enable8bitModeForDevice8bitAta:
311    cmp     BYTE [di+DPT_ATA.bDevice], DEVICE_8BIT_ATA
312    jne     SHORT IgnoreInvalidCommandError
313    jmp     AH23h_Enable8bitPioMode
314%endif
Note: See TracBrowser for help on using the repository browser.