source: xtideuniversalbios/trunk/XTIDE_Universal_BIOS/Src/VariablesAndDPTs/RamVars.asm@ 319

Last change on this file since 319 was 294, checked in by krille_n_@…, 13 years ago

Commit 2/2 (BIOS):

  • Fixed a bug in AH1h_HStatus.asm.
  • Minor optimizations.
  • Fixed spelling and did some cleaning.
File size: 5.0 KB
Line 
1; Project name : XTIDE Universal BIOS
2; Description : Functions for accessings RAMVARS.
3
4; Section containing code
5SECTION .text
6
7;--------------------------------------------------------------------
8; Initializes RAMVARS.
9; Drive detection can be started after this function returns.
10;
11; RamVars_Initialize
12; Parameters:
13; Nothing
14; Returns:
15; DS: RAMVARS segment
16; Corrupts registers:
17; AX, CX, DI
18;--------------------------------------------------------------------
19RamVars_Initialize:
20 push es
21 ; Fall to .StealMemoryForRAMVARS
22
23;--------------------------------------------------------------------
24; .StealMemoryForRAMVARS
25; Parameters:
26; Nothing
27; Returns:
28; DS: RAMVARS segment
29; Corrupts registers:
30; AX
31;--------------------------------------------------------------------
32.StealMemoryForRAMVARS:
33 mov ax, LITE_MODE_RAMVARS_SEGMENT
34 test BYTE [cs:ROMVARS.wFlags], FLG_ROMVARS_FULLMODE
35 jz SHORT .InitializeRamvars ; No need to steal RAM
36
37 LOAD_BDA_SEGMENT_TO ds, ax, ! ; Zero AX
38 mov al, [cs:ROMVARS.bStealSize]
39 sub [BDA.wBaseMem], ax
40 mov ax, [BDA.wBaseMem]
41 eSHL_IM ax, 6 ; Segment to first stolen kB (*=40h)
42 ; Fall to .InitializeRamvars
43
44;--------------------------------------------------------------------
45; .InitializeRamvars
46; Parameters:
47; AX: RAMVARS segment
48; Returns:
49; DS: RAMVARS segment
50; Corrupts registers:
51; AX, CX, DI, ES
52;--------------------------------------------------------------------
53.InitializeRamvars:
54 mov ds, ax
55 mov es, ax
56 mov cx, RAMVARS_size
57 xor di, di
58 call Memory_ZeroESDIwithSizeInCX
59 mov WORD [RAMVARS.wSignature], RAMVARS_SIGNATURE
60 ; Fall to .InitializeDriveTranslationAndReturn
61
62;--------------------------------------------------------------------
63; .InitializeDriveTranslationAndReturn
64; Parameters:
65; DS: RAMVARS segment
66; Returns:
67; Nothing
68; Corrupts registers:
69; AX
70;--------------------------------------------------------------------
71.InitializeDriveTranslationAndReturn:
72 pop es
73 jmp DriveXlate_Reset
74
75
76;--------------------------------------------------------------------
77; Returns segment to RAMVARS.
78; RAMVARS might be located at the top of interrupt vectors (0030:0000h)
79; or at the top of system base RAM.
80;
81; RamVars_GetSegmentToDS
82; Parameters:
83; Nothing
84; Returns:
85; DS: RAMVARS segment
86; Corrupts registers:
87; DI
88;--------------------------------------------------------------------
89ALIGN JUMP_ALIGN
90RamVars_GetSegmentToDS:
91 test BYTE [cs:ROMVARS.wFlags], FLG_ROMVARS_FULLMODE
92 jnz SHORT .GetStolenSegmentToDS
93%ifndef USE_186
94 mov di, LITE_MODE_RAMVARS_SEGMENT
95 mov ds, di
96%else
97 push LITE_MODE_RAMVARS_SEGMENT
98 pop ds
99%endif
100 ret
101
102ALIGN JUMP_ALIGN
103.GetStolenSegmentToDS:
104 LOAD_BDA_SEGMENT_TO ds, di
105 mov di, [BDA.wBaseMem] ; Load available base memory size in kB
106 eSHL_IM di, 6 ; Segment to first stolen kB (*=40h)
107ALIGN JUMP_ALIGN
108.LoopStolenKBs:
109 mov ds, di ; EBDA segment to DS
110 add di, BYTE 64 ; DI to next stolen kB
111 cmp WORD [RAMVARS.wSignature], RAMVARS_SIGNATURE
112 jne SHORT .LoopStolenKBs ; Loop until sign found (always found eventually)
113 ret
114
115
116;--------------------------------------------------------------------
117; RamVars_GetHardDiskCountFromBDAtoAX
118; Parameters:
119; DS: RAMVARS segment
120; Returns:
121; AX: Total hard disk count
122; Corrupts registers:
123; CX
124;--------------------------------------------------------------------
125ALIGN JUMP_ALIGN
126RamVars_GetHardDiskCountFromBDAtoAX:
127 call RamVars_GetCountOfKnownDrivesToAX
128 push ds
129 LOAD_BDA_SEGMENT_TO ds, cx
130 mov cl, [BDA.bHDCount]
131 MAX_U al, cl
132 pop ds
133 ret
134
135;--------------------------------------------------------------------
136; RamVars_GetCountOfKnownDrivesToAX
137; Parameters:
138; DS: RAMVARS segment
139; Returns:
140; AX: Total hard disk count
141; Corrupts registers:
142; None
143;--------------------------------------------------------------------
144ALIGN JUMP_ALIGN
145RamVars_GetCountOfKnownDrivesToAX:
146 mov ax, [RAMVARS.wDrvCntAndFirst]
147 add al, ah
148 and al, 7fh
149 cbw
150 ret
151
152;--------------------------------------------------------------------
153; RamVars_GetIdeControllerCountToCX
154; Parameters:
155; Nothing
156; Returns:
157; CX: Number of IDE controllers to handle
158; Corrupts registers:
159; Nothing
160;--------------------------------------------------------------------
161ALIGN JUMP_ALIGN
162RamVars_GetIdeControllerCountToCX:
163 eMOVZX cx, [cs:ROMVARS.bIdeCnt]
164 ret
165
166%ifdef MODULE_SERIAL_FLOPPY
167;--------------------------------------------------------------------
168; RamVars_UnpackFlopCntAndFirstToAL
169; Parameters:
170; Nothing
171; Returns:
172; AL: First floppy drive number supported
173; CF: Number of floppy drives supported (clear = 1, set = 2)
174; SF: Emulating drives (clear = yes, set = no)
175; Corrupts registers:
176; Nothing
177;--------------------------------------------------------------------
178ALIGN JUMP_ALIGN
179RamVars_UnpackFlopCntAndFirstToAL:
180 mov al, [RAMVARS.xlateVars+XLATEVARS.bFlopCntAndFirst]
181 sar al, 1
182 ret
183%endif
Note: See TracBrowser for help on using the repository browser.