| 1 | ; Project name : XTIDE Universal BIOS
|
|---|
| 2 | ; Description : Int 13h function AH=9h, Initialize Drive Parameters.
|
|---|
| 3 |
|
|---|
| 4 | ;
|
|---|
| 5 | ; XTIDE Universal BIOS and Associated Tools
|
|---|
| 6 | ; Copyright (C) 2009-2010 by Tomi Tilli, 2011-2013 by XTIDE Universal BIOS Team.
|
|---|
| 7 | ;
|
|---|
| 8 | ; This program is free software; you can redistribute it and/or modify
|
|---|
| 9 | ; it under the terms of the GNU General Public License as published by
|
|---|
| 10 | ; the Free Software Foundation; either version 2 of the License, or
|
|---|
| 11 | ; (at your option) any later version.
|
|---|
| 12 | ;
|
|---|
| 13 | ; This program is distributed in the hope that it will be useful,
|
|---|
| 14 | ; but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|---|
| 15 | ; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|---|
| 16 | ; GNU General Public License for more details.
|
|---|
| 17 | ; Visit http://www.gnu.org/licenses/old-licenses/gpl-2.0.html
|
|---|
| 18 | ;
|
|---|
| 19 |
|
|---|
| 20 | ; Section containing code
|
|---|
| 21 | SECTION .text
|
|---|
| 22 |
|
|---|
| 23 | ;--------------------------------------------------------------------
|
|---|
| 24 | ; STORE_ERROR_FLAG_TO_DPT
|
|---|
| 25 | ; Parameters:
|
|---|
| 26 | ; %1: Error flag to set
|
|---|
| 27 | ; AH: BIOS Error Code
|
|---|
| 28 | ; DS:DI: Ptr to DPT
|
|---|
| 29 | ; CF: Set if error code in AH
|
|---|
| 30 | ; Returns:
|
|---|
| 31 | ; CF: Clear if no error
|
|---|
| 32 | ; Set if error flag was set
|
|---|
| 33 | ; Corrupts registers:
|
|---|
| 34 | ; Nothing
|
|---|
| 35 | ;--------------------------------------------------------------------
|
|---|
| 36 | %macro STORE_ERROR_FLAG_TO_DPT 1
|
|---|
| 37 | mov al, %1
|
|---|
| 38 | call SetErrorFlagFromALwithErrorCodeInAH
|
|---|
| 39 | %endmacro
|
|---|
| 40 |
|
|---|
| 41 |
|
|---|
| 42 | ;--------------------------------------------------------------------
|
|---|
| 43 | ; Int 13h function AH=9h, Initialize Drive Parameters.
|
|---|
| 44 | ;
|
|---|
| 45 | ; AH9h_HandlerForInitializeDriveParameters
|
|---|
| 46 | ; Parameters:
|
|---|
| 47 | ; DL: Translated Drive number
|
|---|
| 48 | ; DS:DI: Ptr to DPT (in RAMVARS segment)
|
|---|
| 49 | ; SS:BP: Ptr to IDEPACK
|
|---|
| 50 | ; Returns with INTPACK:
|
|---|
| 51 | ; AH: Int 13h return status
|
|---|
| 52 | ; CF: 0 if successful, 1 if error
|
|---|
| 53 | ;--------------------------------------------------------------------
|
|---|
| 54 | AH9h_HandlerForInitializeDriveParameters:
|
|---|
| 55 | %ifndef USE_186
|
|---|
| 56 | call AH9h_InitializeDriveForUse
|
|---|
| 57 | jmp Int13h_ReturnFromHandlerAfterStoringErrorCodeFromAH
|
|---|
| 58 | %else
|
|---|
| 59 | push Int13h_ReturnFromHandlerAfterStoringErrorCodeFromAH
|
|---|
| 60 | ; Fall to AH9h_InitializeDriveForUse
|
|---|
| 61 | %endif
|
|---|
| 62 |
|
|---|
| 63 |
|
|---|
| 64 | ;--------------------------------------------------------------------
|
|---|
| 65 | ; Initialize drive to be ready for use.
|
|---|
| 66 | ;
|
|---|
| 67 | ; AH9h_InitializeDriveForUse
|
|---|
| 68 | ; Parameters:
|
|---|
| 69 | ; DS:DI: Ptr to DPT (in RAMVARS segment)
|
|---|
| 70 | ; SS:BP: Ptr to IDEPACK
|
|---|
| 71 | ; Returns:
|
|---|
| 72 | ; AH: Int 13h return status
|
|---|
| 73 | ; CF: 0 if successful, 1 if error
|
|---|
| 74 | ; Corrupts registers:
|
|---|
| 75 | ; AL, CX
|
|---|
| 76 | ;--------------------------------------------------------------------
|
|---|
| 77 | AH9h_InitializeDriveForUse:
|
|---|
| 78 | xor ax, ax ; Clear AH to assume no errors
|
|---|
| 79 |
|
|---|
| 80 | %ifdef MODULE_ADVANCED_ATA
|
|---|
| 81 | ; Clear Initialization Error flags from DPT
|
|---|
| 82 | mov [di+DPT.bInitError], al
|
|---|
| 83 | %endif
|
|---|
| 84 |
|
|---|
| 85 | %ifdef MODULE_SERIAL
|
|---|
| 86 | ; No need to do this for serial devices
|
|---|
| 87 | test BYTE [di+DPT.bFlagsHigh], FLGH_DPT_SERIAL_DEVICE ; Clears CF
|
|---|
| 88 | jz SHORT .ContinueInitialization
|
|---|
| 89 | ret ; With AH and CF cleared
|
|---|
| 90 | .ContinueInitialization:
|
|---|
| 91 | %endif
|
|---|
| 92 |
|
|---|
| 93 | push es
|
|---|
| 94 | push si
|
|---|
| 95 | push dx
|
|---|
| 96 | push bx
|
|---|
| 97 |
|
|---|
| 98 |
|
|---|
| 99 | ;;; SelectDrive
|
|---|
| 100 | ; Try to select drive and wait until ready
|
|---|
| 101 | call AccessDPT_GetDriveSelectByteToAL
|
|---|
| 102 | mov [bp+IDEPACK.bDrvAndHead], al
|
|---|
| 103 | call Device_SelectDrive
|
|---|
| 104 | STORE_ERROR_FLAG_TO_DPT FLG_INITERROR_FAILED_TO_SELECT_DRIVE
|
|---|
| 105 | %ifdef USE_386
|
|---|
| 106 | jc .ReturnWithErrorCodeInAH
|
|---|
| 107 | %else
|
|---|
| 108 | jnc SHORT .ContinueInitializationSinceDriveSelectedSuccessfully
|
|---|
| 109 | jmp .ReturnWithErrorCodeInAH
|
|---|
| 110 | .ContinueInitializationSinceDriveSelectedSuccessfully:
|
|---|
| 111 | %endif
|
|---|
| 112 |
|
|---|
| 113 |
|
|---|
| 114 | %ifdef MODULE_8BIT_IDE_ADVANCED
|
|---|
| 115 | ;;; Set XT-CF mode
|
|---|
| 116 | call AH1Eh_GetCurrentXTCFmodeToAX
|
|---|
| 117 | call AH9h_SetModeFromALtoXTCF
|
|---|
| 118 | STORE_ERROR_FLAG_TO_DPT FLG_INITERROR_FAILED_TO_SET_XTCF_MODE
|
|---|
| 119 | %endif ; MODULE_8BIT_IDE_ADVANCED
|
|---|
| 120 |
|
|---|
| 121 | %ifdef MODULE_8BIT_IDE
|
|---|
| 122 | ;;; Set 8-bit PIO mode
|
|---|
| 123 | call AH9h_Enable8bitModeForDevice8bitAta
|
|---|
| 124 | STORE_ERROR_FLAG_TO_DPT FLG_INITERROR_FAILED_TO_SET_8BIT_MODE
|
|---|
| 125 | %endif ; MODULE_8BIT_IDE
|
|---|
| 126 |
|
|---|
| 127 |
|
|---|
| 128 | ;;; InitializeDeviceParameters
|
|---|
| 129 | ; Initialize Logical Sectors per Track and Max Head number
|
|---|
| 130 | mov ax, [di+DPT.wPchsHeadsAndSectors]
|
|---|
| 131 | dec ax ; Max Head number
|
|---|
| 132 | xchg ah, al
|
|---|
| 133 | mov dl, al ; Sectors per track
|
|---|
| 134 | mov al, COMMAND_INITIALIZE_DEVICE_PARAMETERS
|
|---|
| 135 | mov bx, TIMEOUT_AND_STATUS_TO_WAIT(TIMEOUT_BSY, FLG_STATUS_BSY)
|
|---|
| 136 | call Idepack_StoreNonExtParametersAndIssueCommandFromAL
|
|---|
| 137 | STORE_ERROR_FLAG_TO_DPT FLG_INITERROR_FAILED_TO_INITIALIZE_CHS_PARAMETERS
|
|---|
| 138 |
|
|---|
| 139 |
|
|---|
| 140 | ;;; SetWriteCache
|
|---|
| 141 | ; Enable or Disable Write Cache
|
|---|
| 142 | call AccessDPT_GetPointerToDRVPARAMStoCSBX
|
|---|
| 143 | mov bl, [cs:bx+DRVPARAMS.wFlags]
|
|---|
| 144 | push bx ; Save .wFlags for later use in InitializeBlockMode
|
|---|
| 145 | and bx, BYTE MASK_DRVPARAMS_WRITECACHE
|
|---|
| 146 | jz SHORT .SkipSetWriteCache ; DEFAULT_WRITE_CACHE
|
|---|
| 147 | mov si, [cs:bx+.rgbWriteCacheCommands]
|
|---|
| 148 | call AH23h_SetControllerFeatures
|
|---|
| 149 | STORE_ERROR_FLAG_TO_DPT FLG_INITERROR_FAILED_TO_SET_WRITE_CACHE
|
|---|
| 150 | .SkipSetWriteCache:
|
|---|
| 151 |
|
|---|
| 152 |
|
|---|
| 153 | ;;; RecalibrateDrive
|
|---|
| 154 | ; Recalibrate drive by seeking to cylinder 0
|
|---|
| 155 | call AH11h_RecalibrateDrive
|
|---|
| 156 | STORE_ERROR_FLAG_TO_DPT FLG_INITERROR_FAILED_TO_RECALIBRATE_DRIVE
|
|---|
| 157 |
|
|---|
| 158 |
|
|---|
| 159 | ;;; InitializeBlockMode
|
|---|
| 160 | ; Initialize block mode transfers
|
|---|
| 161 | pop ax ; Restore .wFlags saved in SetWriteCache
|
|---|
| 162 | test al, FLG_DRVPARAMS_BLOCKMODE ; Tested here so block mode can be enabled with AH=24h
|
|---|
| 163 | jz SHORT .BlockModeDisabled
|
|---|
| 164 |
|
|---|
| 165 | ; Try block sizes until we find largest possible supported by drive
|
|---|
| 166 | mov bl, 128
|
|---|
| 167 | .TryNextBlockSize:
|
|---|
| 168 | mov al, bl
|
|---|
| 169 | call AH24h_SetBlockSize ; Stores block size to DPT
|
|---|
| 170 | jnc SHORT .SupportedBlockSizeFound
|
|---|
| 171 | shr bl, 1
|
|---|
| 172 | jnc SHORT .TryNextBlockSize
|
|---|
| 173 | STORE_ERROR_FLAG_TO_DPT FLG_INITERROR_FAILED_TO_SET_BLOCK_MODE
|
|---|
| 174 | .BlockModeDisabled:
|
|---|
| 175 | .SupportedBlockSizeFound:
|
|---|
| 176 |
|
|---|
| 177 |
|
|---|
| 178 | %ifdef MODULE_ADVANCED_ATA
|
|---|
| 179 | ;;; InitializePioMode
|
|---|
| 180 | ; Initialize fastest supported PIO mode
|
|---|
| 181 | mov dl, PIO_DEFAULT_MODE_DISABLE_IORDY
|
|---|
| 182 | test BYTE [di+DPT.bFlagsHigh], FLGH_DPT_IORDY
|
|---|
| 183 | jz SHORT .IordyNotSupported
|
|---|
| 184 |
|
|---|
| 185 | ; Advanced PIO mode 3 and above
|
|---|
| 186 | mov dl, [di+DPT_ADVANCED_ATA.bPioMode]
|
|---|
| 187 | or dl, PIO_FLOW_CONTROL_MODE_xxx
|
|---|
| 188 |
|
|---|
| 189 | .IordyNotSupported:
|
|---|
| 190 | mov si, FEATURE_SET_TRANSFER_MODE
|
|---|
| 191 | call AH23h_SetControllerFeatures
|
|---|
| 192 | STORE_ERROR_FLAG_TO_DPT FLG_INITERROR_FAILED_TO_SET_PIO_MODE
|
|---|
| 193 | %endif ; MODULE_ADVANCED_ATA
|
|---|
| 194 |
|
|---|
| 195 |
|
|---|
| 196 | %ifdef MODULE_FEATURE_SETS
|
|---|
| 197 | ;;; InitStandbyTimer
|
|---|
| 198 | ; Initialize the standby timer (if supported)
|
|---|
| 199 | test BYTE [di+DPT.bFlagsHigh], FLGH_DPT_POWER_MANAGEMENT_SUPPORTED
|
|---|
| 200 | jz SHORT .NoPowerManagementSupport
|
|---|
| 201 |
|
|---|
| 202 | mov al, COMMAND_IDLE
|
|---|
| 203 | mov dl, [cs:ROMVARS.bIdleTimeout]
|
|---|
| 204 | mov bx, TIMEOUT_AND_STATUS_TO_WAIT(TIMEOUT_BSY, FLG_STATUS_BSY)
|
|---|
| 205 | call Idepack_StoreNonExtParametersAndIssueCommandFromAL
|
|---|
| 206 | STORE_ERROR_FLAG_TO_DPT FLG_INITERROR_FAILED_TO_INITIALIZE_STANDBY_TIMER
|
|---|
| 207 | .NoPowerManagementSupport:
|
|---|
| 208 | %endif ; MODULE_FEATURE_SETS
|
|---|
| 209 |
|
|---|
| 210 |
|
|---|
| 211 | ; There might have been several errors so just return one error code for them all
|
|---|
| 212 | .ReturnWithErrorCodeInAH:
|
|---|
| 213 | %ifdef MODULE_ADVANCED_ATA
|
|---|
| 214 | mov ah, [di+DPT.bInitError]
|
|---|
| 215 | test ah, ah ; Clears CF
|
|---|
| 216 | jz SHORT .ReturnWithSuccess
|
|---|
| 217 | mov ah, RET_HD_RESETFAIL
|
|---|
| 218 | stc
|
|---|
| 219 | .ReturnWithSuccess:
|
|---|
| 220 | %endif
|
|---|
| 221 |
|
|---|
| 222 | pop bx
|
|---|
| 223 | pop dx
|
|---|
| 224 | pop si
|
|---|
| 225 | pop es
|
|---|
| 226 | ret
|
|---|
| 227 |
|
|---|
| 228 |
|
|---|
| 229 | .rgbWriteCacheCommands:
|
|---|
| 230 | db 0 ; DEFAULT_WRITE_CACHE
|
|---|
| 231 | db FEATURE_DISABLE_WRITE_CACHE ; DISABLE_WRITE_CACHE
|
|---|
| 232 | db FEATURE_ENABLE_WRITE_CACHE ; ENABLE_WRITE_CACHE
|
|---|
| 233 |
|
|---|
| 234 |
|
|---|
| 235 |
|
|---|
| 236 | ;--------------------------------------------------------------------
|
|---|
| 237 | ; SetErrorFlagFromALwithErrorCodeInAH
|
|---|
| 238 | ; Parameters:
|
|---|
| 239 | ; AH: BIOS Error Code
|
|---|
| 240 | ; AL: Error flag to set
|
|---|
| 241 | ; DS:DI: Ptr to DPT
|
|---|
| 242 | ; CF: Set if error code in AH
|
|---|
| 243 | ; Clear if AH = 0
|
|---|
| 244 | ; Returns:
|
|---|
| 245 | ; CF: Clear if no error
|
|---|
| 246 | ; Set if error flag was set
|
|---|
| 247 | ; Corrupts registers:
|
|---|
| 248 | ; Nothing
|
|---|
| 249 | ;--------------------------------------------------------------------
|
|---|
| 250 | IgnoreInvalidCommandError:
|
|---|
| 251 | xor ah, ah ; Clears CF
|
|---|
| 252 | SetErrorFlagFromALwithErrorCodeInAH:
|
|---|
| 253 | jnc SHORT .NoErrorFlagToSet
|
|---|
| 254 | cmp ah, RET_HD_INVALID
|
|---|
| 255 | jbe SHORT IgnoreInvalidCommandError
|
|---|
| 256 |
|
|---|
| 257 | or [di+DPT.bInitError], al
|
|---|
| 258 | stc
|
|---|
| 259 | .NoErrorFlagToSet:
|
|---|
| 260 | ret
|
|---|
| 261 |
|
|---|
| 262 |
|
|---|
| 263 | %ifdef MODULE_8BIT_IDE_ADVANCED
|
|---|
| 264 | ;--------------------------------------------------------------------
|
|---|
| 265 | ; AH9h_SetModeFromALtoXTCF
|
|---|
| 266 | ; Parameters:
|
|---|
| 267 | ; AL: XT-CF Mode to set
|
|---|
| 268 | ; DS:DI: Ptr to DPT (in RAMVARS segment)
|
|---|
| 269 | ; SS:BP: Ptr to IDEPACK
|
|---|
| 270 | ; Returns:
|
|---|
| 271 | ; AH: Int 13h return status
|
|---|
| 272 | ; CF: Clear if successful or device is not XT-CF
|
|---|
| 273 | ; Set if failed to set mode for XT-CF
|
|---|
| 274 | ; Corrupts registers:
|
|---|
| 275 | ; AL, BX, CX, DX, SI
|
|---|
| 276 | ;--------------------------------------------------------------------
|
|---|
| 277 | AH9h_SetModeFromALtoXTCF:
|
|---|
| 278 | call AccessDPT_IsThisDeviceXTCF
|
|---|
| 279 | jne SHORT IgnoreInvalidCommandError
|
|---|
| 280 | jmp AH1Eh_ChangeXTCFmodeBasedOnModeInAL
|
|---|
| 281 | %endif ; MODULE_8BIT_IDE_ADVANCED
|
|---|
| 282 |
|
|---|
| 283 |
|
|---|
| 284 | %ifdef MODULE_8BIT_IDE
|
|---|
| 285 | ;--------------------------------------------------------------------
|
|---|
| 286 | ; AH9h_Enable8bitModeForDevice8bitAta
|
|---|
| 287 | ; Parameters:
|
|---|
| 288 | ; DS:DI: Ptr to DPT (in RAMVARS segment)
|
|---|
| 289 | ; SS:BP: Ptr to IDEPACK
|
|---|
| 290 | ; Returns:
|
|---|
| 291 | ; AH: Int 13h return status
|
|---|
| 292 | ; CF: Clear if successful or device is not DEVICE_8BIT_ATA
|
|---|
| 293 | ; Set if failed to set 8-bit mode for DEVICE_8BIT_ATA
|
|---|
| 294 | ; Corrupts registers:
|
|---|
| 295 | ; AL, BX, CX, DX, SI
|
|---|
| 296 | ;--------------------------------------------------------------------
|
|---|
| 297 | AH9h_Enable8bitModeForDevice8bitAta:
|
|---|
| 298 | cmp BYTE [di+DPT_ATA.bDevice], DEVICE_8BIT_ATA
|
|---|
| 299 | jne SHORT IgnoreInvalidCommandError
|
|---|
| 300 | jmp AH23h_Enable8bitPioMode
|
|---|
| 301 | %endif ; MODULE_8BIT_IDE
|
|---|
