| 1 | ; Project name : XTIDE Universal BIOS
|
|---|
| 2 | ; Description : Int 13h function AH=9h, Initialize Drive Parameters.
|
|---|
| 3 |
|
|---|
| 4 | ;
|
|---|
| 5 | ; XTIDE Universal BIOS and Associated Tools
|
|---|
| 6 | ; Copyright (C) 2009-2010 by Tomi Tilli, 2011-2012 by XTIDE Universal BIOS Team.
|
|---|
| 7 | ;
|
|---|
| 8 | ; This program is free software; you can redistribute it and/or modify
|
|---|
| 9 | ; it under the terms of the GNU General Public License as published by
|
|---|
| 10 | ; the Free Software Foundation; either version 2 of the License, or
|
|---|
| 11 | ; (at your option) any later version.
|
|---|
| 12 | ;
|
|---|
| 13 | ; This program is distributed in the hope that it will be useful,
|
|---|
| 14 | ; but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|---|
| 15 | ; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|---|
| 16 | ; GNU General Public License for more details.
|
|---|
| 17 | ; Visit http://www.gnu.org/licenses/old-licenses/gpl-2.0.html
|
|---|
| 18 | ;
|
|---|
| 19 |
|
|---|
| 20 | ; Section containing code
|
|---|
| 21 | SECTION .text
|
|---|
| 22 |
|
|---|
| 23 | ;--------------------------------------------------------------------
|
|---|
| 24 | ; STORE_ERROR_FLAG_TO_DPT
|
|---|
| 25 | ; Parameters:
|
|---|
| 26 | ; %1: Error flag to set
|
|---|
| 27 | ; AH: BIOS Error Code
|
|---|
| 28 | ; DS:DI: Ptr to DPT
|
|---|
| 29 | ; CF: Set if error code in AH
|
|---|
| 30 | ; Returns:
|
|---|
| 31 | ; CF: Clear if no error
|
|---|
| 32 | ; Set if error flag was set
|
|---|
| 33 | ; Corrupts registers:
|
|---|
| 34 | ; Nothing
|
|---|
| 35 | ;--------------------------------------------------------------------
|
|---|
| 36 | %macro STORE_ERROR_FLAG_TO_DPT 1
|
|---|
| 37 | mov al, %1
|
|---|
| 38 | call SetErrorFlagFromALwithErrorCodeInAH
|
|---|
| 39 | %endmacro
|
|---|
| 40 |
|
|---|
| 41 |
|
|---|
| 42 | ;--------------------------------------------------------------------
|
|---|
| 43 | ; Int 13h function AH=9h, Initialize Drive Parameters.
|
|---|
| 44 | ;
|
|---|
| 45 | ; AH9h_HandlerForInitializeDriveParameters
|
|---|
| 46 | ; Parameters:
|
|---|
| 47 | ; DL: Translated Drive number
|
|---|
| 48 | ; DS:DI: Ptr to DPT (in RAMVARS segment)
|
|---|
| 49 | ; SS:BP: Ptr to IDEPACK
|
|---|
| 50 | ; Returns with INTPACK:
|
|---|
| 51 | ; AH: Int 13h return status
|
|---|
| 52 | ; CF: 0 if successful, 1 if error
|
|---|
| 53 | ;--------------------------------------------------------------------
|
|---|
| 54 | AH9h_HandlerForInitializeDriveParameters:
|
|---|
| 55 | %ifndef USE_186
|
|---|
| 56 | call AH9h_InitializeDriveForUse
|
|---|
| 57 | jmp Int13h_ReturnFromHandlerAfterStoringErrorCodeFromAH
|
|---|
| 58 | %else
|
|---|
| 59 | push Int13h_ReturnFromHandlerAfterStoringErrorCodeFromAH
|
|---|
| 60 | ; Fall to AH9h_InitializeDriveForUse
|
|---|
| 61 | %endif
|
|---|
| 62 |
|
|---|
| 63 |
|
|---|
| 64 | ;--------------------------------------------------------------------
|
|---|
| 65 | ; Initialize drive to be ready for use.
|
|---|
| 66 | ;
|
|---|
| 67 | ; AH9h_InitializeDriveForUse
|
|---|
| 68 | ; Parameters:
|
|---|
| 69 | ; DS:DI: Ptr to DPT (in RAMVARS segment)
|
|---|
| 70 | ; SS:BP: Ptr to IDEPACK
|
|---|
| 71 | ; Returns:
|
|---|
| 72 | ; AH: Int 13h return status
|
|---|
| 73 | ; CF: 0 if successful, 1 if error
|
|---|
| 74 | ; Corrupts registers:
|
|---|
| 75 | ; AL, BX, CX, DX
|
|---|
| 76 | ;--------------------------------------------------------------------
|
|---|
| 77 | AH9h_InitializeDriveForUse:
|
|---|
| 78 | xor ax, ax ; Clear AH to assume no errors
|
|---|
| 79 |
|
|---|
| 80 | %ifdef MODULE_ADVANCED_ATA
|
|---|
| 81 | ; Clear Initialization Error flags from DPT
|
|---|
| 82 | mov [di+DPT.bInitError], al
|
|---|
| 83 | %endif
|
|---|
| 84 |
|
|---|
| 85 | %ifdef MODULE_SERIAL
|
|---|
| 86 | ; No need to do this for serial devices
|
|---|
| 87 | test BYTE [di+DPT.bFlagsHigh], FLGH_DPT_SERIAL_DEVICE ; Clears CF
|
|---|
| 88 | jz SHORT .ContinueInitialization
|
|---|
| 89 | ret ; With AH and CF cleared
|
|---|
| 90 | .ContinueInitialization:
|
|---|
| 91 | %endif
|
|---|
| 92 |
|
|---|
| 93 | push es
|
|---|
| 94 | push si
|
|---|
| 95 |
|
|---|
| 96 |
|
|---|
| 97 | ;;; SelectDrive
|
|---|
| 98 | ; Try to select drive and wait until ready
|
|---|
| 99 | call AccessDPT_GetDriveSelectByteForOldInt13hToAL
|
|---|
| 100 | mov [bp+IDEPACK.bDrvAndHead], al
|
|---|
| 101 | call Device_SelectDrive
|
|---|
| 102 | STORE_ERROR_FLAG_TO_DPT FLG_INITERROR_FAILED_TO_SELECT_DRIVE
|
|---|
| 103 | jnc SHORT .ContinueInitializationSinceDriveSelectedSuccesfully
|
|---|
| 104 | jmp .ReturnWithErrorCodeInAH
|
|---|
| 105 | .ContinueInitializationSinceDriveSelectedSuccesfully:
|
|---|
| 106 |
|
|---|
| 107 |
|
|---|
| 108 | ;;; Set XT-CF mode
|
|---|
| 109 | %ifdef MODULE_8BIT_IDE
|
|---|
| 110 | call AccessDPT_IsThisDeviceXTCF
|
|---|
| 111 | jne SHORT .DoNotSetXTCFmode
|
|---|
| 112 |
|
|---|
| 113 | call AccessDPT_GetIdevarsToCSBX
|
|---|
| 114 | mov al, [cs:bx+IDEVARS.bXTCFcontrolRegister]
|
|---|
| 115 | call AH1Eh_ChangeXTCFmodeBasedOnControlRegisterInAL
|
|---|
| 116 | STORE_ERROR_FLAG_TO_DPT FLG_INITERROR_FAILED_TO_SET_XTCF_MODE
|
|---|
| 117 | .DoNotSetXTCFmode:
|
|---|
| 118 | %endif
|
|---|
| 119 |
|
|---|
| 120 |
|
|---|
| 121 | ;;; InitializeDeviceParameters
|
|---|
| 122 | ; Initialize CHS parameters if LBA is not used and
|
|---|
| 123 | ; user has specified P-CHS parameters
|
|---|
| 124 | test BYTE [di+DPT.bFlagsLow], FLGL_DPT_ASSISTED_LBA
|
|---|
| 125 | jnz SHORT .SkipInitializeDeviceParameters ; No need to initialize CHS parameters if LBA mode enabled
|
|---|
| 126 | call AccessDPT_GetPointerToDRVPARAMStoCSBX
|
|---|
| 127 | test BYTE [cs:bx+DRVPARAMS.wFlags], FLG_DRVPARAMS_USERCHS ; User specified P-CHS?
|
|---|
| 128 | jz SHORT .SkipInitializeDeviceParameters
|
|---|
| 129 |
|
|---|
| 130 | ; Initialize Logical Sectors per Track and Max Head number
|
|---|
| 131 | mov ax, [cs:bx+DRVPARAMS.wHeadsAndSectors]
|
|---|
| 132 | dec ax ; Max Head number
|
|---|
| 133 | xchg al, ah ; Heads now in AH
|
|---|
| 134 | mov dx, ax ; Sectors per Track now in DL
|
|---|
| 135 | mov al, COMMAND_INITIALIZE_DEVICE_PARAMETERS
|
|---|
| 136 | mov bx, TIMEOUT_AND_STATUS_TO_WAIT(TIMEOUT_BSY, FLG_STATUS_BSY)
|
|---|
| 137 | call Idepack_StoreNonExtParametersAndIssueCommandFromAL
|
|---|
| 138 | STORE_ERROR_FLAG_TO_DPT FLG_INITERROR_FAILED_TO_INITIALIZE_CHS_PARAMETERS
|
|---|
| 139 | .SkipInitializeDeviceParameters:
|
|---|
| 140 |
|
|---|
| 141 |
|
|---|
| 142 | ;;; SetWriteCache
|
|---|
| 143 | ; Enable or Disable Write Cache
|
|---|
| 144 | call AccessDPT_GetPointerToDRVPARAMStoCSBX
|
|---|
| 145 | mov bl, [cs:bx+DRVPARAMS.wFlags]
|
|---|
| 146 | push bx ; Save .wFlags for later use in InitializeBlockMode
|
|---|
| 147 | and bx, BYTE MASK_DRVPARAMS_WRITECACHE
|
|---|
| 148 | jz SHORT .SkipSetWriteCache ; DEFAULT_WRITE_CACHE
|
|---|
| 149 | mov si, [cs:bx+.rgbWriteCacheCommands]
|
|---|
| 150 | call AH23h_SetControllerFeatures
|
|---|
| 151 | STORE_ERROR_FLAG_TO_DPT FLG_INITERROR_FAILED_TO_SET_WRITE_CACHE
|
|---|
| 152 | .SkipSetWriteCache:
|
|---|
| 153 |
|
|---|
| 154 |
|
|---|
| 155 | ;;; RecalibrateDrive
|
|---|
| 156 | ; Recalibrate drive by seeking to cylinder 0
|
|---|
| 157 | call AH11h_RecalibrateDrive
|
|---|
| 158 | STORE_ERROR_FLAG_TO_DPT FLG_INITERROR_FAILED_TO_RECALIBRATE_DRIVE
|
|---|
| 159 |
|
|---|
| 160 |
|
|---|
| 161 | ;;; InitializeBlockMode
|
|---|
| 162 | ; Initialize block mode transfers
|
|---|
| 163 | pop ax ; Restore .wFlags saved in SetWriteCache
|
|---|
| 164 | test BYTE [di+DPT.bFlagsHigh], FLGH_DPT_BLOCK_MODE_SUPPORTED
|
|---|
| 165 | jz SHORT .BlockModeNotSupportedOrDisabled
|
|---|
| 166 | test al, FLG_DRVPARAMS_BLOCKMODE
|
|---|
| 167 | jz SHORT .BlockModeNotSupportedOrDisabled
|
|---|
| 168 |
|
|---|
| 169 | ; Try block sizes until we find largest possible supported by drive
|
|---|
| 170 | mov bl, 128
|
|---|
| 171 | .TryNextBlockSize:
|
|---|
| 172 | mov al, bl
|
|---|
| 173 | call AH24h_SetBlockSize ; Stores block size to DPT
|
|---|
| 174 | jnc SHORT .SupportedBlockSizeFound
|
|---|
| 175 | shr bl, 1
|
|---|
| 176 | jnc SHORT .TryNextBlockSize
|
|---|
| 177 | STORE_ERROR_FLAG_TO_DPT FLG_INITERROR_FAILED_TO_SET_BLOCK_MODE
|
|---|
| 178 | .BlockModeNotSupportedOrDisabled:
|
|---|
| 179 | .SupportedBlockSizeFound:
|
|---|
| 180 |
|
|---|
| 181 |
|
|---|
| 182 | %ifdef MODULE_ADVANCED_ATA
|
|---|
| 183 | ;;; InitializePioMode
|
|---|
| 184 | ; Initialize fastest supported PIO mode
|
|---|
| 185 | mov dl, PIO_DEFAULT_MODE_DISABLE_IORDY
|
|---|
| 186 | test BYTE [di+DPT.bFlagsHigh], FLGH_DPT_IORDY
|
|---|
| 187 | jz SHORT .IordyNotSupported
|
|---|
| 188 |
|
|---|
| 189 | ; Advanced PIO mode 3 and above
|
|---|
| 190 | mov dl, [di+DPT_ADVANCED_ATA.bPioMode]
|
|---|
| 191 | or dl, PIO_FLOW_CONTROL_MODE_xxx
|
|---|
| 192 |
|
|---|
| 193 | .IordyNotSupported:
|
|---|
| 194 | mov si, FEATURE_SET_TRANSFER_MODE
|
|---|
| 195 | call AH23h_SetControllerFeatures
|
|---|
| 196 | STORE_ERROR_FLAG_TO_DPT FLG_INITERROR_FAILED_TO_SET_PIO_MODE
|
|---|
| 197 | %endif ; MODULE_ADVANCED_ATA
|
|---|
| 198 |
|
|---|
| 199 |
|
|---|
| 200 | %ifdef MODULE_FEATURE_SETS
|
|---|
| 201 | ;;; InitStandbyTimer
|
|---|
| 202 | ; Initialize the standby timer (if supported)
|
|---|
| 203 | test BYTE [di+DPT.bFlagsHigh], FLGH_DPT_POWER_MANAGEMENT_SUPPORTED
|
|---|
| 204 | jz SHORT .NoPowerManagementSupport
|
|---|
| 205 |
|
|---|
| 206 | mov al, COMMAND_IDLE
|
|---|
| 207 | mov dl, [cs:ROMVARS.bIdleTimeout]
|
|---|
| 208 | mov bx, TIMEOUT_AND_STATUS_TO_WAIT(TIMEOUT_BSY, FLG_STATUS_BSY)
|
|---|
| 209 | call Idepack_StoreNonExtParametersAndIssueCommandFromAL
|
|---|
| 210 | STORE_ERROR_FLAG_TO_DPT FLG_INITERROR_FAILED_TO_INITIALIZE_STANDBY_TIMER
|
|---|
| 211 | .NoPowerManagementSupport:
|
|---|
| 212 | %endif ; MODULE_FEATURE_SETS
|
|---|
| 213 |
|
|---|
| 214 |
|
|---|
| 215 | ; There might have been several errors so just return one error code for them all
|
|---|
| 216 | .ReturnWithErrorCodeInAH:
|
|---|
| 217 | %ifdef MODULE_ADVANCED_ATA
|
|---|
| 218 | mov ah, [di+DPT.bInitError]
|
|---|
| 219 | test ah, ah ; Clears CF
|
|---|
| 220 | jz SHORT .ReturnWithSuccess
|
|---|
| 221 | mov ah, RET_HD_RESETFAIL
|
|---|
| 222 | stc
|
|---|
| 223 | .ReturnWithSuccess:
|
|---|
| 224 | %endif
|
|---|
| 225 |
|
|---|
| 226 | pop si
|
|---|
| 227 | pop es
|
|---|
| 228 | ret
|
|---|
| 229 |
|
|---|
| 230 |
|
|---|
| 231 | .rgbWriteCacheCommands:
|
|---|
| 232 | db 0 ; DEFAULT_WRITE_CACHE
|
|---|
| 233 | db FEATURE_DISABLE_WRITE_CACHE ; DISABLE_WRITE_CACHE
|
|---|
| 234 | db FEATURE_ENABLE_WRITE_CACHE ; ENABLE_WRITE_CACHE
|
|---|
| 235 |
|
|---|
| 236 |
|
|---|
| 237 |
|
|---|
| 238 | ;--------------------------------------------------------------------
|
|---|
| 239 | ; SetErrorFlagFromALwithErrorCodeInAH
|
|---|
| 240 | ; Parameters:
|
|---|
| 241 | ; AH: BIOS Error Code
|
|---|
| 242 | ; AL: Error flag to set
|
|---|
| 243 | ; DS:DI: Ptr to DPT
|
|---|
| 244 | ; CF: Set if error code in AH
|
|---|
| 245 | ; Clear if AH = 0
|
|---|
| 246 | ; Returns:
|
|---|
| 247 | ; CF: Clear if no error
|
|---|
| 248 | ; Set if error flag was set
|
|---|
| 249 | ; Corrupts registers:
|
|---|
| 250 | ; Nothing
|
|---|
| 251 | ;--------------------------------------------------------------------
|
|---|
| 252 | IgnoreInvalidCommandError:
|
|---|
| 253 | xor ah, ah ; Clears CF
|
|---|
| 254 | SetErrorFlagFromALwithErrorCodeInAH:
|
|---|
| 255 | jnc SHORT .NoErrorFlagToSet
|
|---|
| 256 | cmp ah, RET_HD_INVALID
|
|---|
| 257 | jbe SHORT IgnoreInvalidCommandError
|
|---|
| 258 |
|
|---|
| 259 | or [di+DPT.bInitError], al
|
|---|
| 260 | stc
|
|---|
| 261 | .NoErrorFlagToSet:
|
|---|
| 262 | ret
|
|---|
