1 | ; Project name : XTIDE Universal BIOS |
---|
2 | ; Description : Functions for initializing the BIOS. |
---|
3 | |
---|
4 | ; |
---|
5 | ; XTIDE Universal BIOS and Associated Tools |
---|
6 | ; Copyright (C) 2009-2010 by Tomi Tilli, 2011-2013 by XTIDE Universal BIOS Team. |
---|
7 | ; |
---|
8 | ; This program is free software; you can redistribute it and/or modify |
---|
9 | ; it under the terms of the GNU General Public License as published by |
---|
10 | ; the Free Software Foundation; either version 2 of the License, or |
---|
11 | ; (at your option) any later version. |
---|
12 | ; |
---|
13 | ; This program is distributed in the hope that it will be useful, |
---|
14 | ; but WITHOUT ANY WARRANTY; without even the implied warranty of |
---|
15 | ; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
---|
16 | ; GNU General Public License for more details. |
---|
17 | ; Visit http://www.gnu.org/licenses/old-licenses/gpl-2.0.html |
---|
18 | ; |
---|
19 | |
---|
20 | ; Section containing code |
---|
21 | SECTION .text |
---|
22 | |
---|
23 | ;-------------------------------------------------------------------- |
---|
24 | ; Initializes the BIOS. |
---|
25 | ; This function is called from main BIOS ROM search routine. |
---|
26 | ; |
---|
27 | ; Initialize_FromMainBiosRomSearch |
---|
28 | ; Parameters: |
---|
29 | ; Nothing |
---|
30 | ; Returns: |
---|
31 | ; Nothing |
---|
32 | ; Corrupts registers: |
---|
33 | ; Nothing |
---|
34 | ;-------------------------------------------------------------------- |
---|
35 | Initialize_FromMainBiosRomSearch: ; unused entrypoint ok |
---|
36 | pushf ; To store IF |
---|
37 | sti ; Enable interrupts for keystrokes |
---|
38 | push ds |
---|
39 | push ax ; We use AX to install very late init handler |
---|
40 | LOAD_BDA_SEGMENT_TO ds, ax |
---|
41 | |
---|
42 | test BYTE [BDA.bKBFlgs1], (1<<2) ; Clears ZF if CTRL is held down |
---|
43 | jnz SHORT .SkipRomInitialization |
---|
44 | |
---|
45 | ; Install INT 19h handler (boot loader) where drives are detected |
---|
46 | mov WORD [BIOS_BOOT_LOADER_INTERRUPT_19h*4], Int19h_BootLoaderHandler |
---|
47 | mov [BIOS_BOOT_LOADER_INTERRUPT_19h*4+2], cs |
---|
48 | |
---|
49 | %ifdef MODULE_VERY_LATE_INIT |
---|
50 | push es |
---|
51 | ; Install special INT 13h handler that initializes XTIDE Universal BIOS |
---|
52 | ; when our INT 19h is not called |
---|
53 | les ax, [BIOS_DISK_INTERRUPT_13h*4] ; Load system INT 13h handler |
---|
54 | mov WORD [BIOS_DISK_INTERRUPT_13h*4], Int13hBiosInit_Handler |
---|
55 | mov [BIOS_DISK_INTERRUPT_13h*4+2], cs |
---|
56 | mov [TEMPORARY_VECTOR_FOR_SYSTEM_INT13h*4], ax |
---|
57 | mov [TEMPORARY_VECTOR_FOR_SYSTEM_INT13h*4+2], es |
---|
58 | pop es |
---|
59 | %endif |
---|
60 | |
---|
61 | .SkipRomInitialization: |
---|
62 | pop ax |
---|
63 | pop ds |
---|
64 | popf |
---|
65 | retf |
---|
66 | |
---|
67 | |
---|
68 | ;-------------------------------------------------------------------- |
---|
69 | ; Initializes the BIOS variables and detects IDE drives. |
---|
70 | ; |
---|
71 | ; Initialize_AndDetectDrives |
---|
72 | ; Parameters: |
---|
73 | ; ES: BDA Segment |
---|
74 | ; Returns: |
---|
75 | ; DS: RAMVARS segment |
---|
76 | ; Corrupts registers: |
---|
77 | ; All, except ES |
---|
78 | ;-------------------------------------------------------------------- |
---|
79 | Initialize_AndDetectDrives: |
---|
80 | call DetectPrint_InitializeDisplayContext |
---|
81 | call DetectPrint_RomFoundAtSegment |
---|
82 | call RamVars_Initialize |
---|
83 | call BootVars_Initialize |
---|
84 | %ifdef MODULE_HOTKEYS |
---|
85 | ; This is a simple fix for the so called "No Fixed Disk Present in FDISK"-bug introduced in r551. MODULE_HOTKEYS includes the internal |
---|
86 | ; module MODULE_DRIVEXLATE which is needed if interrupt handlers are installed before drive detection. The reason for this is that |
---|
87 | ; Interrupts_InitializeInterruptVectors won't install our interrupt 13h handler if no drives were detected (unless MODULE_DRIVEXLATE is included). |
---|
88 | ; Since the drive detection hasn't been done yet, the handler will not be installed, causing the above mentioned bug. |
---|
89 | call Interrupts_InitializeInterruptVectors ; HotkeyBar requires INT 40h so install handlers before drive detection |
---|
90 | call DetectDrives_FromAllIDEControllers |
---|
91 | %else |
---|
92 | ; Without MODULE_HOTKEYS (or actually MODULE_DRIVEXLATE) we *must* use this call order. |
---|
93 | call DetectDrives_FromAllIDEControllers |
---|
94 | call Interrupts_InitializeInterruptVectors |
---|
95 | %endif |
---|
96 | mov [RAMVARS.wDrvDetectSignature], es ; No longer in drive detection mode (set normal timeouts) |
---|
97 | ; Fall to .StoreDptPointersToIntVectors |
---|
98 | |
---|
99 | ;-------------------------------------------------------------------- |
---|
100 | ; .StoreDptPointersToIntVectors |
---|
101 | ; Parameters: |
---|
102 | ; DS: RAMVARS segment |
---|
103 | ; ES: BDA and interrupt vector segment (zero) |
---|
104 | ; Returns: |
---|
105 | ; Nothing |
---|
106 | ; Corrupts registers: |
---|
107 | ; AX, BX, CX, DX, SI, DI |
---|
108 | ;-------------------------------------------------------------------- |
---|
109 | %ifdef MODULE_COMPATIBLE_TABLES |
---|
110 | .StoreDptPointersToIntVectors: |
---|
111 | %ifndef USE_AT |
---|
112 | test BYTE [cs:ROMVARS.wFlags], FLG_ROMVARS_FULLMODE |
---|
113 | jz SHORT .SkipToReturn ; Only Full operating mode has extra RAM to spare |
---|
114 | %endif |
---|
115 | |
---|
116 | mov bx, HD0_DPT_POINTER_41h * 4 |
---|
117 | mov dl, 80h |
---|
118 | .FindForNextDrive: |
---|
119 | call FindDPT_ForDriveNumberInDL ; DPT to DS:DI |
---|
120 | jc SHORT .NextDrive ; Store nothing if not our drive |
---|
121 | |
---|
122 | push dx |
---|
123 | call CompatibleDPT_CreateToAXSIforDriveDL |
---|
124 | pop dx |
---|
125 | |
---|
126 | mov [es:bx], si |
---|
127 | mov [es:bx+2], ax |
---|
128 | |
---|
129 | .NextDrive: |
---|
130 | inc dx |
---|
131 | add bx, (HD1_DPT_POINTER_46h - HD0_DPT_POINTER_41h) * 4 |
---|
132 | cmp dl, 82h |
---|
133 | jb SHORT .FindForNextDrive |
---|
134 | |
---|
135 | .SkipToReturn: |
---|
136 | %endif ; MODULE_COMPATIBLE_TABLES |
---|
137 | ret |
---|