source: xtideuniversalbios/trunk/XTIDE_Universal_BIOS/Src/Initialization/FloppyDrive.asm @ 102

Last change on this file since 102 was 102, checked in by krille_n_@…, 13 years ago

Changes to XTIDE Universal BIOS

  • Minor optimization in FloppyDrive.asm
File size: 5.3 KB
Line 
1; Project name  :   XTIDE Universal BIOS
2; Description   :   Various floppy drive related functions that
3;                   Boot Menu uses.
4
5; Section containing code
6SECTION .text
7
8;--------------------------------------------------------------------
9; Checks is floppy drive handler installed to interrupt vector 40h.
10;
11; FloppyDrive_IsInt40hInstalled
12;   Parameters:
13;       ES:     BDA and Interrupt Vector segment (zero)
14;   Returns:
15;       CF:     Set if INT 40h is installed
16;               Cleared if INT 40h is not installed
17;   Corrupts registers:
18;       BX, CX, DI
19;--------------------------------------------------------------------
20FloppyDrive_IsInt40hInstalled:
21    cmp     WORD [es:INTV_FLOPPY_FUNC*4+2], 0C000h  ; Any ROM segment?
22%ifdef USE_AT   ; No need to verify on XT systems.
23    jb      SHORT .Int40hHandlerIsNotInstalled
24    call    .VerifyInt40hHandlerSinceSomeBiosesSimplyReturnFromInt40h
25.Int40hHandlerIsNotInstalled:
26%endif
27    cmc
28    ret
29
30;--------------------------------------------------------------------
31; .VerifyInt40hHandlerSinceSomeBiosesSimplyReturnFromInt40h
32;   Parameters:
33;       Nothing
34;   Returns:
35;       CF:     Cleared if INT 40h is installed
36;               Set if INT 40h is not installed
37;   Corrupts registers:
38;       BX, CX, DI
39;--------------------------------------------------------------------
40%ifdef USE_AT
41.VerifyInt40hHandlerSinceSomeBiosesSimplyReturnFromInt40h:
42    push    es
43    push    dx
44    push    ax
45
46    call    .LoadInt40hVerifyParameters
47    int     INTV_DISK_FUNC
48    jc      SHORT .Int40hIsInstalled    ; Maybe there are not any floppy drives at all
49    push    es
50    push    di
51
52    call    .LoadInt40hVerifyParameters
53    int     INTV_FLOPPY_FUNC
54
55    pop     dx
56    pop     cx
57    cmp     dx, di                      ; Difference in offsets?
58    jne     SHORT .Int40hNotInstalled
59    mov     dx, es
60    cmp     cx, dx                      ; Difference in segments?
61    je      SHORT .Int40hIsInstalled
62.Int40hNotInstalled:
63    stc
64.Int40hIsInstalled:
65    pop     ax
66    pop     dx
67    pop     es
68    ret
69
70;--------------------------------------------------------------------
71; .LoadInt40hVerifyParameters
72;   Parameters:
73;       Nothing
74;   Returns:
75;       AH:     08h (Get Drive Parameters)
76;       DL:     00h (floppy drive)
77;       ES:DI:  0:0h (to guard against BIOS bugs)
78;   Corrupts registers:
79;       DH
80;--------------------------------------------------------------------
81.LoadInt40hVerifyParameters:
82    mov     ah, 08h             ; Get Drive Parameters
83    cwd                         ; Floppy drive 0
84    mov     di, dx
85    mov     es, dx              ; ES:DI = 0000:0000h to guard against BIOS bugs
86    ret
87%endif
88
89
90;--------------------------------------------------------------------
91; Returns floppy drive type.
92; PC/XT system do not support AH=08h but FLOPPY_TYPE_525_OR_35_DD
93; is still returned for them.
94;
95; FloppyDrive_GetType
96;   Parameters:
97;       DL:     Floppy Drive number
98;   Returns:
99;       BX:     Floppy Drive Type:
100;                   FLOPPY_TYPE_525_OR_35_DD
101;                   FLOPPY_TYPE_525_DD
102;                   FLOPPY_TYPE_525_HD
103;                   FLOPPY_TYPE_35_DD
104;                   FLOPPY_TYPE_35_HD
105;                   FLOPPY_TYPE_35_ED
106;       CF:     Set if AH=08h not supported (XT systems) or error
107;               Cleared if type read correctly (AT systems)
108;   Corrupts registers:
109;       AX, CX, DX, DI, ES
110;--------------------------------------------------------------------
111ALIGN JUMP_ALIGN
112FloppyDrive_GetType:
113    mov     ah, 08h         ; Get Drive Parameters
114    xor     bx, bx          ; FLOPPY_TYPE_525_OR_35_DD when function not supported
115    int     INTV_FLOPPY_FUNC
116    ret
117
118
119;--------------------------------------------------------------------
120; Returns number of Floppy Drives in system.
121;
122; FloppyDrive_GetCount
123;   Parameters:
124;       Nothing
125;   Returns:
126;       CX:     Number of Floppy Drives
127;   Corrupts registers:
128;       Nothing
129;--------------------------------------------------------------------
130ALIGN JUMP_ALIGN
131FloppyDrive_GetCount:
132    push    es
133%ifdef USE_AT
134    call    FloppyDrive_GetCountFromBIOS
135%else
136    call    FloppyDrive_GetCountFromBDA
137%endif
138    MAX_U   cl, [cs:ROMVARS.bMinFddCnt]
139    xor     ch, ch
140    pop     es
141    ret
142
143
144;--------------------------------------------------------------------
145; Reads Floppy Drive Count from BIOS.
146; Does not work on most XT systems. Call FloppyDrive_GetCountFromBDA
147; if this function fails.
148;
149; FloppyDrive_GetCountFromBIOS
150;   Parameters:
151;       Nothing
152;   Returns:
153;       CL:     Number of Floppy Drives
154;       CF:     Cleared if successfull
155;               Set if BIOS function not supported
156;   Corrupts registers:
157;       CH, ES
158;--------------------------------------------------------------------
159%ifdef USE_AT
160ALIGN JUMP_ALIGN
161FloppyDrive_GetCountFromBIOS:
162    push    di
163    push    dx
164    push    bx
165    push    ax
166
167    mov     ah, 08h                 ; Get Drive Parameters
168    cwd                             ; Floppy Drive 00h
169    int     INTV_FLOPPY_FUNC
170    mov     cl, dl                  ; Number of Floppy Drives to CL
171
172    pop     ax
173    pop     bx
174    pop     dx
175    pop     di
176    ret
177%endif
178
179
180;--------------------------------------------------------------------
181; Reads Floppy Drive Count (0...4) from BIOS Data Area.
182; This function should be used only if FloppyDrive_GetCountFromBIOS fails.
183;
184; FloppyDrive_GetCountFromBDA
185;   Parameters:
186;       Nothing
187;   Returns:
188;       CL:     Number of Floppy Drives
189;   Corrupts registers:
190;       CH, ES
191;--------------------------------------------------------------------
192%ifndef USE_AT
193ALIGN JUMP_ALIGN
194FloppyDrive_GetCountFromBDA:
195    LOAD_BDA_SEGMENT_TO es, cx
196    mov     cl, [es:BDA.wEquipment]         ; Load Equipment WORD low byte
197    mov     ch, cl                          ; Copy it to CH
198    and     cx, 0C001h                      ; Leave bits 15..14 and 0
199    eROL_IM ch, 2                           ; EW low byte bits 7..6 to 1..0
200    add     cl, ch                          ; CL = Floppy Drive count
201    ret
202%endif
Note: See TracBrowser for help on using the repository browser.