source: xtideuniversalbios/trunk/XTIDE_Universal_BIOS/Src/Handlers/Int19h/BootSector.asm @ 521

Last change on this file since 521 was 521, checked in by aitotat@…, 11 years ago

Changes to XTIDE Universal BIOS:

  • Hopefully fixed problems with recent changes to AH=00h.
  • Timeout error code is no longer displayed when trying to boot from floppy drive.
File size: 4.2 KB
Line 
1; Project name  :   XTIDE Universal BIOS
2; Description   :   Reading and jumping to boot sector.
3
4;
5; XTIDE Universal BIOS and Associated Tools
6; Copyright (C) 2009-2010 by Tomi Tilli, 2011-2012 by XTIDE Universal BIOS Team.
7;
8; This program is free software; you can redistribute it and/or modify
9; it under the terms of the GNU General Public License as published by
10; the Free Software Foundation; either version 2 of the License, or
11; (at your option) any later version.
12;
13; This program is distributed in the hope that it will be useful,
14; but WITHOUT ANY WARRANTY; without even the implied warranty of
15; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
16; GNU General Public License for more details.
17; Visit http://www.gnu.org/licenses/old-licenses/gpl-2.0.html
18;
19
20; Section containing code
21SECTION .text
22
23;--------------------------------------------------------------------
24; BootSector_TryToLoadFromDriveDL_AndBoot
25;   Parameters:
26;       DL:     Drive to boot from (translated, 00h or 80h)
27;       DS:     RAMVARS segment
28;   Returns:
29;       ES:BX:  Ptr to boot sector (if successful)
30;       CF:     Set if boot sector loaded successfully
31;               Cleared if failed to load boot sector
32;   Corrupts registers:
33;       AX, CX, DH, SI, DI, (DL if failed to read boot sector)
34;--------------------------------------------------------------------
35BootSector_TryToLoadFromDriveDL_AndBoot:
36    call    DetectPrint_TryToBootFromDL
37    call    LoadFirstSectorFromDriveDL
38    jnc     SHORT .FirstSectorLoadedToESBX
39
40    ; Do not display timeout error (80h) for floppy drives since
41    ; it most likely mean no diskette in drive. This way we do not
42    ; display error code every time user intends to boot from hard disk
43    ; when A then C boot order is used.
44    js      SHORT .PrintFailedToLoadErrorCode   ; Hard Drive
45    cmp     ah, RET_HD_TIMEOUT
46    je      SHORT .ReturnWithCFclearSinceFailedToLoadBootSector
47    cmp     ah, RET_HD_NOMEDIA
48    je      SHORT .ReturnWithCFclearSinceFailedToLoadBootSector
49.PrintFailedToLoadErrorCode:
50%ifdef USE_186
51    push    .ReturnWithCFclearSinceFailedToLoadBootSector
52    jmp     DetectPrint_FailedToLoadFirstSector
53%else
54    call    DetectPrint_FailedToLoadFirstSector
55    jmp     .ReturnWithCFclearSinceFailedToLoadBootSector
56%endif
57
58
59.FirstSectorLoadedToESBX:
60    test    dl, dl
61    jns     SHORT .AlwaysBootFromFloppyDriveForBooterGames
62    cmp     WORD [es:bx+510], 0AA55h        ; Valid boot sector?
63    jne     SHORT .FirstHardDiskSectorNotBootable
64.AlwaysBootFromFloppyDriveForBooterGames:
65    stc     ; Boot Sector loaded succesfully
66    jmp     SHORT Int19_JumpToBootSectorOrRomBoot
67
68.FirstHardDiskSectorNotBootable:
69    mov     si, g_szBootSectorNotFound
70    call    DetectPrint_NullTerminatedStringFromCSSI
71.ReturnWithCFclearSinceFailedToLoadBootSector:
72    clc
73    ret
74
75%ifndef CHECK_FOR_UNUSED_ENTRYPOINTS
76  %ifdef MODULE_DRIVEXLATE
77    %if TryToBoot_FallThroughTo_BootSector_TryToLoadFromDriveDL_AndBoot <> BootSector_TryToLoadFromDriveDL_AndBoot
78      %error "TryToBoot_FallThroughTo_BootSector_TryToLoadFromDriveDL_AndBoot <> BootSector_TryToLoadFromDriveDL_AndBoot, BootSector must come immediately after int19h.asm"
79    %endif
80  %endif
81%endif
82
83;--------------------------------------------------------------------
84; LoadFirstSectorFromDriveDL
85;   Parameters:
86;       DL:     Drive to boot from (translated, 00h or 80h)
87;   Returns:
88;       AH:     INT 13h error code
89;       ES:BX:  Ptr to boot sector (if successful)
90;       CF:     Cleared if read successful
91;               Set if any error
92;   Corrupts registers:
93;       AL, CX, DH, DI
94;--------------------------------------------------------------------
95LoadFirstSectorFromDriveDL:
96    LOAD_BDA_SEGMENT_TO es, bx              ; ES:BX now points to...
97    mov     bx, BOOTVARS.rgbBootSect        ; ...boot sector location
98    mov     di, BOOT_READ_RETRY_TIMES       ; Initialize retry counter
99
100.ReadRetryLoop:
101    mov     ax, 0201h                       ; Read 1 sector
102    mov     cx, 1                           ; Cylinder 0, Sector 1
103    xor     dh, dh                          ; Head 0
104    int     BIOS_DISK_INTERRUPT_13h
105    jc      SHORT .FailedToLoadFirstSector
106.Return:
107    ret
108
109.FailedToLoadFirstSector:
110    dec     di                              ; Decrement retry counter (preserve CF)
111    jz      SHORT .Return                   ; Loop while retries left
112
113    ; Reset drive and retry
114    xor     ax, ax                          ; AH=00h, Disk Controller Reset
115    test    dl, dl                          ; Floppy drive?
116    eCMOVS  ah, RESET_HARD_DISK             ; AH=0Dh, Reset Hard Disk (Alternate reset)
117    int     BIOS_DISK_INTERRUPT_13h
118    jmp     SHORT .ReadRetryLoop
119
Note: See TracBrowser for help on using the repository browser.