| 1 | ; Project name : XTIDE Universal BIOS
|
|---|
| 2 | ; Description : Functions for detecting drive for the BIOS.
|
|---|
| 3 |
|
|---|
| 4 | ;
|
|---|
| 5 | ; XTIDE Universal BIOS and Associated Tools
|
|---|
| 6 | ; Copyright (C) 2009-2010 by Tomi Tilli, 2011-2012 by XTIDE Universal BIOS Team.
|
|---|
| 7 | ;
|
|---|
| 8 | ; This program is free software; you can redistribute it and/or modify
|
|---|
| 9 | ; it under the terms of the GNU General Public License as published by
|
|---|
| 10 | ; the Free Software Foundation; either version 2 of the License, or
|
|---|
| 11 | ; (at your option) any later version.
|
|---|
| 12 | ;
|
|---|
| 13 | ; This program is distributed in the hope that it will be useful,
|
|---|
| 14 | ; but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|---|
| 15 | ; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|---|
| 16 | ; GNU General Public License for more details.
|
|---|
| 17 | ; Visit http://www.gnu.org/licenses/old-licenses/gpl-2.0.html
|
|---|
| 18 | ;
|
|---|
| 19 |
|
|---|
| 20 | ; Section containing code
|
|---|
| 21 | SECTION .text
|
|---|
| 22 |
|
|---|
| 23 | ;--------------------------------------------------------------------
|
|---|
| 24 | ; Detects all IDE hard disks to be controlled by this BIOS.
|
|---|
| 25 | ;
|
|---|
| 26 | ; DetectDrives_FromAllIDEControllers
|
|---|
| 27 | ; Parameters:
|
|---|
| 28 | ; DS: RAMVARS segment
|
|---|
| 29 | ; ES: BDA segment (zero)
|
|---|
| 30 | ; Returns:
|
|---|
| 31 | ; Nothing
|
|---|
| 32 | ; Corrupts registers:
|
|---|
| 33 | ; All (not segments)
|
|---|
| 34 | ;--------------------------------------------------------------------
|
|---|
| 35 | DetectDrives_FromAllIDEControllers:
|
|---|
| 36 | call RamVars_GetIdeControllerCountToCX
|
|---|
| 37 | mov bp, ROMVARS.ideVars0 ; CS:BP now points to first IDEVARS
|
|---|
| 38 |
|
|---|
| 39 | .DriveDetectLoop: ; Loop through IDEVARS
|
|---|
| 40 | push cx
|
|---|
| 41 |
|
|---|
| 42 | mov cx, g_szDetectMaster
|
|---|
| 43 | mov bh, MASK_DRVNHEAD_SET ; Select Master drive
|
|---|
| 44 | call StartDetectionWithDriveSelectByteInBHandStringInCX ; Detect and create DPT + BOOTNFO
|
|---|
| 45 |
|
|---|
| 46 | mov cx, g_szDetectSlave
|
|---|
| 47 | mov bh, MASK_DRVNHEAD_SET | FLG_DRVNHEAD_DRV
|
|---|
| 48 | call StartDetectionWithDriveSelectByteInBHandStringInCX
|
|---|
| 49 |
|
|---|
| 50 | pop cx
|
|---|
| 51 |
|
|---|
| 52 | add bp, BYTE IDEVARS_size ; Point to next IDEVARS
|
|---|
| 53 |
|
|---|
| 54 | %ifdef MODULE_SERIAL
|
|---|
| 55 | jcxz .AddHardDisks ; Set to zero on .ideVarsSerialAuto iteration (if any)
|
|---|
| 56 | %endif
|
|---|
| 57 | loop .DriveDetectLoop
|
|---|
| 58 |
|
|---|
| 59 | %ifdef MODULE_SERIAL
|
|---|
| 60 | ;----------------------------------------------------------------------
|
|---|
| 61 | ;
|
|---|
| 62 | ; if serial drive detected, do not scan (avoids duplicate drives and isn't needed - we already have a connection)
|
|---|
| 63 | ;
|
|---|
| 64 | call FindDPT_ToDSDIforSerialDevice
|
|---|
| 65 | jnc .AddHardDisks
|
|---|
| 66 |
|
|---|
| 67 | mov bp, ROMVARS.ideVarsSerialAuto ; Point to our special IDEVARS structure, just for serial scans
|
|---|
| 68 |
|
|---|
| 69 | mov al,[cs:ROMVARS.wFlags] ; Configurator set to always scan?
|
|---|
| 70 | or al,[es:BDA.bKBFlgs1] ; Or, did the user hold down the ALT key?
|
|---|
| 71 | and al,8 ; 8 = alt key depressed, same as FLG_ROMVARS_SERIAL_ALWAYSDETECT
|
|---|
| 72 | jnz .DriveDetectLoop
|
|---|
| 73 | %endif
|
|---|
| 74 |
|
|---|
| 75 | .AddHardDisks:
|
|---|
| 76 | ;----------------------------------------------------------------------
|
|---|
| 77 | ;
|
|---|
| 78 | ; Add in hard disks to BDA, finalize our Count and First variables
|
|---|
| 79 | ;
|
|---|
| 80 | ; Note that we perform the add to bHDCount and store bFirstDrv even if the count is zero.
|
|---|
| 81 | ; This is done because we use the value of .bFirstDrv to know how many drives were in the system
|
|---|
| 82 | ; at the time of boot, and to return that number on int13h/8h calls. Because the count is zero,
|
|---|
| 83 | ; FindDPT_ForDriveNumber will not find any drives that are ours.
|
|---|
| 84 | ;
|
|---|
| 85 | mov cx, [RAMVARS.wDrvCntAndFlopCnt] ; Our count of hard disks
|
|---|
| 86 |
|
|---|
| 87 | mov al, [es:BDA.bHDCount]
|
|---|
| 88 | add cl, al ; Add our drives to the system count
|
|---|
| 89 | mov [es:BDA.bHDCount], cl
|
|---|
| 90 | or al, 80h ; Or in hard disk flag
|
|---|
| 91 | mov [RAMVARS.bFirstDrv], al ; Store first drive number
|
|---|
| 92 |
|
|---|
| 93 | .AddFloppies:
|
|---|
| 94 | %ifdef MODULE_SERIAL_FLOPPY
|
|---|
| 95 | ;----------------------------------------------------------------------
|
|---|
| 96 | ;
|
|---|
| 97 | ; Add in any emulated serial floppy drives, finalize our packed Count and First variables
|
|---|
| 98 | ;
|
|---|
| 99 | dec ch
|
|---|
| 100 | mov al, ch
|
|---|
| 101 | js .NoFloppies ; if no drives are present, we store 0ffh
|
|---|
| 102 |
|
|---|
| 103 | call FloppyDrive_GetCountFromBIOS_or_BDA
|
|---|
| 104 |
|
|---|
| 105 | push ax
|
|---|
| 106 |
|
|---|
| 107 | add al, ch ; Add our drives to existing drive count
|
|---|
| 108 | cmp al, 3 ; For BDA, max out at 4 drives (ours is zero based)
|
|---|
| 109 | jb .MaxBDAFloppiesExceeded
|
|---|
| 110 | mov al, 3
|
|---|
| 111 | .MaxBDAFloppiesExceeded:
|
|---|
| 112 | eROR_IM al, 2 ; move to bits 6-7
|
|---|
| 113 | inc ax ; low order bit, indicating floppy drive exists
|
|---|
| 114 |
|
|---|
| 115 | mov ah, [es:BDA.wEquipment] ; Load Equipment WORD low byte
|
|---|
| 116 | and ah, 03eh ; Mask off drive number and drives present bit
|
|---|
| 117 | or al, ah ; Or in new values
|
|---|
| 118 | mov [es:BDA.wEquipment], al ; and store
|
|---|
| 119 |
|
|---|
| 120 | mov al, 1eh ; BDA pointer to Floppy DPT
|
|---|
| 121 | mov si, AH8h_FloppyDPT
|
|---|
| 122 | call Interrupts_InstallHandlerToVectorInALFromCSSI
|
|---|
| 123 |
|
|---|
| 124 | pop ax
|
|---|
| 125 |
|
|---|
| 126 | shr ch, 1 ; number of drives, 1 or 2 only, to CF flag (clear=1, set=2)
|
|---|
| 127 | rcl al, 1 ; starting drive number in upper 7 bits, number of drives in low bit
|
|---|
| 128 | .NoFloppies:
|
|---|
| 129 | mov [RAMVARS.xlateVars+XLATEVARS.bFlopCntAndFirst], al
|
|---|
| 130 | %endif
|
|---|
| 131 |
|
|---|
| 132 | ret
|
|---|
| 133 |
|
|---|
| 134 | %ifndef CHECK_FOR_UNUSED_ENTRYPOINTS
|
|---|
| 135 | %if FLG_ROMVARS_SERIAL_SCANDETECT != 8
|
|---|
| 136 | %error "DetectDrives is currently coded to assume that FLG_ROMVARS_SERIAL_SCANDETECT is the same bit as the ALT key code in the BDA. Changes in the code will be needed if these values are no longer the same."
|
|---|
| 137 | %endif
|
|---|
| 138 | %endif
|
|---|
| 139 |
|
|---|
| 140 |
|
|---|
| 141 | ;--------------------------------------------------------------------
|
|---|
| 142 | ; StartDetectionWithDriveSelectByteInBHandStringInCX
|
|---|
| 143 | ; Parameters:
|
|---|
| 144 | ; BH: Drive Select byte for Drive and Head Register
|
|---|
| 145 | ; CX: Offset to "Master" or "Slave" string
|
|---|
| 146 | ; CS:BP: Ptr to IDEVARS for the drive
|
|---|
| 147 | ; DS: RAMVARS segment
|
|---|
| 148 | ; ES: Zero (BDA segment)
|
|---|
| 149 | ; Returns:
|
|---|
| 150 | ; None
|
|---|
| 151 | ; Corrupts registers:
|
|---|
| 152 | ; AX, BL, CX, DX, SI, DI
|
|---|
| 153 | ;--------------------------------------------------------------------
|
|---|
| 154 | StartDetectionWithDriveSelectByteInBHandStringInCX:
|
|---|
| 155 | ; Autodetect port for XT-CF
|
|---|
| 156 | %ifdef MODULE_8BIT_IDE
|
|---|
| 157 | call DetectDrives_DoesIdevarsInCSBPbelongToXTCF
|
|---|
| 158 | jne SHORT .SkipXTCFportDetection
|
|---|
| 159 |
|
|---|
| 160 | ; XT-CF do not support slave drives so skip detection
|
|---|
| 161 | test bh, FLG_DRVNHEAD_DRV
|
|---|
| 162 | jnz SHORT NoSlaveDriveAvailable
|
|---|
| 163 |
|
|---|
| 164 | ; XT-CF do not support slave drives so we can safely update port
|
|---|
| 165 | ; for next drive (another XT-CF card on same system)
|
|---|
| 166 | .DetectNextPort:
|
|---|
| 167 | call BootVars_GetNextXTCFportToDetectToDX
|
|---|
| 168 | cmp dx, XTCF_BASE_PORT_4
|
|---|
| 169 | ja SHORT .SkipXTCFportDetection ; XT-CF not found from any port
|
|---|
| 170 |
|
|---|
| 171 | call AH1Eh_DetectXTCFwithBasePortInDX
|
|---|
| 172 | jc SHORT .DetectNextPort ; XT-CF not found from this port
|
|---|
| 173 |
|
|---|
| 174 | ; We now have autodetected port in DX
|
|---|
| 175 | push dx
|
|---|
| 176 | xchg ax, dx ; Port to print in AX
|
|---|
| 177 | call DetectPrint_StartDetectWithAutodetectedBasePortInAXandIdeVarsInCSBP
|
|---|
| 178 | jmp SHORT .DriveDetectionStringPrintedOnScreen
|
|---|
| 179 |
|
|---|
| 180 | ; Print detect string for devices that do not support autodetection
|
|---|
| 181 | .SkipXTCFportDetection:
|
|---|
| 182 | push dx
|
|---|
| 183 | %endif ; MODULE_8BIT_IDE
|
|---|
| 184 |
|
|---|
| 185 | call DetectPrint_StartDetectWithMasterOrSlaveStringInCXandIdeVarsInCSBP
|
|---|
| 186 | .DriveDetectionStringPrintedOnScreen:
|
|---|
| 187 | %ifdef MODULE_HOTKEYS
|
|---|
| 188 | call HotkeyBar_UpdateDuringDriveDetection
|
|---|
| 189 | %endif
|
|---|
| 190 | %ifdef MODULE_8BIT_IDE
|
|---|
| 191 | pop dx
|
|---|
| 192 | %endif
|
|---|
| 193 | ; Fall to .ReadAtaInfoFromHardDisk
|
|---|
| 194 |
|
|---|
| 195 |
|
|---|
| 196 | ;--------------------------------------------------------------------
|
|---|
| 197 | ; .ReadAtaInfoFromHardDisk
|
|---|
| 198 | ; Parameters:
|
|---|
| 199 | ; BH: Drive Select byte for Drive and Head Register
|
|---|
| 200 | ; DX: Autodetected port (for devices that support autodetection)
|
|---|
| 201 | ; CS:BP: Ptr to IDEVARS for the drive
|
|---|
| 202 | ; DS: RAMVARS segment
|
|---|
| 203 | ; ES: Zero (BDA segment)
|
|---|
| 204 | ; Returns:
|
|---|
| 205 | ; CF: Cleared if ATA-information read successfully
|
|---|
| 206 | ; Set if any error
|
|---|
| 207 | ; Corrupts registers:
|
|---|
| 208 | ; AX, BL, CX, DX, SI, DI
|
|---|
| 209 | ;--------------------------------------------------------------------
|
|---|
| 210 | .ReadAtaInfoFromHardDisk:
|
|---|
| 211 | mov si, BOOTVARS.rgbAtaInfo ; ES:SI now points to ATA info location
|
|---|
| 212 | push es
|
|---|
| 213 | push si
|
|---|
| 214 | push dx
|
|---|
| 215 | push bx
|
|---|
| 216 | call Device_IdentifyToBufferInESSIwithDriveSelectByteInBH
|
|---|
| 217 | pop bx
|
|---|
| 218 | pop dx
|
|---|
| 219 | pop si
|
|---|
| 220 | pop es
|
|---|
| 221 | jnc SHORT CreateBiosTablesForHardDisk
|
|---|
| 222 | ; Fall to .ReadAtapiInfoFromDrive
|
|---|
| 223 |
|
|---|
| 224 | .ReadAtapiInfoFromDrive: ; Not yet implemented
|
|---|
| 225 | ;call ReadAtapiInfoFromDrive ; Assume CD-ROM
|
|---|
| 226 | ;jnc SHORT _CreateBiosTablesForCDROM
|
|---|
| 227 |
|
|---|
| 228 | ;jmp short DetectDrives_DriveNotFound
|
|---|
| 229 | ;;; fall-through instead of previous jmp instruction
|
|---|
| 230 | ;--------------------------------------------------------------------
|
|---|
| 231 | ; DetectDrives_DriveNotFound
|
|---|
| 232 | ; Parameters:
|
|---|
| 233 | ; Nothing
|
|---|
| 234 | ; Returns:
|
|---|
| 235 | ; CF: Set (from BootMenuPrint_NullTerminatedStringFromCSSIandSetCF)
|
|---|
| 236 | ; Corrupts registers:
|
|---|
| 237 | ; AX, SI
|
|---|
| 238 | ;--------------------------------------------------------------------
|
|---|
| 239 | DetectDrives_DriveNotFound:
|
|---|
| 240 | mov si, g_szNotFound
|
|---|
| 241 | jmp DetectPrint_NullTerminatedStringFromCSSIandSetCF
|
|---|
| 242 |
|
|---|
| 243 |
|
|---|
| 244 | ;--------------------------------------------------------------------
|
|---|
| 245 | ; CreateBiosTablesForHardDisk
|
|---|
| 246 | ; Parameters:
|
|---|
| 247 | ; BH: Drive Select byte for Drive and Head Register
|
|---|
| 248 | ; DX: Autodetected port (for devices that support autodetection)
|
|---|
| 249 | ; CS:BP: Ptr to IDEVARS for the drive
|
|---|
| 250 | ; ES:SI Ptr to ATA information for the drive
|
|---|
| 251 | ; DS: RAMVARS segment
|
|---|
| 252 | ; ES: BDA segment
|
|---|
| 253 | ; Returns:
|
|---|
| 254 | ; Nothing
|
|---|
| 255 | ; Corrupts registers:
|
|---|
| 256 | ; AX, BX, CX, DX, SI, DI
|
|---|
| 257 | ;--------------------------------------------------------------------
|
|---|
| 258 | CreateBiosTablesForHardDisk:
|
|---|
| 259 | push bx
|
|---|
| 260 | call AtaID_VerifyFromESSI
|
|---|
| 261 | pop bx
|
|---|
| 262 | jc SHORT DetectDrives_DriveNotFound
|
|---|
| 263 | call CreateDPT_FromAtaInformation
|
|---|
| 264 | jc SHORT DetectDrives_DriveNotFound
|
|---|
| 265 | call DriveDetectInfo_CreateForHardDisk
|
|---|
| 266 | jmp SHORT DetectPrint_DriveNameFromDrvDetectInfoInESBX
|
|---|
| 267 |
|
|---|
| 268 |
|
|---|
| 269 | %ifdef MODULE_8BIT_IDE
|
|---|
| 270 | ;--------------------------------------------------------------------
|
|---|
| 271 | ; DetectDrives_DoesIdevarsInCSBPbelongToXTCF
|
|---|
| 272 | ; Parameters:
|
|---|
| 273 | ; CS:BP: Ptr to IDEVARS for the drive
|
|---|
| 274 | ; Returns:
|
|---|
| 275 | ; ZF: Set if IDEVARS belongs to XT-CF device
|
|---|
| 276 | ; Cleared if some other device
|
|---|
| 277 | ; Corrupts registers:
|
|---|
| 278 | ; AL
|
|---|
| 279 | ;--------------------------------------------------------------------
|
|---|
| 280 | DetectDrives_DoesIdevarsInCSBPbelongToXTCF:
|
|---|
| 281 | mov al, [cs:bp+IDEVARS.bDevice]
|
|---|
| 282 | cmp al, DEVICE_8BIT_XTCF_PIO8
|
|---|
| 283 | je SHORT .DeviceIsXTCF
|
|---|
| 284 | cmp al, DEVICE_8BIT_XTCF_DMA
|
|---|
| 285 | je SHORT .DeviceIsXTCF
|
|---|
| 286 | cmp al, DEVICE_8BIT_XTCF_MEMMAP
|
|---|
| 287 | .DeviceIsXTCF:
|
|---|
| 288 | NoSlaveDriveAvailable:
|
|---|
| 289 | ret
|
|---|
| 290 | %endif ; MODULE_8BIT_IDE
|
|---|
