source: xtideuniversalbios/trunk/XTIDE_Universal_BIOS/Src/Initialization/FloppyDrive.asm@ 272

Last change on this file since 272 was 270, checked in by gregli@…, 13 years ago

Fixed a bug with the number of floppy drives reported, if there were no floppy drives emulated.
File size: 5.6 KB
Line 
1; Project name : XTIDE Universal BIOS
2; Description : Various floppy drive related functions that
3; Boot Menu uses.
4
5; Section containing code
6SECTION .text
7
8;--------------------------------------------------------------------
9; Checks is floppy drive handler installed to interrupt vector 40h.
10;
11; FloppyDrive_IsInt40hInstalled
12; Parameters:
13; ES: BDA and Interrupt Vector segment (zero)
14; Returns:
15; CF: Set if INT 40h is installed
16; Cleared if INT 40h is not installed
17; Corrupts registers:
18; BX, CX, DI
19;--------------------------------------------------------------------
20FloppyDrive_IsInt40hInstalled:
21 cmp WORD [es:BIOS_DISKETTE_INTERRUPT_40h*4+2], 0C000h ; Any ROM segment?
22%ifdef USE_AT ; No need to verify on XT systems.
23 jb SHORT .Int40hHandlerIsNotInstalled
24 call .VerifyInt40hHandlerSinceSomeBiosesSimplyReturnFromInt40h
25.Int40hHandlerIsNotInstalled:
26%endif
27 cmc
28 ret
29
30;--------------------------------------------------------------------
31; .VerifyInt40hHandlerSinceSomeBiosesSimplyReturnFromInt40h
32; Parameters:
33; Nothing
34; Returns:
35; CF: Cleared if INT 40h is installed
36; Set if INT 40h is not installed
37; Corrupts registers:
38; BX, CX, DI
39;--------------------------------------------------------------------
40%ifdef USE_AT
41.VerifyInt40hHandlerSinceSomeBiosesSimplyReturnFromInt40h:
42 push es
43 push dx
44 push ax
45
46 call .LoadInt40hVerifyParameters
47 int BIOS_DISK_INTERRUPT_13h
48 jc SHORT .Int40hIsInstalled ; Maybe there are not any floppy drives at all
49 push es
50 push di
51
52 call .LoadInt40hVerifyParameters
53 int BIOS_DISKETTE_INTERRUPT_40h
54
55 pop dx
56 pop cx
57 cmp dx, di ; Difference in offsets?
58 jne SHORT .Int40hNotInstalled
59 mov dx, es
60 cmp cx, dx ; Difference in segments?
61 je SHORT .Int40hIsInstalled
62.Int40hNotInstalled:
63 stc
64.Int40hIsInstalled:
65 pop ax
66 pop dx
67 pop es
68 ret
69
70;--------------------------------------------------------------------
71; .LoadInt40hVerifyParameters
72; Parameters:
73; Nothing
74; Returns:
75; AH: 08h (Get Drive Parameters)
76; DL: 00h (floppy drive)
77; ES:DI: 0:0h (to guard against BIOS bugs)
78; Corrupts registers:
79; DH
80;--------------------------------------------------------------------
81.LoadInt40hVerifyParameters:
82 mov ah, 08h ; Get Drive Parameters
83 cwd ; Floppy drive 0
84 mov di, dx
85 mov es, dx ; ES:DI = 0000:0000h to guard against BIOS bugs
86 ret
87%endif
88
89
90;--------------------------------------------------------------------
91; Returns floppy drive type.
92; PC/XT system do not support AH=08h but FLOPPY_TYPE_525_OR_35_DD
93; is still returned for them.
94;
95; FloppyDrive_GetType
96; Parameters:
97; DL: Floppy Drive number
98; Returns:
99; BX: Floppy Drive Type:
100; FLOPPY_TYPE_525_OR_35_DD
101; FLOPPY_TYPE_525_DD
102; FLOPPY_TYPE_525_HD
103; FLOPPY_TYPE_35_DD
104; FLOPPY_TYPE_35_HD
105; FLOPPY_TYPE_35_ED
106; CF: Set if AH=08h not supported (XT systems) or error
107; Cleared if type read correctly (AT systems)
108; Corrupts registers:
109; AX, CX, DX, DI, ES
110;--------------------------------------------------------------------
111ALIGN JUMP_ALIGN
112FloppyDrive_GetType:
113 mov ah, 08h ; Get Drive Parameters
114 xor bx, bx ; FLOPPY_TYPE_525_OR_35_DD when function not supported
115 int BIOS_DISKETTE_INTERRUPT_40h
116 ret
117
118
119;--------------------------------------------------------------------
120; Returns number of Floppy Drives in system.
121;
122; FloppyDrive_GetCountToAX
123; Parameters:
124; DS: RAMVARS Segment
125; Returns:
126; AX: Number of Floppy Drives
127;--------------------------------------------------------------------
128ALIGN JUMP_ALIGN
129FloppyDrive_GetCountToAX:
130%ifdef MODULE_SERIAL_FLOPPY
131 call RamVars_UnpackFlopCntAndFirstToAL
132 js .UseBIOSorBDA ; We didn't add in any drives, counts here are not valid
133
134 adc al,1 ; adds in the drive count bit, and adds 1 for count vs. 0-index,
135 jmp .FinishCalc ; need to clear AH on the way out, and add in minimum drive numbers
136
137.UseBIOSorBDA:
138%endif
139 call FloppyDrive_GetCountFromBIOS_or_BDA
140
141.FinishCalc:
142 mov ah, [cs:ROMVARS.bMinFddCnt]
143 MAX_U al, ah
144 cbw
145
146 ret
147
148ALIGN JUMP_ALIGN
149FloppyDrive_GetCountFromBIOS_or_BDA:
150 push es
151
152;--------------------------------------------------------------------
153; Reads Floppy Drive Count from BIOS.
154; Does not work on most XT systems. Call FloppyDrive_GetCountFromBDA
155; if this function fails.
156;
157; GetCountFromBIOS
158; Parameters:
159; Nothing
160; Returns:
161; CL: Number of Floppy Drives
162; CF: Cleared if successfull
163; Set if BIOS function not supported
164; Corrupts registers:
165; CH, ES
166;--------------------------------------------------------------------
167%ifdef USE_AT
168ALIGN JUMP_ALIGN
169.GetCountFromBIOS:
170 push di
171 push dx
172 push bx
173
174 mov ah, 08h ; Get Drive Parameters
175 cwd ; Floppy Drive 00h
176 int BIOS_DISKETTE_INTERRUPT_40h
177 mov al, dl ; Number of Floppy Drives to AL
178
179 pop bx
180 pop dx
181 pop di
182%endif
183
184;--------------------------------------------------------------------
185; Reads Floppy Drive Count (0...4) from BIOS Data Area.
186; This function should be used only if FloppyDrive_GetCountFromBIOS fails.
187;
188; GetCountFromBDA
189; Parameters:
190; Nothing
191; Returns:
192; CL: Number of Floppy Drives
193; Corrupts registers:
194; CH, ES
195;--------------------------------------------------------------------
196%ifndef USE_AT
197ALIGN JUMP_ALIGN
198.GetCountFromBDA:
199 LOAD_BDA_SEGMENT_TO es, ax
200 mov al, [es:BDA.wEquipment] ; Load Equipment WORD low byte
201 mov ah, al ; Copy it to CH
202 and ax, 0C001h ; Leave bits 15..14 and 0
203 eROL_IM ah, 2 ; EW low byte bits 7..6 to 1..0
204 add al, ah ; CL = Floppy Drive count
205%endif
206
207 pop es
208 ret
209
Note: See TracBrowser for help on using the repository browser.