source: xtideuniversalbios/trunk/XTIDE_Universal_BIOS/Src/Handlers/Int13h/AH9h_HInit.asm @ 480

Last change on this file since 480 was 480, checked in by aitotat@…, 12 years ago

Changes to XTIDE Universal BIOS:

  • XT-CF DMA transfers should now work.
File size: 9.4 KB
Line 
1; Project name  :   XTIDE Universal BIOS
2; Description   :   Int 13h function AH=9h, Initialize Drive Parameters.
3
4;
5; XTIDE Universal BIOS and Associated Tools
6; Copyright (C) 2009-2010 by Tomi Tilli, 2011-2012 by XTIDE Universal BIOS Team.
7;
8; This program is free software; you can redistribute it and/or modify
9; it under the terms of the GNU General Public License as published by
10; the Free Software Foundation; either version 2 of the License, or
11; (at your option) any later version.
12;
13; This program is distributed in the hope that it will be useful,
14; but WITHOUT ANY WARRANTY; without even the implied warranty of
15; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
16; GNU General Public License for more details.
17; Visit http://www.gnu.org/licenses/old-licenses/gpl-2.0.html
18;
19
20; Section containing code
21SECTION .text
22
23;--------------------------------------------------------------------
24; STORE_ERROR_FLAG_TO_DPT
25;   Parameters:
26;       %1:     Error flag to set
27;       AH:     BIOS Error Code
28;       DS:DI:  Ptr to DPT
29;       CF:     Set if error code in AH
30;   Returns:
31;       CF:     Clear if no error
32;               Set if error flag was set
33;   Corrupts registers:
34;       Nothing
35;--------------------------------------------------------------------
36%macro STORE_ERROR_FLAG_TO_DPT 1
37    mov     al, %1
38    call    SetErrorFlagFromALwithErrorCodeInAH
39%endmacro
40
41
42;--------------------------------------------------------------------
43; Int 13h function AH=9h, Initialize Drive Parameters.
44;
45; AH9h_HandlerForInitializeDriveParameters
46;   Parameters:
47;       DL:     Translated Drive number
48;       DS:DI:  Ptr to DPT (in RAMVARS segment)
49;       SS:BP:  Ptr to IDEPACK
50;   Returns with INTPACK:
51;       AH:     Int 13h return status
52;       CF:     0 if successful, 1 if error
53;--------------------------------------------------------------------
54AH9h_HandlerForInitializeDriveParameters:
55%ifndef USE_186
56    call    AH9h_InitializeDriveForUse
57    jmp     Int13h_ReturnFromHandlerAfterStoringErrorCodeFromAH
58%else
59    push    Int13h_ReturnFromHandlerAfterStoringErrorCodeFromAH
60    ; Fall to AH9h_InitializeDriveForUse
61%endif
62
63
64;--------------------------------------------------------------------
65; Initialize drive to be ready for use.
66;
67; AH9h_InitializeDriveForUse
68;   Parameters:
69;       DS:DI:  Ptr to DPT (in RAMVARS segment)
70;       SS:BP:  Ptr to IDEPACK
71;   Returns:
72;       AH:     Int 13h return status
73;       CF:     0 if successful, 1 if error
74;   Corrupts registers:
75;       AL, BX, CX, DX
76;--------------------------------------------------------------------
77AH9h_InitializeDriveForUse:
78    xor     ax, ax              ; Clear AH to assume no errors
79
80%ifdef MODULE_ADVANCED_ATA
81    ; Clear Initialization Error flags from DPT
82    mov     [di+DPT.bInitError], al
83%endif
84
85%ifdef MODULE_SERIAL
86    ; No need to do this for serial devices
87    test    BYTE [di+DPT.bFlagsHigh], FLGH_DPT_SERIAL_DEVICE    ; Clears CF
88    jz      SHORT .ContinueInitialization
89    ret     ; With AH and CF cleared
90.ContinueInitialization:
91%endif
92
93    push    es
94    push    si
95
96
97;;; SelectDrive
98    ; Try to select drive and wait until ready
99    call    AccessDPT_GetDriveSelectByteForOldInt13hToAL
100    mov     [bp+IDEPACK.bDrvAndHead], al
101    call    Device_SelectDrive
102    STORE_ERROR_FLAG_TO_DPT     FLG_INITERROR_FAILED_TO_SELECT_DRIVE
103    jnc     SHORT .ContinueInitializationSinceDriveSelectedSuccesfully
104    jmp     .ReturnWithErrorCodeInAH
105.ContinueInitializationSinceDriveSelectedSuccesfully:
106
107
108;;; Set XT-CF mode
109%ifdef MODULE_8BIT_IDE
110    call    AccessDPT_GetIdevarsToCSBX
111    mov     al, [cs:bx+IDEVARS.bXTCFcontrolRegister]
112    call    AH9h_SetModeFromALtoXTCF
113    STORE_ERROR_FLAG_TO_DPT     FLG_INITERROR_FAILED_TO_SET_XTCF_MODE
114.DoNotSetXTCFmode:
115
116
117;;; Set 8-bit PIO mode
118    call    AH9h_Enable8bitModeForDevice8bitAta
119    STORE_ERROR_FLAG_TO_DPT     FLG_INITERROR_FAILED_TO_SET_8BIT_MODE
120.DoNotSet8bitMode:
121%endif ; MODULE_8BIT_IDE
122
123
124;;; InitializeDeviceParameters
125    ; Initialize CHS parameters if LBA is not used and
126    ; user has specified P-CHS parameters
127    test    BYTE [di+DPT.bFlagsLow], FLGL_DPT_ASSISTED_LBA
128    jnz     SHORT .SkipInitializeDeviceParameters       ; No need to initialize CHS parameters if LBA mode enabled
129    call    AccessDPT_GetPointerToDRVPARAMStoCSBX
130    test    BYTE [cs:bx+DRVPARAMS.wFlags], FLG_DRVPARAMS_USERCHS    ; User specified P-CHS?
131    jz      SHORT .SkipInitializeDeviceParameters
132
133    ; Initialize Logical Sectors per Track and Max Head number
134    mov     ax, [cs:bx+DRVPARAMS.wHeadsAndSectors]
135    dec     ax                          ; Max Head number
136    xchg    al, ah                      ; Heads now in AH
137    mov     dx, ax                      ; Sectors per Track now in DL
138    mov     al, COMMAND_INITIALIZE_DEVICE_PARAMETERS
139    mov     bx, TIMEOUT_AND_STATUS_TO_WAIT(TIMEOUT_BSY, FLG_STATUS_BSY)
140    call    Idepack_StoreNonExtParametersAndIssueCommandFromAL
141    STORE_ERROR_FLAG_TO_DPT     FLG_INITERROR_FAILED_TO_INITIALIZE_CHS_PARAMETERS
142.SkipInitializeDeviceParameters:
143
144
145;;; SetWriteCache
146    ; Enable or Disable Write Cache
147    call    AccessDPT_GetPointerToDRVPARAMStoCSBX
148    mov     bl, [cs:bx+DRVPARAMS.wFlags]
149    push    bx  ; Save .wFlags for later use in InitializeBlockMode
150    and     bx, BYTE MASK_DRVPARAMS_WRITECACHE
151    jz      SHORT .SkipSetWriteCache        ; DEFAULT_WRITE_CACHE
152    mov     si, [cs:bx+.rgbWriteCacheCommands]
153    call    AH23h_SetControllerFeatures
154    STORE_ERROR_FLAG_TO_DPT     FLG_INITERROR_FAILED_TO_SET_WRITE_CACHE
155.SkipSetWriteCache:
156
157
158;;; RecalibrateDrive
159    ; Recalibrate drive by seeking to cylinder 0
160    call    AH11h_RecalibrateDrive
161    STORE_ERROR_FLAG_TO_DPT     FLG_INITERROR_FAILED_TO_RECALIBRATE_DRIVE
162
163
164;;; InitializeBlockMode
165    ; Initialize block mode transfers
166    pop     ax  ; Restore .wFlags saved in SetWriteCache
167    test    BYTE [di+DPT.bFlagsHigh], FLGH_DPT_BLOCK_MODE_SUPPORTED
168    jz      SHORT .BlockModeNotSupportedOrDisabled
169    test    al, FLG_DRVPARAMS_BLOCKMODE
170    jz      SHORT .BlockModeNotSupportedOrDisabled
171
172    ; Try block sizes until we find largest possible supported by drive
173    mov     bl, 128
174.TryNextBlockSize:
175    mov     al, bl
176    call    AH24h_SetBlockSize  ; Stores block size to DPT
177    jnc     SHORT .SupportedBlockSizeFound
178    shr     bl, 1
179    jnc     SHORT .TryNextBlockSize
180    STORE_ERROR_FLAG_TO_DPT     FLG_INITERROR_FAILED_TO_SET_BLOCK_MODE
181.BlockModeNotSupportedOrDisabled:
182.SupportedBlockSizeFound:
183
184
185%ifdef MODULE_ADVANCED_ATA
186;;; InitializePioMode
187    ; Initialize fastest supported PIO mode
188    mov     dl, PIO_DEFAULT_MODE_DISABLE_IORDY
189    test    BYTE [di+DPT.bFlagsHigh], FLGH_DPT_IORDY
190    jz      SHORT .IordyNotSupported
191
192    ; Advanced PIO mode 3 and above
193    mov     dl, [di+DPT_ADVANCED_ATA.bPioMode]
194    or      dl, PIO_FLOW_CONTROL_MODE_xxx
195
196.IordyNotSupported:
197    mov     si, FEATURE_SET_TRANSFER_MODE
198    call    AH23h_SetControllerFeatures
199    STORE_ERROR_FLAG_TO_DPT     FLG_INITERROR_FAILED_TO_SET_PIO_MODE
200%endif ; MODULE_ADVANCED_ATA
201
202
203%ifdef MODULE_FEATURE_SETS
204;;; InitStandbyTimer
205    ; Initialize the standby timer (if supported)
206    test    BYTE [di+DPT.bFlagsHigh], FLGH_DPT_POWER_MANAGEMENT_SUPPORTED
207    jz      SHORT .NoPowerManagementSupport
208
209    mov     al, COMMAND_IDLE
210    mov     dl, [cs:ROMVARS.bIdleTimeout]
211    mov     bx, TIMEOUT_AND_STATUS_TO_WAIT(TIMEOUT_BSY, FLG_STATUS_BSY)
212    call    Idepack_StoreNonExtParametersAndIssueCommandFromAL
213    STORE_ERROR_FLAG_TO_DPT     FLG_INITERROR_FAILED_TO_INITIALIZE_STANDBY_TIMER
214.NoPowerManagementSupport:
215%endif ; MODULE_FEATURE_SETS
216
217
218    ; There might have been several errors so just return one error code for them all
219.ReturnWithErrorCodeInAH:
220%ifdef MODULE_ADVANCED_ATA
221    mov     ah, [di+DPT.bInitError]
222    test    ah, ah  ; Clears CF
223    jz      SHORT .ReturnWithSuccess
224    mov     ah, RET_HD_RESETFAIL
225    stc
226.ReturnWithSuccess:
227%endif
228
229    pop     si
230    pop     es
231    ret
232
233
234.rgbWriteCacheCommands:
235    db      0                               ; DEFAULT_WRITE_CACHE
236    db      FEATURE_DISABLE_WRITE_CACHE     ; DISABLE_WRITE_CACHE
237    db      FEATURE_ENABLE_WRITE_CACHE      ; ENABLE_WRITE_CACHE
238
239
240
241;--------------------------------------------------------------------
242; SetErrorFlagFromALwithErrorCodeInAH
243;   Parameters:
244;       AH:     BIOS Error Code
245;       AL:     Error flag to set
246;       DS:DI:  Ptr to DPT
247;       CF:     Set if error code in AH
248;               Clear if AH = 0
249;   Returns:
250;       CF:     Clear if no error
251;               Set if error flag was set
252;   Corrupts registers:
253;       Nothing
254;--------------------------------------------------------------------
255IgnoreInvalidCommandError:
256    xor     ah, ah  ; Clears CF
257SetErrorFlagFromALwithErrorCodeInAH:
258    jnc     SHORT .NoErrorFlagToSet
259    cmp     ah, RET_HD_INVALID
260    jbe     SHORT IgnoreInvalidCommandError
261
262    or      [di+DPT.bInitError], al
263    stc
264.NoErrorFlagToSet:
265    ret
266
267
268%ifdef MODULE_8BIT_IDE
269;--------------------------------------------------------------------
270; AH9h_SetModeFromALtoXTCF
271;   Parameters:
272;       AL:     XT-CF Mode to set
273;       DS:DI:  Ptr to DPT (in RAMVARS segment)
274;       SS:BP:  Ptr to IDEPACK
275;   Returns:
276;       AH:     Int 13h return status
277;       CF:     Clear if successful or device is not XT-CF
278;               Set if failed to set mode for XT-CF
279;   Corrupts registers:
280;       AL, BX, CX, DX, SI
281;--------------------------------------------------------------------
282AH9h_SetModeFromALtoXTCF:
283    call    AccessDPT_IsThisDeviceXTCF
284    jne     SHORT IgnoreInvalidCommandError
285    jmp     AH1Eh_ChangeXTCFmodeBasedOnControlRegisterInAL
286
287
288;--------------------------------------------------------------------
289; AH9h_Enable8bitModeForDevice8bitAta
290;   Parameters:
291;       DS:DI:  Ptr to DPT (in RAMVARS segment)
292;       SS:BP:  Ptr to IDEPACK
293;   Returns:
294;       AH:     Int 13h return status
295;       CF:     Clear if successful or device is not DEVICE_8BIT_ATA
296;               Set if failed to set 8-bit mode for DEVICE_8BIT_ATA
297;   Corrupts registers:
298;       AL, BX, CX, DX, SI
299;--------------------------------------------------------------------
300AH9h_Enable8bitModeForDevice8bitAta:
301    cmp     BYTE [di+DPT_ATA.bDevice], DEVICE_8BIT_ATA
302    jne     SHORT IgnoreInvalidCommandError
303    jmp     AH23h_Enable8bitPioMode
304%endif ; MODULE_8BIT_IDE
Note: See TracBrowser for help on using the repository browser.