Changeset 542 in xtideuniversalbios for trunk/XTIDE_Universal_BIOS/Src/Initialization

Timestamp:

Apr 15, 2013, 4:03:33 PM (12 years ago)

Author:

aitotat@…

google:author:

aitotat@gmail.com

Message:

Changes to XTIDE Universal BIOS:

• Fixed a bug that allowed EBIOS functions for user defined CHS.
• Simplified user defined CHS and LBA setup a little.

Location:

trunk/XTIDE_Universal_BIOS/Src/Initialization

Files:

• AdvancedAta/Vision.asm (modified) (3 diffs)
• AtaID.asm (modified) (1 diff)
• Initialize.asm (modified) (1 diff)

trunk/XTIDE_Universal_BIOS/Src/Initialization/AdvancedAta/Vision.asm

@@ -41 +41 @@
     in      al, QD65XX_BASE_PORT + QD65XX_CONFIG_REGISTER_in
 
-%if 0
+%ifdef DANGEROUS_DETECTION
     ; Checking alternative base port is currently commented away
     ; since Intel PIIX4 south bridge mirrors Interrupt Controller registers
@@ -51 +51 @@
     or      dl, QD65XX_ALTERNATIVE_BASE_PORT
     in      al, QD65XX_ALTERNATIVE_BASE_PORT + QD65XX_CONFIG_REGISTER_in
-%endif ; 0
+%endif ; DANGEROUS_DETECTION
     ; Fall to IsConfigRegisterWithIDinAL
 
@@ -65 +65 @@
 ;       Nothing
 ;--------------------------------------------------------------------
-;IsConfigRegisterWithIDinAL:
+IsConfigRegisterWithIDinAL:
     mov     ah, al
     and     al, MASK_QDCONFIG_CONTROLLER_ID

trunk/XTIDE_Universal_BIOS/Src/Initialization/AtaID.asm

@@ -95 +95 @@
 
 
+;--------------------------------------------------------------------
+; Writes user defined limits from ROMVARS to ATA ID read from the drive.
+; Modifying the ATA ID reduces code and possibilites for bugs since
+; only little furher checks are needed elsewhere.
+;
+; AtaID_ModifyESSIforUserDefinedLimitsAndReturnTranslateModeInDX
+;   Parameters:
+;       DS:DI:  Ptr to incomplete Disk Parameter Table
+;       ES:SI:  Ptr to 512-byte ATA information read from the drive
+;       CS:BP:  Ptr to IDEVARS for the controller
+;   Returns:
+;       DX:     User defined P-CHS to L-CHS translate mode
+;   Corrupts registers:
+;       AX, BX, CX
+;--------------------------------------------------------------------
+AtaID_ModifyESSIforUserDefinedLimitsAndReturnTranslateModeInDX:
+    call    AccessDPT_GetPointerToDRVPARAMStoCSBX
+    push    ds
+    push    es
+    pop     ds      ; DS:SI now points to ATA information
+
+    ; Load User Defined CHS or LBA to CX:AX
+    mov     dx, [cs:bx+DRVPARAMS.wFlags]
+    mov     ax, [cs:bx+DRVPARAMS.wCylinders]        ; Or .dwMaximumLBA
+    mov     cx, [cs:bx+DRVPARAMS.wHeadsAndSectors]  ; Or .dwMaximumLBA+2
+
+    ; * User defined CHS *
+    test    dl, FLG_DRVPARAMS_USERCHS
+    jz      SHORT .NoUserDefinedCHS
+
+    ; Apply new CHS and disable LBA (we also want to set CHS addressing)
+    mov     [si+ATA1.wCylCnt], ax
+    eMOVZX  ax, cl
+    mov     [si+ATA1.wHeadCnt], ax
+    mov     al, ch
+    mov     [si+ATA1.wSPT], ax
+    and     BYTE [si+ATA1.wCaps+1], ~(A1_wCaps_LBA>>8)
+    and     BYTE [si+ATA6.wSetSup83+1], ~(A6_wSetSup83_LBA48>>8)
+.NoUserDefinedCHS:
+
+    ; * User defined LBA *
+    test    dl, FLG_DRVPARAMS_USERLBA
+    jz      SHORT .NoUserDefinedLBA
+
+    ; Apply new LBA and disable LBA48
+    cmp     cx, [si+ATA1.dwLBACnt+2]
+    ja      SHORT .NoUserDefinedLBA     ; Do not set larger than drive
+    jb      SHORT .StoreNewLBA
+    cmp     ax, [si+ATA1.dwLBACnt]
+    ja      SHORT .NoUserDefinedLBA     ; Allow same size to disable LBA48
+.StoreNewLBA:
+    mov     [si+ATA1.dwLBACnt], ax
+    mov     [si+ATA1.dwLBACnt+2], cx
+    and     BYTE [si+ATA6.wSetSup83+1], ~(A6_wSetSup83_LBA48>>8)
+.NoUserDefinedLBA:
+
+    ; * Disable Block Mode transfers *
+    test    dl, FLG_DRVPARAMS_BLOCKMODE
+    jnz     SHORT .NoNeedToDisableBlockMode
+    mov     BYTE [si+ATA1.bBlckSize], 1 ; sectors
+.NoNeedToDisableBlockMode:
+
+    ; * Load P-CHS to L-CHS translate mode to DX *
+    and     dx, BYTE MASK_DRVPARAMS_TRANSLATEMODE
+    eSHR_IM dx, TRANSLATEMODE_FIELD_POSITION
+
+    pop     ds
+    ret
+
+
 %ifdef MODULE_ADVANCED_ATA
 ;--------------------------------------------------------------------

trunk/XTIDE_Universal_BIOS/Src/Initialization/Initialize.asm

@@ -95 +95 @@
 ;--------------------------------------------------------------------
 .StoreDptPointersToIntVectors:
+%ifndef USE_AT
+    test    BYTE [cs:ROMVARS.wFlags], FLG_ROMVARS_FULLMODE
+    jz      SHORT .CompatibleDPTsCreated    ; Only Full operating mode has extra RAM to spare
+%endif
+
     mov     dl, 80h
     call    FindDPT_ForDriveNumberInDL  ; DPT to DS:DI