source: xtideuniversalbios/trunk/XTIDE_Universal_BIOS/Src/Initialization/DetectDrives.asm@ 556

Last change on this file since 556 was 545, checked in by aitotat@…, 12 years ago

Changes to XTIDE Universal BIOS:

  • Integrated XT-CFv3 support by James Pearce.
  • XT-CFv2 memory mapped I/O and DMA modes are no longer supported (but PIO mode is).
File size: 9.2 KB
Line 
1; Project name : XTIDE Universal BIOS
2; Description : Functions for detecting drive for the BIOS.
3
4;
5; XTIDE Universal BIOS and Associated Tools
6; Copyright (C) 2009-2010 by Tomi Tilli, 2011-2013 by XTIDE Universal BIOS Team.
7;
8; This program is free software; you can redistribute it and/or modify
9; it under the terms of the GNU General Public License as published by
10; the Free Software Foundation; either version 2 of the License, or
11; (at your option) any later version.
12;
13; This program is distributed in the hope that it will be useful,
14; but WITHOUT ANY WARRANTY; without even the implied warranty of
15; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
16; GNU General Public License for more details.
17; Visit http://www.gnu.org/licenses/old-licenses/gpl-2.0.html
18;
19
20; Section containing code
21SECTION .text
22
23;--------------------------------------------------------------------
24; Detects all IDE hard disks to be controlled by this BIOS.
25;
26; DetectDrives_FromAllIDEControllers
27; Parameters:
28; DS: RAMVARS segment
29; ES: BDA segment (zero)
30; Returns:
31; Nothing
32; Corrupts registers:
33; All (not segments)
34;--------------------------------------------------------------------
35DetectDrives_FromAllIDEControllers:
36 call RamVars_GetIdeControllerCountToCX
37 mov bp, ROMVARS.ideVars0 ; CS:BP now points to first IDEVARS
38
39.DriveDetectLoop: ; Loop through IDEVARS
40 push cx
41
42 mov cx, g_szDetectMaster
43 mov bh, MASK_DRVNHEAD_SET ; Select Master drive
44 call StartDetectionWithDriveSelectByteInBHandStringInCX ; Detect and create DPT + BOOTNFO
45
46 mov cx, g_szDetectSlave
47 mov bh, MASK_DRVNHEAD_SET | FLG_DRVNHEAD_DRV
48 call StartDetectionWithDriveSelectByteInBHandStringInCX
49
50 pop cx
51
52 add bp, BYTE IDEVARS_size ; Point to next IDEVARS
53
54%ifdef MODULE_SERIAL
55 jcxz .AddHardDisks ; Set to zero on .ideVarsSerialAuto iteration (if any)
56%endif
57 loop .DriveDetectLoop
58
59%ifdef MODULE_SERIAL
60;----------------------------------------------------------------------
61;
62; if serial drive detected, do not scan (avoids duplicate drives and isn't needed - we already have a connection)
63;
64 call FindDPT_ToDSDIforSerialDevice ; does not modify AX
65 jnc .AddHardDisks
66
67 mov bp, ROMVARS.ideVarsSerialAuto ; Point to our special IDEVARS structure, just for serial scans
68
69%ifdef MODULE_HOTKEYS
70 cmp al, COM_DETECT_HOTKEY_SCANCODE ; Set by last call to HotkeyBar_UpdateDuringDriveDetection above
71 je .DriveDetectLoop
72%endif
73
74 mov al,[cs:ROMVARS.wFlags] ; Configurator set to always scan?
75 or al,[es:BDA.bKBFlgs1] ; Or, did the user hold down the ALT key?
76 and al,8 ; 8 = alt key depressed, same as FLG_ROMVARS_SERIAL_ALWAYSDETECT
77 jnz .DriveDetectLoop
78%endif
79
80.AddHardDisks:
81;----------------------------------------------------------------------
82;
83; Add in hard disks to BDA, finalize our Count and First variables
84;
85; Note that we perform the add to bHDCount and store bFirstDrv even if the count is zero.
86; This is done because we use the value of .bFirstDrv to know how many drives were in the system
87; at the time of boot, and to return that number on int13h/8h calls. Because the count is zero,
88; FindDPT_ForDriveNumber will not find any drives that are ours.
89;
90 mov cx, [RAMVARS.wDrvCntAndFlopCnt] ; Our count of hard disks
91
92 mov al, [es:BDA.bHDCount]
93 add cl, al ; Add our drives to the system count
94 mov [es:BDA.bHDCount], cl
95 or al, 80h ; Or in hard disk flag
96 mov [RAMVARS.bFirstDrv], al ; Store first drive number
97
98.AddFloppies:
99%ifdef MODULE_SERIAL_FLOPPY
100;----------------------------------------------------------------------
101;
102; Add in any emulated serial floppy drives, finalize our packed Count and First variables
103;
104 dec ch
105 mov al, ch
106 js .NoFloppies ; if no drives are present, we store 0ffh
107
108 call FloppyDrive_GetCountFromBIOS_or_BDA
109
110 push ax
111
112 add al, ch ; Add our drives to existing drive count
113 cmp al, 3 ; For BDA, max out at 4 drives (ours is zero based)
114 jb .MaxBDAFloppiesExceeded
115 mov al, 3
116.MaxBDAFloppiesExceeded:
117 eROR_IM al, 2 ; move to bits 6-7
118 inc ax ; low order bit, indicating floppy drive exists
119
120 mov ah, [es:BDA.wEquipment] ; Load Equipment WORD low byte
121 and ah, 03eh ; Mask off drive number and drives present bit
122 or al, ah ; Or in new values
123 mov [es:BDA.wEquipment], al ; and store
124
125 mov al, 1eh ; BDA pointer to Floppy DPT
126 mov si, AH8h_FloppyDPT
127 call Interrupts_InstallHandlerToVectorInALFromCSSI
128
129 pop ax
130
131 shr ch, 1 ; number of drives, 1 or 2 only, to CF flag (clear=1, set=2)
132 rcl al, 1 ; starting drive number in upper 7 bits, number of drives in low bit
133.NoFloppies:
134 mov [RAMVARS.xlateVars+XLATEVARS.bFlopCntAndFirst], al
135%endif
136
137 ret
138
139%ifndef CHECK_FOR_UNUSED_ENTRYPOINTS
140 %if FLG_ROMVARS_SERIAL_SCANDETECT != 8
141 %error "DetectDrives is currently coded to assume that FLG_ROMVARS_SERIAL_SCANDETECT is the same bit as the ALT key code in the BDA. Changes in the code will be needed if these values are no longer the same."
142 %endif
143%endif
144
145
146;--------------------------------------------------------------------
147; StartDetectionWithDriveSelectByteInBHandStringInCX
148; Parameters:
149; BH: Drive Select byte for Drive and Head Register
150; CX: Offset to "Master" or "Slave" string
151; CS:BP: Ptr to IDEVARS for the drive
152; DS: RAMVARS segment
153; ES: Zero (BDA segment)
154; Returns:
155; None
156; Corrupts registers:
157; AX, BL, CX, DX, SI, DI
158;--------------------------------------------------------------------
159StartDetectionWithDriveSelectByteInBHandStringInCX:
160%ifdef MODULE_8BIT_IDE
161 call DetectDrives_DoesIdevarsInCSBPbelongToXTCF
162 jne SHORT .ShouldNotSkipSlaveDriveDetection
163
164 ; XT-CF do not support slave drives so skip detection
165 test bh, FLG_DRVNHEAD_DRV
166 jnz SHORT NoSlaveDriveAvailable
167.ShouldNotSkipSlaveDriveDetection:
168%endif ; MODULE_8BIT_IDE
169
170 call DetectPrint_StartDetectWithMasterOrSlaveStringInCXandIdeVarsInCSBP
171.DriveDetectionStringPrintedOnScreen:
172%ifdef MODULE_HOTKEYS
173 call HotkeyBar_UpdateDuringDriveDetection
174%endif
175 ; Fall to .ReadAtaInfoFromHardDisk
176
177
178;--------------------------------------------------------------------
179; .ReadAtaInfoFromHardDisk
180; Parameters:
181; BH: Drive Select byte for Drive and Head Register
182; DX: Autodetected port (for devices that support autodetection)
183; CS:BP: Ptr to IDEVARS for the drive
184; DS: RAMVARS segment
185; ES: Zero (BDA segment)
186; Returns:
187; CF: Cleared if ATA-information read successfully
188; Set if any error
189; Corrupts registers:
190; AX, BL, CX, DX, SI, DI
191;--------------------------------------------------------------------
192.ReadAtaInfoFromHardDisk:
193 mov si, BOOTVARS.rgbAtaInfo ; ES:SI now points to ATA info location
194 push es
195 push si
196 push dx
197 push bx
198 call Device_IdentifyToBufferInESSIwithDriveSelectByteInBH
199 pop bx
200 pop dx
201 pop si
202 pop es
203 jnc SHORT CreateBiosTablesForHardDisk
204 ; Fall to .ReadAtapiInfoFromDrive
205
206.ReadAtapiInfoFromDrive: ; Not yet implemented
207 ;call ReadAtapiInfoFromDrive ; Assume CD-ROM
208 ;jnc SHORT _CreateBiosTablesForCDROM
209
210 ;jmp short DetectDrives_DriveNotFound
211;;; fall-through instead of previous jmp instruction
212;--------------------------------------------------------------------
213; DetectDrives_DriveNotFound
214; Parameters:
215; Nothing
216; Returns:
217; CF: Set (from DetectPrint_NullTerminatedStringFromCSSIandSetCF)
218; Corrupts registers:
219; AX, SI
220;--------------------------------------------------------------------
221DetectDrives_DriveNotFound:
222 mov si, g_szNotFound
223 jmp DetectPrint_NullTerminatedStringFromCSSIandSetCF
224
225
226;--------------------------------------------------------------------
227; CreateBiosTablesForHardDisk
228; Parameters:
229; BH: Drive Select byte for Drive and Head Register
230; DX: Autodetected port (for devices that support autodetection)
231; CS:BP: Ptr to IDEVARS for the drive
232; ES:SI Ptr to ATA information for the drive
233; DS: RAMVARS segment
234; ES: BDA segment
235; Returns:
236; Nothing
237; Corrupts registers:
238; AX, BX, CX, DX, SI, DI
239;--------------------------------------------------------------------
240CreateBiosTablesForHardDisk:
241 push bx
242 call AtaID_VerifyFromESSI
243 pop bx
244 jc SHORT DetectDrives_DriveNotFound
245 call CreateDPT_FromAtaInformation
246 jc SHORT DetectDrives_DriveNotFound
247 call DriveDetectInfo_CreateForHardDisk
248 jmp SHORT DetectPrint_DriveNameFromDrvDetectInfoInESBX
249
250
251%ifdef MODULE_8BIT_IDE
252;--------------------------------------------------------------------
253; DetectDrives_DoesIdevarsInCSBPbelongToXTCF
254; Parameters:
255; CS:BP: Ptr to IDEVARS for the drive
256; Returns:
257; ZF: Set if IDEVARS belongs to XT-CF device
258; Cleared if some other device
259; Corrupts registers:
260; AL
261;--------------------------------------------------------------------
262DetectDrives_DoesIdevarsInCSBPbelongToXTCF:
263 mov al, [cs:bp+IDEVARS.bDevice]
264 cmp al, DEVICE_8BIT_XTCF_PIO8
265 je SHORT .Done
266 cmp al, DEVICE_8BIT_XTCF_PIO8_WITH_BIU_OFFLOAD
267
268%ifdef MODULE_8BIT_IDE_ADVANCED
269 je SHORT .Done
270 cmp al, DEVICE_8BIT_XTCF_DMA
271%endif ; MODULE_8BIT_IDE_ADVANCED
272
273.Done: ; return state via ZF, set from the cmp instructions
274NoSlaveDriveAvailable:
275 ret
276%endif ; MODULE_8BIT_IDE
Note: See TracBrowser for help on using the repository browser.