source: xtideuniversalbios/trunk/XTIDE_Universal_BIOS/Src/VariablesAndDPTs/AccessDPT.asm@ 210

; Project name  :   XTIDE Universal BIOS
; Description   :   Functions for accessing DPT data.

; Section containing code
SECTION .text

;--------------------------------------------------------------------
; AccessDPT_GetDriveSelectByteToAL
;   Parameters:
;       DS:DI:  Ptr to Disk Parameter Table
;   Returns:
;       AL:     Drive Select Byte
;   Corrupts registers:
;       Nothing
;--------------------------------------------------------------------
ALIGN JUMP_ALIGN
AccessDPT_GetDriveSelectByteToAL:
    mov     al, [di+DPT.wFlags]
    and     al, FLG_DRVNHEAD_LBA | FLG_DRVNHEAD_DRV
    or      al, MASK_DRVNHEAD_SET   ; Bits set to 1 for old drives
    ret


;--------------------------------------------------------------------
; AccessDPT_GetDeviceControlByteToAL
;   Parameters:
;       DS:DI:  Ptr to Disk Parameter Table
;   Returns:
;       AL:     Device Control Byte
;   Corrupts registers:
;       Nothing
;--------------------------------------------------------------------
ALIGN JUMP_ALIGN
AccessDPT_GetDeviceControlByteToAL:
    xor     al, al
    test    BYTE [di+DPT.bFlagsLow], FLGL_DPT_ENABLE_IRQ
    jnz     SHORT .EnableDeviceIrq
    or      al, FLG_DEVCONTROL_nIEN ; Disable IRQ
.EnableDeviceIrq:
    ret

        
;--------------------------------------------------------------------
; AccessDPT_GetLCHS
;   Parameters:
;       DS:DI:  Ptr to Disk Parameter Table
;   Returns:
;       AX:     Number of L-CHS sectors per track
;       BX:     Number of L-CHS cylinders
;       DX:     Number of L-CHS heads
;   Corrupts registers:
;       CX
;--------------------------------------------------------------------
AccessDPT_GetLCHS:
    ; Load CHS from DPT
    eMOVZX  ax, BYTE [di+DPT.bSectors]
    mov     bx, [di+DPT.dwCylinders]
    cwd
    mov     dl, [di+DPT.bHeads]

    ; Only need to limit sectors for LBA assist
    test    BYTE [di+DPT.bFlagsLow], FLG_DRVNHEAD_LBA
    jz      SHORT AccessDPT_ShiftPCHinBXDXtoLCH

    cmp     WORD [di+DPT.dwCylinders+2], BYTE 0
    jnz     SHORT .Return_MAX_LCHS_CYLINDERS

    ; Limit cylinders to 1024
    cmp     bx, MAX_LCHS_CYLINDERS
    jb      SHORT .Return
ALIGN JUMP_ALIGN
.Return_MAX_LCHS_CYLINDERS:
    mov     bx, MAX_LCHS_CYLINDERS
ALIGN JUMP_ALIGN, ret
.Return:
    ret


;--------------------------------------------------------------------
; AccessDPT_ShiftPCHinBXDXtoLCH
;   Parameters:
;       BX:     P-CHS cylinders (1...16383)
;       DX:     P-CHS heads (1...16)
;   Returns:
;       BX:     Number of L-CHS cylinders (1...1024)
;       DX:     Number of L-CHS heads (1...255)
;       CX:     Number of bits shifted
;   Corrupts registers:
;       Nothing
;--------------------------------------------------------------------
AccessDPT_ShiftPCHinBXDXtoLCH:
    xor     cx, cx
.ShiftLoop:
    cmp     bx, MAX_LCHS_CYLINDERS      ; Need to shift?
    jbe     SHORT .LimitHeadsTo255      ;  If not, return
    inc     cx                          ; Increment shift count
    shr     bx, 1                       ; Halve cylinders
    shl     dx, 1                       ; Double heads
    jmp     SHORT .ShiftLoop
.LimitHeadsTo255:                       ; DOS does not support drives with 256 heads
    sub     dl, dh                      ; DH set only when 256 logical heads
    xor     dh, dh
    ret

        
;--------------------------------------------------------------------
; Returns pointer to DRVPARAMS for master or slave drive.
;
; AccessDPT_GetPointerToDRVPARAMStoCSBX
;   Parameters:
;       DS:DI:  Ptr to Disk Parameter Table
;   Returns:
;       CS:BX:  Ptr to DRVPARAMS
;   Corrupts registers:
;       Nothing
;--------------------------------------------------------------------
ALIGN JUMP_ALIGN
AccessDPT_GetPointerToDRVPARAMStoCSBX:
    eMOVZX  bx, [di+DPT.bIdevarsOffset]         ; CS:BX points to IDEVARS
    add     bx, BYTE IDEVARS.drvParamsMaster    ; CS:BX points to Master Drive DRVPARAMS
    test    BYTE [di+DPT.bFlagsLow], FLGL_DPT_SLAVE
    jz      SHORT .ReturnPointerToDRVPARAMS
    add     bx, BYTE DRVPARAMS_size             ; CS:BX points to Slave Drive DRVPARAMS
.ReturnPointerToDRVPARAMS:
    ret

;--------------------------------------------------------------------
; AccessDPT_GetUnshiftedAddressModeToALZF
;   Parameters:
;       DS:DI:  Ptr to Disk Parameter Table
;   Returns:
;       AL:     Addressing Mode (L-CHS, P-CHS, LBA28, LBA48) 
;               unshifted (still shifted where it is in bFlagsLow)
;       ZF:     Set based on value in AL
;   Corrupts registers:
;       AL
;--------------------------------------------------------------------
; 
; Converted to a macro since only called in two places, and the call/ret overhead 
; is not worth it for these two instructions (4 bytes total)
;
%macro AccessDPT_GetUnshiftedAddressModeToALZF 0
    mov     al, [di+DPT.bFlagsLow]
    and     al, MASKL_DPT_ADDRESSING_MODE
%endmacro