source: xtideuniversalbios/trunk/XTIDE_Universal_BIOS/Src/Initialization/AdvancedAta/AdvAtaInit.asm @ 534

Last change on this file since 534 was 526, checked in by krille_n_@…, 9 years ago

Changes:

  • Update of the copyright notices to include the year 2013.
File size: 4.7 KB
Line 
1; Project name  :   XTIDE Universal BIOS
2; Description   :   Common functions for initializing different
3;                   VLB and PCI IDE Controllers.
4
5;
6; XTIDE Universal BIOS and Associated Tools
7; Copyright (C) 2009-2010 by Tomi Tilli, 2011-2013 by XTIDE Universal BIOS Team.
8;
9; This program is free software; you can redistribute it and/or modify
10; it under the terms of the GNU General Public License as published by
11; the Free Software Foundation; either version 2 of the License, or
12; (at your option) any later version.
13;
14; This program is distributed in the hope that it will be useful,
15; but WITHOUT ANY WARRANTY; without even the implied warranty of
16; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
17; GNU General Public License for more details.
18; Visit http://www.gnu.org/licenses/old-licenses/gpl-2.0.html
19;
20
21; Section containing code
22SECTION .text
23
24;--------------------------------------------------------------------
25; AdvAtaInit_DetectControllerForIdeBaseInBX
26;   Parameters:
27;       BX:     IDE Controller base port
28;   Returns:
29;       AX:     ID WORD specific for detected controller
30;               Zero if no controller detected
31;       DX:     Controller base port (not IDE)
32;       CF:     Set if controller detected
33;               Cleared if no controller
34;   Corrupts registers:
35;       BX
36;--------------------------------------------------------------------
37AdvAtaInit_DetectControllerForIdeBaseInBX:
38    call    Vision_DetectAndReturnIDinAXandPortInDXifControllerPresent
39    jne     SHORT .NoAdvancedControllerForPortBX
40    call    Vision_DoesIdePortInBXbelongToControllerWithIDinAX
41    jne     SHORT .NoAdvancedControllerForPortBX
42
43    stc     ; Advanced Controller found for port BX
44    ret
45
46.NoAdvancedControllerForPortBX:
47    xor     ax, ax
48    ret
49
50
51;--------------------------------------------------------------------
52; AdvAtaInit_GetControllerMaxPioModeToAL
53;   Parameters:
54;       AX:     ID WORD specific for detected controller
55;   Returns:
56;       AL:     Max supported PIO mode
57;       AH:     FLGH_DPT_IORDY if IORDY supported, zero otherwise
58;       CF:     Set if PIO limit necessary
59;               Cleared if no need to limit timings
60;   Corrupts registers:
61;       (AX if CF cleared)
62;--------------------------------------------------------------------
63AdvAtaInit_GetControllerMaxPioModeToAL  equ Vision_GetMaxPioModeToAL
64
65
66;--------------------------------------------------------------------
67; AdvAtaInit_InitializeControllerForDPTinDSDI
68;   Parameters:
69;       DS:DI:  Ptr to DPT for Single or Slave Drive
70;   Returns:
71;       AH:     Int 13h return status
72;       CF:     Cleared if success or no controller to initialize
73;               Set if error
74;   Corrupts registers:
75;       AL, BX, CX, DX
76;--------------------------------------------------------------------
77AdvAtaInit_InitializeControllerForDPTinDSDI:
78    ; Call Controller Specific initialization function
79    mov     ax, [di+DPT_ADVANCED_ATA.wControllerID]
80    test    ax, ax
81    jz      SHORT .NoAdvancedController ; Return with CF cleared
82
83    push    bp
84    push    si
85
86    ; We only support Vision at the moment so no need to identify ID
87    call    AdvAtaInit_LoadMasterDPTtoDSSIifSlaveInDSDI
88    call    Vision_InitializeWithIDinAHandConfigInAL
89
90    pop     si
91    pop     bp
92
93.NoAdvancedController:
94    xor     ax, ax                      ; Success
95    ret
96
97
98;--------------------------------------------------------------------
99; AdvAtaInit_LoadMasterDPTtoDSSIifSlaveInDSDI
100;   Parameters:
101;       DS:DI:  Ptr to DPT for Single or Slave Drive
102;   Returns:
103;       SI:     Offset to Master DPT if Slave Drive present
104;               Zero if Slave Drive not present
105;   Corrupts registers:
106;       AX
107;--------------------------------------------------------------------
108AdvAtaInit_LoadMasterDPTtoDSSIifSlaveInDSDI:
109    ; Must be Slave Drive if previous DPT has same IDEVARS offset
110    lea     si, [di-LARGEST_DPT_SIZE]   ; DS:SI points to previous DPT
111    mov     al, [di+DPT.bIdevarsOffset]
112    cmp     al, [si+DPT.bIdevarsOffset]
113    je      SHORT .MasterAndSlaveDrivePresent
114
115    ; We only have single drive so zero SI
116    xor     si, si
117.MasterAndSlaveDrivePresent:
118    ret
119
120
121;--------------------------------------------------------------------
122; AdvAtaInit_SelectSlowestCommonPioTimingsToBXandCXfromDSSIandDSDI
123;   Parameters:
124;       DS:DI:  Ptr to DPT for Single or Slave Drive
125;       SI:     Offset to Master DPT if Slave Drive present
126;               Zero if Slave Drive not present
127;   Returns:
128;       BX:     Best common PIO mode
129;       CX:     Slowest common PIO Cycle Time in nanosecs
130;   Corrupts registers:
131;       Nothing
132;--------------------------------------------------------------------
133AdvAtaInit_SelectSlowestCommonPioTimingsToBXandCXfromDSSIandDSDI:
134    eMOVZX  bx, [di+DPT_ADVANCED_ATA.bPioMode]
135    mov     cx, [di+DPT_ADVANCED_ATA.wMinPioCycleTime]
136    test    si, si
137    jz      SHORT .PioTimingsLoadedToAXandCX
138    MIN_U   bl, [si+DPT_ADVANCED_ATA.bPioMode]
139    MAX_U   cx, [si+DPT_ADVANCED_ATA.wMinPioCycleTime]
140.PioTimingsLoadedToAXandCX:
141    ret
Note: See TracBrowser for help on using the repository browser.