| 1 | ; Project name : XTIDE Universal BIOS
|
|---|
| 2 | ; Description : Int 13h function AH=9h, Initialize Drive Parameters.
|
|---|
| 3 |
|
|---|
| 4 | ;
|
|---|
| 5 | ; XTIDE Universal BIOS and Associated Tools
|
|---|
| 6 | ; Copyright (C) 2009-2010 by Tomi Tilli, 2011-2012 by XTIDE Universal BIOS Team.
|
|---|
| 7 | ;
|
|---|
| 8 | ; This program is free software; you can redistribute it and/or modify
|
|---|
| 9 | ; it under the terms of the GNU General Public License as published by
|
|---|
| 10 | ; the Free Software Foundation; either version 2 of the License, or
|
|---|
| 11 | ; (at your option) any later version.
|
|---|
| 12 | ;
|
|---|
| 13 | ; This program is distributed in the hope that it will be useful,
|
|---|
| 14 | ; but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|---|
| 15 | ; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|---|
| 16 | ; GNU General Public License for more details.
|
|---|
| 17 | ; Visit http://www.gnu.org/licenses/old-licenses/gpl-2.0.html
|
|---|
| 18 | ;
|
|---|
| 19 |
|
|---|
| 20 | ; Section containing code
|
|---|
| 21 | SECTION .text
|
|---|
| 22 |
|
|---|
| 23 | ;--------------------------------------------------------------------
|
|---|
| 24 | ; STORE_ERROR_FLAG_TO_DPT
|
|---|
| 25 | ; Parameters:
|
|---|
| 26 | ; %1: Error flag to set
|
|---|
| 27 | ; AH: BIOS Error Code
|
|---|
| 28 | ; DS:DI: Ptr to DPT
|
|---|
| 29 | ; CF: Set if error code in AH
|
|---|
| 30 | ; Returns:
|
|---|
| 31 | ; CF: Clear if no error
|
|---|
| 32 | ; Set if error flag was set
|
|---|
| 33 | ; Corrupts registers:
|
|---|
| 34 | ; Nothing
|
|---|
| 35 | ;--------------------------------------------------------------------
|
|---|
| 36 | %macro STORE_ERROR_FLAG_TO_DPT 1
|
|---|
| 37 | mov al, %1
|
|---|
| 38 | call SetErrorFlagFromALwithErrorCodeInAH
|
|---|
| 39 | %endmacro
|
|---|
| 40 |
|
|---|
| 41 |
|
|---|
| 42 | ;--------------------------------------------------------------------
|
|---|
| 43 | ; Int 13h function AH=9h, Initialize Drive Parameters.
|
|---|
| 44 | ;
|
|---|
| 45 | ; AH9h_HandlerForInitializeDriveParameters
|
|---|
| 46 | ; Parameters:
|
|---|
| 47 | ; DL: Translated Drive number
|
|---|
| 48 | ; DS:DI: Ptr to DPT (in RAMVARS segment)
|
|---|
| 49 | ; SS:BP: Ptr to IDEPACK
|
|---|
| 50 | ; Returns with INTPACK:
|
|---|
| 51 | ; AH: Int 13h return status
|
|---|
| 52 | ; CF: 0 if successful, 1 if error
|
|---|
| 53 | ;--------------------------------------------------------------------
|
|---|
| 54 | AH9h_HandlerForInitializeDriveParameters:
|
|---|
| 55 | %ifndef USE_186
|
|---|
| 56 | call AH9h_InitializeDriveForUse
|
|---|
| 57 | jmp Int13h_ReturnFromHandlerAfterStoringErrorCodeFromAH
|
|---|
| 58 | %else
|
|---|
| 59 | push Int13h_ReturnFromHandlerAfterStoringErrorCodeFromAH
|
|---|
| 60 | ; Fall to AH9h_InitializeDriveForUse
|
|---|
| 61 | %endif
|
|---|
| 62 |
|
|---|
| 63 |
|
|---|
| 64 | ;--------------------------------------------------------------------
|
|---|
| 65 | ; Initialize drive to be ready for use.
|
|---|
| 66 | ;
|
|---|
| 67 | ; AH9h_InitializeDriveForUse
|
|---|
| 68 | ; Parameters:
|
|---|
| 69 | ; DS:DI: Ptr to DPT (in RAMVARS segment)
|
|---|
| 70 | ; SS:BP: Ptr to IDEPACK
|
|---|
| 71 | ; Returns:
|
|---|
| 72 | ; AH: Int 13h return status
|
|---|
| 73 | ; CF: 0 if successful, 1 if error
|
|---|
| 74 | ; Corrupts registers:
|
|---|
| 75 | ; AL, BX, CX, DX
|
|---|
| 76 | ;--------------------------------------------------------------------
|
|---|
| 77 | AH9h_InitializeDriveForUse:
|
|---|
| 78 | xor ax, ax ; Clear AH to assume no errors
|
|---|
| 79 |
|
|---|
| 80 | %ifdef MODULE_ADVANCED_ATA
|
|---|
| 81 | ; Clear Initialization Error flags from DPT
|
|---|
| 82 | mov [di+DPT.bInitError], al
|
|---|
| 83 | %endif
|
|---|
| 84 |
|
|---|
| 85 | %ifdef MODULE_SERIAL
|
|---|
| 86 | ; No need to do this for serial devices
|
|---|
| 87 | test BYTE [di+DPT.bFlagsHigh], FLGH_DPT_SERIAL_DEVICE ; Clears CF
|
|---|
| 88 | jz SHORT .ContinueInitialization
|
|---|
| 89 | ret ; With AH and CF cleared
|
|---|
| 90 | .ContinueInitialization:
|
|---|
| 91 | %endif
|
|---|
| 92 |
|
|---|
| 93 | push es
|
|---|
| 94 | push si
|
|---|
| 95 |
|
|---|
| 96 |
|
|---|
| 97 | ;;; SelectDrive
|
|---|
| 98 | ; Try to select drive and wait until ready
|
|---|
| 99 | call AccessDPT_GetDriveSelectByteForOldInt13hToAL
|
|---|
| 100 | mov [bp+IDEPACK.bDrvAndHead], al
|
|---|
| 101 | call Device_SelectDrive
|
|---|
| 102 | STORE_ERROR_FLAG_TO_DPT FLG_INITERROR_FAILED_TO_SELECT_DRIVE
|
|---|
| 103 | jnc SHORT .ContinueInitializationSinceDriveSelectedSuccesfully
|
|---|
| 104 | jmp .ReturnWithErrorCodeInAH
|
|---|
| 105 | .ContinueInitializationSinceDriveSelectedSuccesfully:
|
|---|
| 106 |
|
|---|
| 107 |
|
|---|
| 108 | ;;; InitializeDeviceParameters
|
|---|
| 109 | ; Initialize CHS parameters if LBA is not used and
|
|---|
| 110 | ; user has specified P-CHS parameters
|
|---|
| 111 | test BYTE [di+DPT.bFlagsLow], FLGL_DPT_ASSISTED_LBA
|
|---|
| 112 | jnz SHORT .SkipInitializeDeviceParameters ; No need to initialize CHS parameters if LBA mode enabled
|
|---|
| 113 | call AccessDPT_GetPointerToDRVPARAMStoCSBX
|
|---|
| 114 | test BYTE [cs:bx+DRVPARAMS.wFlags], FLG_DRVPARAMS_USERCHS ; User specified P-CHS?
|
|---|
| 115 | jz SHORT .SkipInitializeDeviceParameters
|
|---|
| 116 |
|
|---|
| 117 | ; Initialize Logical Sectors per Track and Max Head number
|
|---|
| 118 | mov ax, [cs:bx+DRVPARAMS.wHeadsAndSectors]
|
|---|
| 119 | dec ax ; Max Head number
|
|---|
| 120 | xchg al, ah ; Heads now in AH
|
|---|
| 121 | mov dx, ax ; Sectors per Track now in DL
|
|---|
| 122 | mov al, COMMAND_INITIALIZE_DEVICE_PARAMETERS
|
|---|
| 123 | mov bx, TIMEOUT_AND_STATUS_TO_WAIT(TIMEOUT_BSY, FLG_STATUS_BSY)
|
|---|
| 124 | call Idepack_StoreNonExtParametersAndIssueCommandFromAL
|
|---|
| 125 | STORE_ERROR_FLAG_TO_DPT FLG_INITERROR_FAILED_TO_INITIALIZE_CHS_PARAMETERS
|
|---|
| 126 | .SkipInitializeDeviceParameters:
|
|---|
| 127 |
|
|---|
| 128 |
|
|---|
| 129 | %ifdef MODULE_8BIT_IDE
|
|---|
| 130 | ;;; Enable 8-bit PIO Transfer Mode for Lo-tech XT-CF (CF and Microdrives only)
|
|---|
| 131 | call AH9h_Enable8bitPioModeForXTCF
|
|---|
| 132 | STORE_ERROR_FLAG_TO_DPT FLG_INITERROR_FAILED_TO_ENABLE_8BIT_PIO_MODE
|
|---|
| 133 | %endif
|
|---|
| 134 |
|
|---|
| 135 |
|
|---|
| 136 | ;;; SetWriteCache
|
|---|
| 137 | ; Enable or Disable Write Cache
|
|---|
| 138 | call AccessDPT_GetPointerToDRVPARAMStoCSBX
|
|---|
| 139 | mov bl, [cs:bx+DRVPARAMS.wFlags]
|
|---|
| 140 | push bx ; Save .wFlags for later use in InitializeBlockMode
|
|---|
| 141 | and bx, BYTE MASK_DRVPARAMS_WRITECACHE
|
|---|
| 142 | jz SHORT .SkipSetWriteCache ; DEFAULT_WRITE_CACHE
|
|---|
| 143 | mov si, [cs:bx+.rgbWriteCacheCommands]
|
|---|
| 144 | call AH23h_SetControllerFeatures
|
|---|
| 145 | STORE_ERROR_FLAG_TO_DPT FLG_INITERROR_FAILED_TO_SET_WRITE_CACHE
|
|---|
| 146 | .SkipSetWriteCache:
|
|---|
| 147 |
|
|---|
| 148 |
|
|---|
| 149 | ;;; RecalibrateDrive
|
|---|
| 150 | ; Recalibrate drive by seeking to cylinder 0
|
|---|
| 151 | call AH11h_RecalibrateDrive
|
|---|
| 152 | STORE_ERROR_FLAG_TO_DPT FLG_INITERROR_FAILED_TO_RECALIBRATE_DRIVE
|
|---|
| 153 |
|
|---|
| 154 |
|
|---|
| 155 | ;;; InitializeBlockMode
|
|---|
| 156 | ; Initialize block mode transfers
|
|---|
| 157 | pop ax ; Restore .wFlags saved in SetWriteCache
|
|---|
| 158 | test BYTE [di+DPT.bFlagsHigh], FLGH_DPT_BLOCK_MODE_SUPPORTED
|
|---|
| 159 | jz SHORT .BlockModeNotSupportedOrDisabled
|
|---|
| 160 | test al, FLG_DRVPARAMS_BLOCKMODE
|
|---|
| 161 | jz SHORT .BlockModeNotSupportedOrDisabled
|
|---|
| 162 |
|
|---|
| 163 | ; Try block sizes until we find largest possible supported by drive
|
|---|
| 164 | mov bl, 128
|
|---|
| 165 | .TryNextBlockSize:
|
|---|
| 166 | mov al, bl
|
|---|
| 167 | call AH24h_SetBlockSize ; Stores block size to DPT
|
|---|
| 168 | jnc SHORT .SupportedBlockSizeFound
|
|---|
| 169 | shr bl, 1
|
|---|
| 170 | jnc SHORT .TryNextBlockSize
|
|---|
| 171 | STORE_ERROR_FLAG_TO_DPT FLG_INITERROR_FAILED_TO_SET_BLOCK_MODE
|
|---|
| 172 | .BlockModeNotSupportedOrDisabled:
|
|---|
| 173 | .SupportedBlockSizeFound:
|
|---|
| 174 |
|
|---|
| 175 |
|
|---|
| 176 | %ifdef MODULE_ADVANCED_ATA
|
|---|
| 177 | ;;; InitializePioMode
|
|---|
| 178 | ; Initialize fastest supported PIO mode
|
|---|
| 179 | mov dl, PIO_DEFAULT_MODE_DISABLE_IORDY
|
|---|
| 180 | test BYTE [di+DPT.bFlagsHigh], FLGH_DPT_IORDY
|
|---|
| 181 | jz SHORT .IordyNotSupported
|
|---|
| 182 |
|
|---|
| 183 | ; Advanced PIO mode 3 and above
|
|---|
| 184 | mov dl, [di+DPT_ADVANCED_ATA.bPioMode]
|
|---|
| 185 | or dl, PIO_FLOW_CONTROL_MODE_xxx
|
|---|
| 186 |
|
|---|
| 187 | .IordyNotSupported:
|
|---|
| 188 | mov si, FEATURE_SET_TRANSFER_MODE
|
|---|
| 189 | call AH23h_SetControllerFeatures
|
|---|
| 190 | STORE_ERROR_FLAG_TO_DPT FLG_INITERROR_FAILED_TO_SET_PIO_MODE
|
|---|
| 191 | %endif ; MODULE_ADVANCED_ATA
|
|---|
| 192 |
|
|---|
| 193 |
|
|---|
| 194 | %ifdef MODULE_FEATURE_SETS
|
|---|
| 195 | ;;; InitStandbyTimer
|
|---|
| 196 | ; Initialize the standby timer (if supported)
|
|---|
| 197 | test BYTE [di+DPT.bFlagsHigh], FLGH_DPT_POWER_MANAGEMENT_SUPPORTED
|
|---|
| 198 | jz SHORT .NoPowerManagementSupport
|
|---|
| 199 |
|
|---|
| 200 | mov al, COMMAND_IDLE
|
|---|
| 201 | mov dl, [cs:ROMVARS.bIdleTimeout]
|
|---|
| 202 | mov bx, TIMEOUT_AND_STATUS_TO_WAIT(TIMEOUT_BSY, FLG_STATUS_BSY)
|
|---|
| 203 | call Idepack_StoreNonExtParametersAndIssueCommandFromAL
|
|---|
| 204 | STORE_ERROR_FLAG_TO_DPT FLG_INITERROR_FAILED_TO_INITIALIZE_STANDBY_TIMER
|
|---|
| 205 | .NoPowerManagementSupport:
|
|---|
| 206 | %endif ; MODULE_FEATURE_SETS
|
|---|
| 207 |
|
|---|
| 208 |
|
|---|
| 209 | ; There might have been several errors so just return one error code for them all
|
|---|
| 210 | .ReturnWithErrorCodeInAH:
|
|---|
| 211 | %ifdef MODULE_ADVANCED_ATA
|
|---|
| 212 | mov ah, [di+DPT.bInitError]
|
|---|
| 213 | test ah, ah ; Clears CF
|
|---|
| 214 | jz SHORT .ReturnWithSuccess
|
|---|
| 215 | mov ah, RET_HD_RESETFAIL
|
|---|
| 216 | stc
|
|---|
| 217 | .ReturnWithSuccess:
|
|---|
| 218 | %endif
|
|---|
| 219 |
|
|---|
| 220 | pop si
|
|---|
| 221 | pop es
|
|---|
| 222 | ret
|
|---|
| 223 |
|
|---|
| 224 |
|
|---|
| 225 | .rgbWriteCacheCommands:
|
|---|
| 226 | db 0 ; DEFAULT_WRITE_CACHE
|
|---|
| 227 | db FEATURE_DISABLE_WRITE_CACHE ; DISABLE_WRITE_CACHE
|
|---|
| 228 | db FEATURE_ENABLE_WRITE_CACHE ; ENABLE_WRITE_CACHE
|
|---|
| 229 |
|
|---|
| 230 |
|
|---|
| 231 |
|
|---|
| 232 | ;--------------------------------------------------------------------
|
|---|
| 233 | ; SetErrorFlagFromALwithErrorCodeInAH
|
|---|
| 234 | ; Parameters:
|
|---|
| 235 | ; AH: BIOS Error Code
|
|---|
| 236 | ; AL: Error flag to set
|
|---|
| 237 | ; DS:DI: Ptr to DPT
|
|---|
| 238 | ; CF: Set if error code in AH
|
|---|
| 239 | ; Clear if AH = 0
|
|---|
| 240 | ; Returns:
|
|---|
| 241 | ; CF: Clear if no error
|
|---|
| 242 | ; Set if error flag was set
|
|---|
| 243 | ; Corrupts registers:
|
|---|
| 244 | ; Nothing
|
|---|
| 245 | ;--------------------------------------------------------------------
|
|---|
| 246 | IgnoreInvalidCommandError:
|
|---|
| 247 | xor ah, ah ; Clears CF
|
|---|
| 248 | SetErrorFlagFromALwithErrorCodeInAH:
|
|---|
| 249 | jnc SHORT .NoErrorFlagToSet
|
|---|
| 250 | cmp ah, RET_HD_INVALID
|
|---|
| 251 | jbe SHORT IgnoreInvalidCommandError
|
|---|
| 252 |
|
|---|
| 253 | or [di+DPT.bInitError], al
|
|---|
| 254 | stc
|
|---|
| 255 | .NoErrorFlagToSet:
|
|---|
| 256 | ret
|
|---|
| 257 |
|
|---|
| 258 |
|
|---|
| 259 | %ifdef MODULE_8BIT_IDE
|
|---|
| 260 | ;--------------------------------------------------------------------
|
|---|
| 261 | ; AH9h_Enable8bitPioModeForXTCF
|
|---|
| 262 | ; Parameters:
|
|---|
| 263 | ; DS:DI: Ptr to DPT
|
|---|
| 264 | ; Returns:
|
|---|
| 265 | ; AH: Int 13h return status
|
|---|
| 266 | ; CF: 0 if successful, 1 if error
|
|---|
| 267 | ; Corrupts registers:
|
|---|
| 268 | ; AL, BX, CX, DX, SI
|
|---|
| 269 | ;--------------------------------------------------------------------
|
|---|
| 270 | AH9h_Enable8bitPioModeForXTCF:
|
|---|
| 271 | eMOVZX bx, BYTE [di+DPT.bIdevarsOffset]
|
|---|
| 272 | cmp BYTE [cs:bx+IDEVARS.bDevice], DEVICE_8BIT_XTCF
|
|---|
| 273 | je SHORT .Enable8bitMode
|
|---|
| 274 | xor ah, ah ; Do nothing for this device
|
|---|
| 275 | ret
|
|---|
| 276 | .Enable8bitMode:
|
|---|
| 277 | mov si, FEATURE_ENABLE_8BIT_PIO_TRANSFER_MODE
|
|---|
| 278 | jmp AH23h_SetControllerFeatures
|
|---|
| 279 | %endif ; MODULE_8BIT_IDE
|
|---|
