| 1 | ; Project name : XTIDE Universal BIOS
|
|---|
| 2 | ; Description : Functions for detecting drive for the BIOS.
|
|---|
| 3 |
|
|---|
| 4 | ;
|
|---|
| 5 | ; XTIDE Universal BIOS and Associated Tools
|
|---|
| 6 | ; Copyright (C) 2009-2010 by Tomi Tilli, 2011-2013 by XTIDE Universal BIOS Team.
|
|---|
| 7 | ;
|
|---|
| 8 | ; This program is free software; you can redistribute it and/or modify
|
|---|
| 9 | ; it under the terms of the GNU General Public License as published by
|
|---|
| 10 | ; the Free Software Foundation; either version 2 of the License, or
|
|---|
| 11 | ; (at your option) any later version.
|
|---|
| 12 | ;
|
|---|
| 13 | ; This program is distributed in the hope that it will be useful,
|
|---|
| 14 | ; but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|---|
| 15 | ; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|---|
| 16 | ; GNU General Public License for more details.
|
|---|
| 17 | ; Visit http://www.gnu.org/licenses/old-licenses/gpl-2.0.html
|
|---|
| 18 | ;
|
|---|
| 19 |
|
|---|
| 20 | ; Section containing code
|
|---|
| 21 | SECTION .text
|
|---|
| 22 |
|
|---|
| 23 | ;--------------------------------------------------------------------
|
|---|
| 24 | ; Detects all IDE hard disks to be controlled by this BIOS.
|
|---|
| 25 | ;
|
|---|
| 26 | ; DetectDrives_FromAllIDEControllers
|
|---|
| 27 | ; Parameters:
|
|---|
| 28 | ; DS: RAMVARS segment
|
|---|
| 29 | ; ES: BDA segment (zero)
|
|---|
| 30 | ; Returns:
|
|---|
| 31 | ; Nothing
|
|---|
| 32 | ; Corrupts registers:
|
|---|
| 33 | ; All (not segments)
|
|---|
| 34 | ;--------------------------------------------------------------------
|
|---|
| 35 | DetectDrives_FromAllIDEControllers:
|
|---|
| 36 | call RamVars_GetIdeControllerCountToCX
|
|---|
| 37 | mov bp, ROMVARS.ideVars0 ; CS:BP now points to first IDEVARS
|
|---|
| 38 |
|
|---|
| 39 | .DriveDetectLoop: ; Loop through IDEVARS
|
|---|
| 40 | push cx
|
|---|
| 41 |
|
|---|
| 42 | mov cx, g_szDetectMaster
|
|---|
| 43 | mov bh, MASK_DRVNHEAD_SET ; Select Master drive
|
|---|
| 44 | call StartDetectionWithDriveSelectByteInBHandStringInCX ; Detect and create DPT + BOOTNFO
|
|---|
| 45 |
|
|---|
| 46 | mov cx, g_szDetectSlave
|
|---|
| 47 | mov bh, MASK_DRVNHEAD_SET | FLG_DRVNHEAD_DRV
|
|---|
| 48 | call StartDetectionWithDriveSelectByteInBHandStringInCX
|
|---|
| 49 |
|
|---|
| 50 | %ifdef MODULE_HOTKEYS
|
|---|
| 51 | %ifdef MODULE_SERIAL
|
|---|
| 52 | ; This is only needed for hotkey F6 (ComDtct) to work
|
|---|
| 53 | call ScanHotkeysFromKeyBufferAndStoreToBootvars ; Done here while CX is still protected
|
|---|
| 54 | %endif
|
|---|
| 55 | %endif
|
|---|
| 56 |
|
|---|
| 57 | pop cx
|
|---|
| 58 |
|
|---|
| 59 | add bp, BYTE IDEVARS_size ; Point to next IDEVARS
|
|---|
| 60 |
|
|---|
| 61 | %ifdef MODULE_SERIAL
|
|---|
| 62 | jcxz .AddHardDisks ; Set to zero on .ideVarsSerialAuto iteration (if any)
|
|---|
| 63 | %endif
|
|---|
| 64 | loop .DriveDetectLoop
|
|---|
| 65 |
|
|---|
| 66 | %ifdef MODULE_SERIAL
|
|---|
| 67 | ;----------------------------------------------------------------------
|
|---|
| 68 | ;
|
|---|
| 69 | ; if serial drive detected, do not scan (avoids duplicate drives and isn't needed - we already have a connection)
|
|---|
| 70 | ;
|
|---|
| 71 | call FindDPT_ToDSDIforSerialDevice ; Does not modify AX
|
|---|
| 72 | jnc .AddHardDisks
|
|---|
| 73 |
|
|---|
| 74 | mov bp, ROMVARS.ideVarsSerialAuto ; Point to our special IDEVARS structure, just for serial scans
|
|---|
| 75 |
|
|---|
| 76 | %ifdef MODULE_HOTKEYS
|
|---|
| 77 | cmp al, COM_DETECT_HOTKEY_SCANCODE ; Set by last call to ScanHotkeysFromKeyBufferAndStoreToBootvars above
|
|---|
| 78 | je .DriveDetectLoop
|
|---|
| 79 | %endif
|
|---|
| 80 |
|
|---|
| 81 | mov al, [cs:ROMVARS.wFlags] ; Configurator set to always scan?
|
|---|
| 82 | or al, [es:BDA.bKBFlgs1] ; Or, did the user hold down the ALT key?
|
|---|
| 83 | and al, 8 ; 8 = alt key depressed, same as FLG_ROMVARS_SERIAL_SCANDETECT
|
|---|
| 84 | jnz .DriveDetectLoop
|
|---|
| 85 | %endif ; MODULE_SERIAL
|
|---|
| 86 |
|
|---|
| 87 | .AddHardDisks:
|
|---|
| 88 | ;----------------------------------------------------------------------
|
|---|
| 89 | ;
|
|---|
| 90 | ; Add in hard disks to BDA, finalize our Count and First variables
|
|---|
| 91 | ;
|
|---|
| 92 | ; Note that we perform the add to bHDCount and store bFirstDrv even if the count is zero.
|
|---|
| 93 | ; This is done because we use the value of .bFirstDrv to know how many drives were in the system
|
|---|
| 94 | ; at the time of boot, and to return that number on int13h/8h calls. Because the count is zero,
|
|---|
| 95 | ; FindDPT_ForDriveNumber will not find any drives that are ours.
|
|---|
| 96 | ;
|
|---|
| 97 |
|
|---|
| 98 | ; Here we might want to replace BIOS configured drives with the ones we detected.
|
|---|
| 99 | ; Primary reason is to support dynamic overlay feature in the future. Second reason
|
|---|
| 100 | ; is a hack to get Windows 95 to load its built-in protected mode IDE driver.
|
|---|
| 101 | ;
|
|---|
| 102 | ; The Windows hack has two parts. First part is to try to alter CMOS address 12h as that
|
|---|
| 103 | ; is what Windows 95 driver reads to detect IDE drives. Altering is not possible on all
|
|---|
| 104 | ; systems since CMOS has a checksum but its location is not standardized. We will first
|
|---|
| 105 | ; try to detect valid checksum. If it succeeds, then it is safe to assume this system
|
|---|
| 106 | ; has compatible CMOS and we can alter it.
|
|---|
| 107 | ; If verify fails, we do the more dirty hack to zero BDA drive count. Then Windows 95 works
|
|---|
| 108 | ; as long as user has configured at least one drive in the BIOS setup.
|
|---|
| 109 |
|
|---|
| 110 | %ifdef USE_AT ; FLG_ROMVARS_IGNORE_MOTHERBOARD_DRIVES is for AT builds only
|
|---|
| 111 | %ifdef MODULE_WIN95_CMOS_HACK
|
|---|
| 112 | mov dl, HARD_DISK_TYPES
|
|---|
| 113 | call CMOS_ReadFromIndexInDLtoAL
|
|---|
| 114 | test al, 0F0h
|
|---|
| 115 | jnz SHORT .ClearBdaDriveCount ; CMOS byte 12h is ready for Windows 95
|
|---|
| 116 | call CMOS_Verify10hTo2Dh ; Can we modify CMOS?
|
|---|
| 117 | jnz SHORT .ClearBdaDriveCount ; Unsupported BIOS, use plan B
|
|---|
| 118 |
|
|---|
| 119 | ; Now we can alter CMOS location 12h. Award BIOS locks if we set drive 0 type to Fh
|
|---|
| 120 | ; (but accept changes to drive type 1). Windows 95 requires that the drive 0 type is
|
|---|
| 121 | ; non zero and ignores drive 1 type. So if we only set drive 1, then Award BIOS
|
|---|
| 122 | ; won't give problems but Windows 95 stays in MS-DOS compatibility mode.
|
|---|
| 123 | ;
|
|---|
| 124 | ; For Award BIOSes we could set the Drive 0 type to 1 and then clear the BDA drive count.
|
|---|
| 125 | ; So essentially we could automatically do what user needs to do manually to get Windows 95
|
|---|
| 126 | ; working on Award BIOSes. However, I think that should be left to do manually since
|
|---|
| 127 | ; there may be SCSI drives on the system or FLG_ROMVARS_IGNORE_MOTHERBOARD_DRIVES could
|
|---|
| 128 | ; be intentionally cleared and forcing the dummy drive might cause only trouble.
|
|---|
| 129 |
|
|---|
| 130 | ; Try to detect Award BIOS (Seems to work on a tested 128k BIOS so hopefully
|
|---|
| 131 | ; there will be no need to scan E000h segment)
|
|---|
| 132 | mov cx, 65536 - 4
|
|---|
| 133 | mov eax, 'Awar' ; Four characters should be enough
|
|---|
| 134 | mov di, 0F000h ; Scan 64k starting from segment F000h
|
|---|
| 135 | mov fs, di ; No need to preserve FS since we set it to zero soon when we boot
|
|---|
| 136 | xor di, di
|
|---|
| 137 | .ScanNextCharacters:
|
|---|
| 138 | cmp [fs:di], eax
|
|---|
| 139 | je SHORT .ClearBdaDriveCount ; Award detected, cannot modify CMOS
|
|---|
| 140 | inc di ; Increment offset by one character (not four)
|
|---|
| 141 | loop .ScanNextCharacters
|
|---|
| 142 |
|
|---|
| 143 | ; Now it should be safe to write
|
|---|
| 144 | mov dl, HARD_DISK_TYPES
|
|---|
| 145 | mov al, 0F0h ; Drive 0 type 16...47 (supposed to be defined elsewhere in the CMOS)
|
|---|
| 146 | call CMOS_WriteALtoIndexInDL
|
|---|
| 147 | call CMOS_StoreNewChecksumFor10hto2Dh
|
|---|
| 148 | .ClearBdaDriveCount:
|
|---|
| 149 | %endif ; MODULE_WIN95_CMOS_HACK
|
|---|
| 150 |
|
|---|
| 151 | test BYTE [cs:ROMVARS.wFlags], FLG_ROMVARS_IGNORE_MOTHERBOARD_DRIVES
|
|---|
| 152 | jz SHORT .ContinueInitialization
|
|---|
| 153 | mov BYTE [es:BDA.bHDCount], 0 ; Set hard disk count to zero
|
|---|
| 154 | .ContinueInitialization:
|
|---|
| 155 | %endif ; USE_AT
|
|---|
| 156 |
|
|---|
| 157 | mov cx, [RAMVARS.wDrvCntAndFlopCnt] ; Our count of hard disks
|
|---|
| 158 | mov al, [es:BDA.bHDCount]
|
|---|
| 159 | add [es:BDA.bHDCount], cl ; Add our drives to the system count
|
|---|
| 160 | or al, 80h ; Or in hard disk flag
|
|---|
| 161 | mov [RAMVARS.bFirstDrv], al ; Store first drive number
|
|---|
| 162 |
|
|---|
| 163 | .AddFloppies:
|
|---|
| 164 | %ifdef MODULE_SERIAL_FLOPPY
|
|---|
| 165 | ;----------------------------------------------------------------------
|
|---|
| 166 | ;
|
|---|
| 167 | ; Add in any emulated serial floppy drives, finalize our packed Count and First variables
|
|---|
| 168 | ;
|
|---|
| 169 | dec ch
|
|---|
| 170 | mov al, ch
|
|---|
| 171 | js SHORT .NoFloppies ; If no drives are present, we store 0FFh
|
|---|
| 172 |
|
|---|
| 173 | call FloppyDrive_GetCountFromBIOS_or_BDA
|
|---|
| 174 |
|
|---|
| 175 | push ax
|
|---|
| 176 |
|
|---|
| 177 | add al, ch ; Add our drives to existing drive count
|
|---|
| 178 | cmp al, 3 ; For BDA, max out at 4 drives (ours is zero based)
|
|---|
| 179 | jb .MaxBDAFloppiesExceeded
|
|---|
| 180 | mov al, 3
|
|---|
| 181 | .MaxBDAFloppiesExceeded:
|
|---|
| 182 | eROR_IM al, 2 ; move to bits 6-7
|
|---|
| 183 | inc ax ; low order bit, indicating floppy drive exists
|
|---|
| 184 |
|
|---|
| 185 | mov ah, 3Eh ; AND mask to AH (all bits set except floppy drive count/present)
|
|---|
| 186 | and ah, [es:BDA.wEquipment] ; Load Equipment WORD low byte and mask off drive number and drives present bit
|
|---|
| 187 | or al, ah ; Or in new values
|
|---|
| 188 | mov [es:BDA.wEquipment], al ; and store
|
|---|
| 189 |
|
|---|
| 190 | mov al, 1Eh ; BDA pointer to Floppy DPT
|
|---|
| 191 | mov si, AH8h_FloppyDPT
|
|---|
| 192 | call Interrupts_InstallHandlerToVectorInALFromCSSI
|
|---|
| 193 |
|
|---|
| 194 | pop ax
|
|---|
| 195 |
|
|---|
| 196 | shr ch, 1 ; number of drives, 1 or 2 only, to CF flag (clear=1, set=2)
|
|---|
| 197 | eRCL_IM al, 1 ; starting drive number in upper 7 bits, number of drives in low bit
|
|---|
| 198 | .NoFloppies:
|
|---|
| 199 | mov [RAMVARS.xlateVars+XLATEVARS.bFlopCntAndFirst], al
|
|---|
| 200 | %endif
|
|---|
| 201 | ret
|
|---|
| 202 |
|
|---|
| 203 | %ifndef CHECK_FOR_UNUSED_ENTRYPOINTS
|
|---|
| 204 | %if FLG_ROMVARS_SERIAL_SCANDETECT != 8
|
|---|
| 205 | %error "DetectDrives is currently coded to assume that FLG_ROMVARS_SERIAL_SCANDETECT is the same bit as the ALT key code in the BDA. Changes in the code will be needed if these values are no longer the same."
|
|---|
| 206 | %endif
|
|---|
| 207 | %endif
|
|---|
| 208 |
|
|---|
| 209 |
|
|---|
| 210 | ;--------------------------------------------------------------------
|
|---|
| 211 | ; StartDetectionWithDriveSelectByteInBHandStringInCX
|
|---|
| 212 | ; Parameters:
|
|---|
| 213 | ; BH: Drive Select byte for Drive and Head Register
|
|---|
| 214 | ; CX: Offset to "Master" or "Slave" string
|
|---|
| 215 | ; CS:BP: Ptr to IDEVARS for the drive
|
|---|
| 216 | ; DS: RAMVARS segment
|
|---|
| 217 | ; ES: Zero (BDA segment)
|
|---|
| 218 | ; Returns:
|
|---|
| 219 | ; Nothing
|
|---|
| 220 | ; Corrupts registers:
|
|---|
| 221 | ; AX, BL, CX, DX, SI, DI
|
|---|
| 222 | ;--------------------------------------------------------------------
|
|---|
| 223 | StartDetectionWithDriveSelectByteInBHandStringInCX:
|
|---|
| 224 | call DetectPrint_StartDetectWithMasterOrSlaveStringInCXandIdeVarsInCSBP
|
|---|
| 225 | ; Fall to .ReadAtaInfoFromHardDisk
|
|---|
| 226 |
|
|---|
| 227 |
|
|---|
| 228 | ;--------------------------------------------------------------------
|
|---|
| 229 | ; .ReadAtaInfoFromHardDisk
|
|---|
| 230 | ; Parameters:
|
|---|
| 231 | ; BH: Drive Select byte for Drive and Head Register
|
|---|
| 232 | ; DX: Autodetected port (for devices that support autodetection)
|
|---|
| 233 | ; CS:BP: Ptr to IDEVARS for the drive
|
|---|
| 234 | ; DS: RAMVARS segment
|
|---|
| 235 | ; ES: Zero (BDA segment)
|
|---|
| 236 | ; Returns:
|
|---|
| 237 | ; CF: Cleared if ATA-information read successfully
|
|---|
| 238 | ; Set if any error
|
|---|
| 239 | ; Corrupts registers:
|
|---|
| 240 | ; AX, BL, CX, DX, SI, DI
|
|---|
| 241 | ;--------------------------------------------------------------------
|
|---|
| 242 | .ReadAtaInfoFromHardDisk:
|
|---|
| 243 | mov si, BOOTVARS.rgbAtaInfo ; ES:SI now points to ATA info location
|
|---|
| 244 | push es
|
|---|
| 245 | push si
|
|---|
| 246 | push dx
|
|---|
| 247 | push bx
|
|---|
| 248 | call Device_IdentifyToBufferInESSIwithDriveSelectByteInBH
|
|---|
| 249 | pop bx
|
|---|
| 250 | pop dx
|
|---|
| 251 | pop si
|
|---|
| 252 | pop es
|
|---|
| 253 | jnc SHORT CreateBiosTablesForHardDisk
|
|---|
| 254 | ; Fall to .ReadAtapiInfoFromDrive
|
|---|
| 255 |
|
|---|
| 256 | .ReadAtapiInfoFromDrive: ; Not yet implemented
|
|---|
| 257 | ;call ReadAtapiInfoFromDrive ; Assume CD-ROM
|
|---|
| 258 | ;jnc SHORT _CreateBiosTablesForCDROM
|
|---|
| 259 |
|
|---|
| 260 | ;jmp short DetectDrives_DriveNotFound
|
|---|
| 261 | ;;; fall-through instead of previous jmp instruction
|
|---|
| 262 | ;--------------------------------------------------------------------
|
|---|
| 263 | ; DetectDrives_DriveNotFound
|
|---|
| 264 | ; Parameters:
|
|---|
| 265 | ; Nothing
|
|---|
| 266 | ; Returns:
|
|---|
| 267 | ; CF: Set (from DetectPrint_NullTerminatedStringFromCSSIandSetCF)
|
|---|
| 268 | ; Corrupts registers:
|
|---|
| 269 | ; AX, SI
|
|---|
| 270 | ;--------------------------------------------------------------------
|
|---|
| 271 | DetectDrives_DriveNotFound:
|
|---|
| 272 | mov si, g_szNotFound
|
|---|
| 273 | jmp DetectPrint_NullTerminatedStringFromCSSIandSetCF
|
|---|
| 274 |
|
|---|
| 275 |
|
|---|
| 276 | ;--------------------------------------------------------------------
|
|---|
| 277 | ; CreateBiosTablesForHardDisk
|
|---|
| 278 | ; Parameters:
|
|---|
| 279 | ; BH: Drive Select byte for Drive and Head Register
|
|---|
| 280 | ; DX: Autodetected port (for devices that support autodetection)
|
|---|
| 281 | ; CS:BP: Ptr to IDEVARS for the drive
|
|---|
| 282 | ; ES:SI Ptr to ATA information for the drive
|
|---|
| 283 | ; DS: RAMVARS segment
|
|---|
| 284 | ; ES: BDA segment
|
|---|
| 285 | ; Returns:
|
|---|
| 286 | ; Nothing
|
|---|
| 287 | ; Corrupts registers:
|
|---|
| 288 | ; AX, BX, CX, DX, SI, DI
|
|---|
| 289 | ;--------------------------------------------------------------------
|
|---|
| 290 | CreateBiosTablesForHardDisk:
|
|---|
| 291 | %ifndef NO_ATAID_VALIDATION
|
|---|
| 292 | push bx
|
|---|
| 293 | call AtaID_VerifyFromESSI
|
|---|
| 294 | pop bx
|
|---|
| 295 | jnz SHORT DetectDrives_DriveNotFound
|
|---|
| 296 | %endif
|
|---|
| 297 | call CreateDPT_FromAtaInformation
|
|---|
| 298 | jc SHORT DetectDrives_DriveNotFound
|
|---|
| 299 | call DriveDetectInfo_CreateForHardDisk
|
|---|
| 300 | jmp SHORT DetectPrint_DriveNameFromDrvDetectInfoInESBX
|
|---|
