source: xtideuniversalbios/trunk/XTIDE_Universal_BIOS/Src/VariablesAndDPTs/RamVars.asm @ 623

Last change on this file since 623 was 623, checked in by krille_n_, 22 months ago

Changes:

  • Reversed the change to IdeDPT.asm in r622 as it didn't work as intended.
  • Reordered some procedures to reduce alignment padding.
  • Added two new defines (EXTRA_LOOP_UNROLLING_SMALL and EXTRA_LOOP_UNROLLING_LARGE) that should improve transfer speeds for some hardware combinations, specifically 808x CPUs with any IDE controller using port I/O and any CPU with XT-IDE controllers.
  • Added a new define (USE_086) for use with 8086 and V30 CPUs only. Unlike the other USE_x86 defines, this define will not change the instruction set used and is therefore compatible with all CPUs. However, it will apply padding to make jump destinations WORD aligned which should improve performance on 8086/V30 CPUs but on 8088/V20 CPUs there is no benefit and, in addition to wasting ROM space, it might in fact be slower on these machines. Since the vast majority of XT class machines are using 8088/V20 CPUs this define is not used in the official XT builds - it's primarily intended for custom BIOS builds.
  • XTIDECFG: The URL to the support forum has been updated.
File size: 5.1 KB
Line 
1; Project name  :   XTIDE Universal BIOS
2; Description   :   Functions for accessings RAMVARS.
3
4;
5; XTIDE Universal BIOS and Associated Tools
6; Copyright (C) 2009-2010 by Tomi Tilli, 2011-2013 by XTIDE Universal BIOS Team.
7;
8; This program is free software; you can redistribute it and/or modify
9; it under the terms of the GNU General Public License as published by
10; the Free Software Foundation; either version 2 of the License, or
11; (at your option) any later version.
12;
13; This program is distributed in the hope that it will be useful,
14; but WITHOUT ANY WARRANTY; without even the implied warranty of
15; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
16; GNU General Public License for more details.
17; Visit http://www.gnu.org/licenses/old-licenses/gpl-2.0.html
18;
19
20; Section containing code
21SECTION .text
22
23;--------------------------------------------------------------------
24; Initializes RAMVARS.
25; Drive detection can be started after this function returns.
26;
27; RamVars_Initialize
28;   Parameters:
29;       Nothing
30;   Returns:
31;       DS:     RAMVARS segment
32;   Corrupts registers:
33;       AX, CX, DX, DI
34;--------------------------------------------------------------------
35RamVars_Initialize:
36    push    es
37
38%ifndef USE_AT
39    mov     ax, LITE_MODE_RAMVARS_SEGMENT
40    test    BYTE [cs:ROMVARS.wFlags], FLG_ROMVARS_FULLMODE
41    jz      SHORT .InitializeRamvars    ; No need to steal RAM
42%endif
43
44    LOAD_BDA_SEGMENT_TO ds, ax, !       ; Zero AX
45    mov     al, [cs:ROMVARS.bStealSize]
46    sub     [BDA.wBaseMem], ax
47%ifdef USE_186
48    imul    ax, [BDA.wBaseMem], 64
49%else
50    mov     al, 64
51    mul     WORD [BDA.wBaseMem]
52%endif
53
54.InitializeRamvars:
55    xor     di, di
56    mov     ds, ax
57    mov     es, ax
58    mov     cx, RAMVARS_size
59    call    Memory_ZeroESDIwithSizeInCX
60    mov     WORD [RAMVARS.wDrvDetectSignature], RAMVARS_DRV_DETECT_SIGNATURE
61    mov     WORD [RAMVARS.wSignature], RAMVARS_RAM_SIGNATURE
62%ifdef MODULE_DRIVEXLATE
63    call    DriveXlate_Reset
64%endif
65
66    pop     es
67    ret
68
69;--------------------------------------------------------------------
70; Returns segment to RAMVARS.
71; RAMVARS might be located at the top of interrupt vectors (0030:0000h)
72; or at the top of system base RAM.
73;
74; RamVars_GetSegmentToDS
75;   Parameters:
76;       Nothing
77;   Returns:
78;       DS:     RAMVARS segment
79;   Corrupts registers:
80;       DI
81;--------------------------------------------------------------------
82ALIGN JUMP_ALIGN
83RamVars_GetSegmentToDS:
84
85%ifndef USE_AT  ; Always in Full Mode for AT builds
86    test    BYTE [cs:ROMVARS.wFlags], FLG_ROMVARS_FULLMODE
87    jnz     SHORT .GetStolenSegmentToDS
88    %ifndef USE_186
89        mov     di, LITE_MODE_RAMVARS_SEGMENT
90        mov     ds, di
91    %else
92        push    LITE_MODE_RAMVARS_SEGMENT
93        pop     ds
94    %endif
95    ret
96%endif
97
98ALIGN JUMP_ALIGN
99.GetStolenSegmentToDS:
100    LOAD_BDA_SEGMENT_TO ds, di
101;%ifdef USE_186
102;   imul    di, [BDA.wBaseMem], 64  ; 2 bytes less but slower, especially on 386/486 processors
103;%else
104    mov     di, [BDA.wBaseMem]      ; Load available base memory size in kB
105    eSHL_IM di, 6                   ; Segment to first stolen kB (*=40h)
106;%endif
107ALIGN JUMP_ALIGN
108.LoopStolenKBs:
109    mov     ds, di                  ; EBDA segment to DS
110    add     di, BYTE 64             ; DI to next stolen kB
111    cmp     WORD [RAMVARS.wSignature], RAMVARS_RAM_SIGNATURE
112    jne     SHORT .LoopStolenKBs    ; Loop until sign found (always found eventually)
113    ret
114
115
116;--------------------------------------------------------------------
117; RamVars_GetHardDiskCountFromBDAtoAX
118;   Parameters:
119;       DS:     RAMVARS segment
120;   Returns:
121;       AX:     Total hard disk count
122;   Corrupts registers:
123;       BX
124;--------------------------------------------------------------------
125%ifdef MODULE_BOOT_MENU
126RamVars_GetHardDiskCountFromBDAtoAX:
127    call    RamVars_GetCountOfKnownDrivesToAX
128    push    ds
129    LOAD_BDA_SEGMENT_TO ds, bx
130    mov     bl, [BDA.bHDCount]
131    MAX_U   al, bl
132    pop     ds
133    ret
134%endif
135
136
137%ifdef MODULE_SERIAL_FLOPPY
138;--------------------------------------------------------------------
139; RamVars_UnpackFlopCntAndFirstToAL
140;   Parameters:
141;       DS:     RAMVARS segment
142;   Returns:
143;       AL:     First floppy drive number supported
144;       CF:     Number of floppy drives supported (clear = 1, set = 2)
145;       SF:     Emulating drives (clear = yes, set = no)
146;   Corrupts registers:
147;       Nothing
148;--------------------------------------------------------------------
149ALIGN JUMP_ALIGN
150RamVars_UnpackFlopCntAndFirstToAL:
151    mov     al, [RAMVARS.xlateVars+XLATEVARS.bFlopCntAndFirst]
152    sar     al, 1
153    ret
154%endif
155
156
157;--------------------------------------------------------------------
158; RamVars_GetIdeControllerCountToCX
159;   Parameters:
160;       Nothing
161;   Returns:
162;       CX:     Number of IDE controllers to handle
163;   Corrupts registers:
164;       Nothing
165;--------------------------------------------------------------------
166ALIGN JUMP_ALIGN
167RamVars_GetIdeControllerCountToCX:
168    eMOVZX  cx, [cs:ROMVARS.bIdeCnt]
169    ret
170
171
172;--------------------------------------------------------------------
173; RamVars_GetCountOfKnownDrivesToAX
174;   Parameters:
175;       DS:     RAMVARS segment
176;   Returns:
177;       AX:     Total hard disk count
178;   Corrupts registers:
179;       None
180;--------------------------------------------------------------------
181ALIGN JUMP_ALIGN
182RamVars_GetCountOfKnownDrivesToAX:
183    mov     ax, [RAMVARS.wFirstDrvAndCount]
184    add     al, ah
185    and     ax, BYTE 7Fh
186    ret
Note: See TracBrowser for help on using the repository browser.