1 | ; Project name : XTIDE Universal BIOS |
---|
2 | ; Description : Common functions for initializing different |
---|
3 | ; VLB and PCI IDE Controllers. |
---|
4 | |
---|
5 | ; |
---|
6 | ; XTIDE Universal BIOS and Associated Tools |
---|
7 | ; Copyright (C) 2009-2010 by Tomi Tilli, 2011-2013 by XTIDE Universal BIOS Team. |
---|
8 | ; |
---|
9 | ; This program is free software; you can redistribute it and/or modify |
---|
10 | ; it under the terms of the GNU General Public License as published by |
---|
11 | ; the Free Software Foundation; either version 2 of the License, or |
---|
12 | ; (at your option) any later version. |
---|
13 | ; |
---|
14 | ; This program is distributed in the hope that it will be useful, |
---|
15 | ; but WITHOUT ANY WARRANTY; without even the implied warranty of |
---|
16 | ; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
---|
17 | ; GNU General Public License for more details. |
---|
18 | ; Visit http://www.gnu.org/licenses/old-licenses/gpl-2.0.html |
---|
19 | ; |
---|
20 | |
---|
21 | ; Section containing code |
---|
22 | SECTION .text |
---|
23 | |
---|
24 | ;-------------------------------------------------------------------- |
---|
25 | ; AdvAtaInit_DetectControllerForIdeBaseInBX |
---|
26 | ; Parameters: |
---|
27 | ; BX: IDE Controller base port |
---|
28 | ; Returns: |
---|
29 | ; AX: ID WORD specific for detected controller |
---|
30 | ; Zero if no controller detected |
---|
31 | ; DX: Controller base port (not IDE) |
---|
32 | ; CF: Set if controller detected |
---|
33 | ; Cleared if no controller |
---|
34 | ; Corrupts registers: |
---|
35 | ; BX |
---|
36 | ;-------------------------------------------------------------------- |
---|
37 | AdvAtaInit_DetectControllerForIdeBaseInBX: |
---|
38 | call Vision_DetectAndReturnIDinAXandPortInDXifControllerPresent |
---|
39 | jnz SHORT .NoVisionControllerFound |
---|
40 | |
---|
41 | call Vision_DoesIdePortInBXbelongToControllerWithIDinAX |
---|
42 | jz SHORT .AdvancedControllerFoundForPortBX |
---|
43 | |
---|
44 | .NoVisionControllerFound: |
---|
45 | call PDC20x30_DetectControllerForIdeBaseInBX |
---|
46 | jnc SHORT .NoAdvancedControllerForPortBX |
---|
47 | |
---|
48 | .AdvancedControllerFoundForPortBX: |
---|
49 | stc |
---|
50 | ret |
---|
51 | |
---|
52 | .NoAdvancedControllerForPortBX: |
---|
53 | xor ax, ax ; Clear ID in AX and CF |
---|
54 | ret |
---|
55 | |
---|
56 | |
---|
57 | ;-------------------------------------------------------------------- |
---|
58 | ; AdvAtaInit_GetControllerMaxPioModeToALandMinPioCycleTimeToBX |
---|
59 | ; Parameters: |
---|
60 | ; AX: ID WORD specific for detected controller |
---|
61 | ; Returns: |
---|
62 | ; AL: Max supported PIO mode |
---|
63 | ; AH: FLGH_DPT_IORDY if IORDY supported, zero otherwise |
---|
64 | ; BX: Min PIO cycle time (only if ZF set) |
---|
65 | ; ZF: Set if PIO limit necessary |
---|
66 | ; Cleared if no need to limit timings |
---|
67 | ; Corrupts registers: |
---|
68 | ; Nothing |
---|
69 | ;-------------------------------------------------------------------- |
---|
70 | AdvAtaInit_GetControllerMaxPioModeToALandMinPioCycleTimeToBX: |
---|
71 | cmp ah, ID_QD6580_ALTERNATE |
---|
72 | %ifdef USE_386 |
---|
73 | jae Vision_GetMaxPioModeToALandMinCycleTimeToBX |
---|
74 | jmp PDC20x30_GetMaxPioModeToALandMinPioCycleTimeToBX |
---|
75 | %else |
---|
76 | jae SHORT .Vision |
---|
77 | jmp PDC20x30_GetMaxPioModeToALandMinPioCycleTimeToBX |
---|
78 | .Vision: |
---|
79 | jmp Vision_GetMaxPioModeToALandMinCycleTimeToBX |
---|
80 | %endif |
---|
81 | |
---|
82 | |
---|
83 | ;-------------------------------------------------------------------- |
---|
84 | ; AdvAtaInit_InitializeControllerForDPTinDSDI |
---|
85 | ; Parameters: |
---|
86 | ; DS:DI: Ptr to DPT for Single or Slave Drive |
---|
87 | ; Returns: |
---|
88 | ; AH: Int 13h return status |
---|
89 | ; CF: Cleared if success or no controller to initialize |
---|
90 | ; Set if error |
---|
91 | ; Corrupts registers: |
---|
92 | ; AL, BX, CX, DX |
---|
93 | ;-------------------------------------------------------------------- |
---|
94 | AdvAtaInit_InitializeControllerForDPTinDSDI: |
---|
95 | ; Call Controller Specific initialization function |
---|
96 | mov ax, [di+DPT_ADVANCED_ATA.wControllerID] |
---|
97 | test ax, ax |
---|
98 | jz SHORT .NoAdvancedController ; Return with CF cleared |
---|
99 | |
---|
100 | cmp ah, ID_QD6580_ALTERNATE |
---|
101 | jae SHORT .Vision |
---|
102 | jmp PDC20x30_InitializeForDPTinDSDI |
---|
103 | |
---|
104 | .Vision: |
---|
105 | push bp |
---|
106 | push si |
---|
107 | |
---|
108 | call AdvAtaInit_LoadMasterDPTtoDSSIifSlaveInDSDI |
---|
109 | call Vision_InitializeWithIDinAH |
---|
110 | xor ax, ax ; Success |
---|
111 | |
---|
112 | pop si |
---|
113 | pop bp |
---|
114 | |
---|
115 | .NoAdvancedController: |
---|
116 | ret |
---|
117 | |
---|
118 | |
---|
119 | ;-------------------------------------------------------------------- |
---|
120 | ; AdvAtaInit_LoadMasterDPTtoDSSIifSlaveInDSDI |
---|
121 | ; Parameters: |
---|
122 | ; DS:DI: Ptr to DPT for Single or Slave Drive |
---|
123 | ; Returns: |
---|
124 | ; SI: Offset to Master DPT if Slave Drive present |
---|
125 | ; Zero if Slave Drive not present |
---|
126 | ; Corrupts registers: |
---|
127 | ; AL |
---|
128 | ;-------------------------------------------------------------------- |
---|
129 | AdvAtaInit_LoadMasterDPTtoDSSIifSlaveInDSDI: |
---|
130 | ; Must be Slave Drive if previous DPT has same IDEVARS offset |
---|
131 | lea si, [di-LARGEST_DPT_SIZE] ; DS:SI points to previous DPT |
---|
132 | mov al, [di+DPT.bIdevarsOffset] |
---|
133 | cmp al, [si+DPT.bIdevarsOffset] |
---|
134 | je SHORT .MasterAndSlaveDrivePresent |
---|
135 | |
---|
136 | ; We only have single drive so zero SI |
---|
137 | xor si, si |
---|
138 | .MasterAndSlaveDrivePresent: |
---|
139 | ret |
---|
140 | |
---|
141 | |
---|
142 | ;-------------------------------------------------------------------- |
---|
143 | ; AdvAtaInit_SelectSlowestCommonPioTimingsToBXandCXfromDSSIandDSDI |
---|
144 | ; Parameters: |
---|
145 | ; DS:DI: Ptr to DPT for Single or Slave Drive |
---|
146 | ; SI: Offset to Master DPT if Slave Drive present |
---|
147 | ; Zero if Slave Drive not present |
---|
148 | ; Returns: |
---|
149 | ; BX: Best common PIO mode |
---|
150 | ; CX: Slowest common PIO Cycle Time in nanosecs |
---|
151 | ; Corrupts registers: |
---|
152 | ; Nothing |
---|
153 | ;-------------------------------------------------------------------- |
---|
154 | AdvAtaInit_SelectSlowestCommonPioTimingsToBXandCXfromDSSIandDSDI: |
---|
155 | eMOVZX bx, [di+DPT_ADVANCED_ATA.bPioMode] |
---|
156 | mov cx, [di+DPT_ADVANCED_ATA.wMinPioCycleTime] |
---|
157 | test si, si |
---|
158 | jz SHORT .PioTimingsLoadedToBXandCX |
---|
159 | MIN_U bl, [si+DPT_ADVANCED_ATA.bPioMode] |
---|
160 | MAX_U cx, [si+DPT_ADVANCED_ATA.wMinPioCycleTime] |
---|
161 | .PioTimingsLoadedToBXandCX: |
---|
162 | ret |
---|