source: xtideuniversalbios/trunk/XTIDE_Universal_BIOS/Src/VariablesAndDPTs/BootVars.asm @ 492

Last change on this file since 492 was 492, checked in by gregli@…, 11 years ago

Removed the dependency between MODULE_BOOT_MENU and MODULE_HOTKEYS. With these changes, 0, 1, or 2 of them can be included in a build. This change also means that the hotkeys don't work while the menu is up. But the most important hotkey there was for Rom Boot, and that has been added to the menu as a choice proper. Lots of changes across the board in the hotkeys code - even if we eventually back this change out (becaue, for example we want hotkeys to work in the menu) we should probably start from this base and add that functionality back in, as these changes results in approximately 120 bytes of savings and includes new functionality, such as the Rom Boot menu item and the Com Detect hotkey.
File size: 2.3 KB
Line 
1; Project name  :   XTIDE Universal BIOS
2; Description   :   Functions for accessings BOOTVARS.
3
4;
5; XTIDE Universal BIOS and Associated Tools
6; Copyright (C) 2009-2010 by Tomi Tilli, 2011-2012 by XTIDE Universal BIOS Team.
7;
8; This program is free software; you can redistribute it and/or modify
9; it under the terms of the GNU General Public License as published by
10; the Free Software Foundation; either version 2 of the License, or
11; (at your option) any later version.
12;
13; This program is distributed in the hope that it will be useful,
14; but WITHOUT ANY WARRANTY; without even the implied warranty of
15; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
16; GNU General Public License for more details.
17; Visit http://www.gnu.org/licenses/old-licenses/gpl-2.0.html
18;
19
20; Section containing code
21SECTION .text
22
23;--------------------------------------------------------------------
24; BootVars_Initialize
25;   Parameters:
26;       DS:     RAMVARS Segment
27;       ES:     BDA Segment
28;   Returns:
29;       Nothing
30;   Corrupts registers:
31;       AX, CX, DX, DI
32;--------------------------------------------------------------------
33BootVars_Initialize:
34%ifdef MODULE_8BIT_IDE
35    mov     WORD [es:BOOTVARS.wNextXTCFportToScan], XTCF_BASE_PORT_DETECTION_SEED
36%endif
37
38    ; Clear to zero
39    mov     al, DRVDETECTINFO_size
40    mul     BYTE [cs:ROMVARS.bIdeCnt]
41    mov     di, BOOTVARS.clearToZeroFromThisPoint   ; We must not initialize anything before this!
42    add     ax, BOOTVARS_size
43    sub     ax, di
44    xchg    cx, ax
45
46%ifdef MODULE_HOTKEYS
47    call    Memory_ZeroESDIwithSizeInCX
48
49    ; Store default drives to boot from
50    mov     dl, [cs:ROMVARS.bBootDrv]
51
52    ; fall through to BootVars_StoreHotkeyForDriveNumberInDL
53
54;--------------------------------------------------------------------
55; BootVars_StoreHotkeyForDriveNumberInDL
56;   Parameters:
57;       DL:     Floppy or Hard Drive number
58;       DS:     RAMVARS Segment
59;       ES:     BDA Segment
60;   Returns:
61;       Nothing
62;   Corrupts registers:
63;       AX, CX, DI
64;--------------------------------------------------------------------
65BootVars_StoreHotkeyForDriveNumberInDL:
66    mov     WORD [es:BOOTVARS.hotkeyVars+HOTKEYVARS.wHddAndFddLetters], DEFAULT_FLOPPY_DRIVE_LETTER | (DEFAULT_HARD_DRIVE_LETTER<<8)
67    call    DriveXlate_ConvertDriveNumberFromDLtoDriveLetter
68    jmp     HotkeyBar_StoreHotkeyToBootvarsForDriveLetterInDL
69
70%else
71    jmp     Memory_ZeroESDIwithSizeInCX
72
73%endif ; MODULE_HOTKEYS
Note: See TracBrowser for help on using the repository browser.