| 1 | ; Project name : XTIDE Universal BIOS
|
|---|
| 2 | ; Description : Int 13h function AH=9h, Initialize Drive Parameters.
|
|---|
| 3 |
|
|---|
| 4 | ;
|
|---|
| 5 | ; XTIDE Universal BIOS and Associated Tools
|
|---|
| 6 | ; Copyright (C) 2009-2010 by Tomi Tilli, 2011-2013 by XTIDE Universal BIOS Team.
|
|---|
| 7 | ;
|
|---|
| 8 | ; This program is free software; you can redistribute it and/or modify
|
|---|
| 9 | ; it under the terms of the GNU General Public License as published by
|
|---|
| 10 | ; the Free Software Foundation; either version 2 of the License, or
|
|---|
| 11 | ; (at your option) any later version.
|
|---|
| 12 | ;
|
|---|
| 13 | ; This program is distributed in the hope that it will be useful,
|
|---|
| 14 | ; but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|---|
| 15 | ; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|---|
| 16 | ; GNU General Public License for more details.
|
|---|
| 17 | ; Visit http://www.gnu.org/licenses/old-licenses/gpl-2.0.html
|
|---|
| 18 | ;
|
|---|
| 19 |
|
|---|
| 20 | ; Section containing code
|
|---|
| 21 | SECTION .text
|
|---|
| 22 |
|
|---|
| 23 | ;--------------------------------------------------------------------
|
|---|
| 24 | ; STORE_ERROR_FLAG_TO_DPT
|
|---|
| 25 | ; Parameters:
|
|---|
| 26 | ; %1: Error flag to set
|
|---|
| 27 | ; AH: BIOS Error Code
|
|---|
| 28 | ; DS:DI: Ptr to DPT
|
|---|
| 29 | ; CF: Set if error code in AH
|
|---|
| 30 | ; Returns:
|
|---|
| 31 | ; CF: Clear if no error
|
|---|
| 32 | ; Set if error flag was set
|
|---|
| 33 | ; Corrupts registers:
|
|---|
| 34 | ; Nothing
|
|---|
| 35 | ;--------------------------------------------------------------------
|
|---|
| 36 | %macro STORE_ERROR_FLAG_TO_DPT 1
|
|---|
| 37 | mov al, %1
|
|---|
| 38 | call SetErrorFlagFromALwithErrorCodeInAH
|
|---|
| 39 | %endmacro
|
|---|
| 40 |
|
|---|
| 41 |
|
|---|
| 42 | ;--------------------------------------------------------------------
|
|---|
| 43 | ; Int 13h function AH=9h, Initialize Drive Parameters.
|
|---|
| 44 | ;
|
|---|
| 45 | ; AH9h_HandlerForInitializeDriveParameters
|
|---|
| 46 | ; Parameters:
|
|---|
| 47 | ; DL: Translated Drive number
|
|---|
| 48 | ; DS:DI: Ptr to DPT (in RAMVARS segment)
|
|---|
| 49 | ; SS:BP: Ptr to IDEPACK
|
|---|
| 50 | ; Returns with INTPACK:
|
|---|
| 51 | ; AH: Int 13h return status
|
|---|
| 52 | ; CF: 0 if successful, 1 if error
|
|---|
| 53 | ;--------------------------------------------------------------------
|
|---|
| 54 | AH9h_HandlerForInitializeDriveParameters:
|
|---|
| 55 | %ifndef USE_186
|
|---|
| 56 | call AH9h_InitializeDriveForUse
|
|---|
| 57 | jmp Int13h_ReturnFromHandlerAfterStoringErrorCodeFromAH
|
|---|
| 58 | %else
|
|---|
| 59 | push Int13h_ReturnFromHandlerAfterStoringErrorCodeFromAH
|
|---|
| 60 | ; Fall to AH9h_InitializeDriveForUse
|
|---|
| 61 | %endif
|
|---|
| 62 |
|
|---|
| 63 |
|
|---|
| 64 | ;--------------------------------------------------------------------
|
|---|
| 65 | ; Initialize drive to be ready for use.
|
|---|
| 66 | ;
|
|---|
| 67 | ; AH9h_InitializeDriveForUse
|
|---|
| 68 | ; Parameters:
|
|---|
| 69 | ; DS:DI: Ptr to DPT (in RAMVARS segment)
|
|---|
| 70 | ; SS:BP: Ptr to IDEPACK
|
|---|
| 71 | ; Returns:
|
|---|
| 72 | ; AH: Int 13h return status
|
|---|
| 73 | ; CF: 0 if successful, 1 if error
|
|---|
| 74 | ; Corrupts registers:
|
|---|
| 75 | ; AL, CX
|
|---|
| 76 | ;--------------------------------------------------------------------
|
|---|
| 77 | AH9h_InitializeDriveForUse:
|
|---|
| 78 | xor ax, ax ; Clear AH to assume no errors
|
|---|
| 79 |
|
|---|
| 80 | %ifdef MODULE_ADVANCED_ATA
|
|---|
| 81 | ; Clear Initialization Error flags from DPT
|
|---|
| 82 | mov [di+DPT.bInitError], al
|
|---|
| 83 | %endif
|
|---|
| 84 |
|
|---|
| 85 | %ifdef MODULE_SERIAL
|
|---|
| 86 | ; No need to do this for serial devices
|
|---|
| 87 | test BYTE [di+DPT.bFlagsHigh], FLGH_DPT_SERIAL_DEVICE ; Clears CF
|
|---|
| 88 | jz SHORT .ContinueInitialization
|
|---|
| 89 | ret ; With AH and CF cleared
|
|---|
| 90 | .ContinueInitialization:
|
|---|
| 91 | %endif
|
|---|
| 92 |
|
|---|
| 93 | push es
|
|---|
| 94 | push si
|
|---|
| 95 | push dx
|
|---|
| 96 | push bx
|
|---|
| 97 |
|
|---|
| 98 |
|
|---|
| 99 | ;;; SelectDrive
|
|---|
| 100 | ; Try to select drive and wait until ready
|
|---|
| 101 | call AccessDPT_GetDriveSelectByteToAL
|
|---|
| 102 | mov [bp+IDEPACK.bDrvAndHead], al
|
|---|
| 103 | call Device_SelectDrive
|
|---|
| 104 | STORE_ERROR_FLAG_TO_DPT FLG_INITERROR_FAILED_TO_SELECT_DRIVE
|
|---|
| 105 | %ifdef USE_386
|
|---|
| 106 | jc .ReturnWithErrorCodeInAH
|
|---|
| 107 | %else
|
|---|
| 108 | jnc SHORT .ContinueInitializationSinceDriveSelectedSuccesfully
|
|---|
| 109 | jmp .ReturnWithErrorCodeInAH
|
|---|
| 110 | .ContinueInitializationSinceDriveSelectedSuccesfully:
|
|---|
| 111 | %endif
|
|---|
| 112 |
|
|---|
| 113 |
|
|---|
| 114 | ;;; Set XT-CF mode
|
|---|
| 115 | %ifdef MODULE_8BIT_IDE_ADVANCED
|
|---|
| 116 | call AH1Eh_GetCurrentXTCFmodeToAX
|
|---|
| 117 | call AH9h_SetModeFromALtoXTCF
|
|---|
| 118 | STORE_ERROR_FLAG_TO_DPT FLG_INITERROR_FAILED_TO_SET_XTCF_MODE
|
|---|
| 119 | .DoNotSetXTCFmode:
|
|---|
| 120 | %endif ; MODULE_8BIT_IDE_ADVANCED
|
|---|
| 121 |
|
|---|
| 122 | %ifdef MODULE_8BIT_IDE
|
|---|
| 123 | ;;; Set 8-bit PIO mode
|
|---|
| 124 | call AH9h_Enable8bitModeForDevice8bitAta
|
|---|
| 125 | STORE_ERROR_FLAG_TO_DPT FLG_INITERROR_FAILED_TO_SET_8BIT_MODE
|
|---|
| 126 | .DoNotSet8bitMode:
|
|---|
| 127 | %endif ; MODULE_8BIT_IDE
|
|---|
| 128 |
|
|---|
| 129 |
|
|---|
| 130 | ;;; InitializeDeviceParameters
|
|---|
| 131 | ; Initialize Logical Sectors per Track and Max Head number
|
|---|
| 132 | mov ax, [di+DPT.wPchsHeadsAndSectors]
|
|---|
| 133 | dec ax ; Max Head number
|
|---|
| 134 | xchg ah, al
|
|---|
| 135 | mov dl, al ; Sectors per track
|
|---|
| 136 | mov al, COMMAND_INITIALIZE_DEVICE_PARAMETERS
|
|---|
| 137 | mov bx, TIMEOUT_AND_STATUS_TO_WAIT(TIMEOUT_BSY, FLG_STATUS_BSY)
|
|---|
| 138 | call Idepack_StoreNonExtParametersAndIssueCommandFromAL
|
|---|
| 139 | STORE_ERROR_FLAG_TO_DPT FLG_INITERROR_FAILED_TO_INITIALIZE_CHS_PARAMETERS
|
|---|
| 140 | .SkipInitializeDeviceParameters:
|
|---|
| 141 |
|
|---|
| 142 |
|
|---|
| 143 | ;;; SetWriteCache
|
|---|
| 144 | ; Enable or Disable Write Cache
|
|---|
| 145 | call AccessDPT_GetPointerToDRVPARAMStoCSBX
|
|---|
| 146 | mov bl, [cs:bx+DRVPARAMS.wFlags]
|
|---|
| 147 | push bx ; Save .wFlags for later use in InitializeBlockMode
|
|---|
| 148 | and bx, BYTE MASK_DRVPARAMS_WRITECACHE
|
|---|
| 149 | jz SHORT .SkipSetWriteCache ; DEFAULT_WRITE_CACHE
|
|---|
| 150 | mov si, [cs:bx+.rgbWriteCacheCommands]
|
|---|
| 151 | call AH23h_SetControllerFeatures
|
|---|
| 152 | STORE_ERROR_FLAG_TO_DPT FLG_INITERROR_FAILED_TO_SET_WRITE_CACHE
|
|---|
| 153 | .SkipSetWriteCache:
|
|---|
| 154 |
|
|---|
| 155 |
|
|---|
| 156 | ;;; RecalibrateDrive
|
|---|
| 157 | ; Recalibrate drive by seeking to cylinder 0
|
|---|
| 158 | call AH11h_RecalibrateDrive
|
|---|
| 159 | STORE_ERROR_FLAG_TO_DPT FLG_INITERROR_FAILED_TO_RECALIBRATE_DRIVE
|
|---|
| 160 |
|
|---|
| 161 |
|
|---|
| 162 | ;;; InitializeBlockMode
|
|---|
| 163 | ; Initialize block mode transfers
|
|---|
| 164 | pop ax ; Restore .wFlags saved in SetWriteCache
|
|---|
| 165 | test BYTE [di+DPT.bFlagsHigh], FLGH_DPT_BLOCK_MODE_SUPPORTED
|
|---|
| 166 | jz SHORT .BlockModeNotSupportedOrDisabled
|
|---|
| 167 | test al, FLG_DRVPARAMS_BLOCKMODE
|
|---|
| 168 | jz SHORT .BlockModeNotSupportedOrDisabled
|
|---|
| 169 |
|
|---|
| 170 | ; Try block sizes until we find largest possible supported by drive
|
|---|
| 171 | mov bl, 128
|
|---|
| 172 | .TryNextBlockSize:
|
|---|
| 173 | mov al, bl
|
|---|
| 174 | call AH24h_SetBlockSize ; Stores block size to DPT
|
|---|
| 175 | jnc SHORT .SupportedBlockSizeFound
|
|---|
| 176 | shr bl, 1
|
|---|
| 177 | jnc SHORT .TryNextBlockSize
|
|---|
| 178 | STORE_ERROR_FLAG_TO_DPT FLG_INITERROR_FAILED_TO_SET_BLOCK_MODE
|
|---|
| 179 | .BlockModeNotSupportedOrDisabled:
|
|---|
| 180 | .SupportedBlockSizeFound:
|
|---|
| 181 |
|
|---|
| 182 |
|
|---|
| 183 | %ifdef MODULE_ADVANCED_ATA
|
|---|
| 184 | ;;; InitializePioMode
|
|---|
| 185 | ; Initialize fastest supported PIO mode
|
|---|
| 186 | mov dl, PIO_DEFAULT_MODE_DISABLE_IORDY
|
|---|
| 187 | test BYTE [di+DPT.bFlagsHigh], FLGH_DPT_IORDY
|
|---|
| 188 | jz SHORT .IordyNotSupported
|
|---|
| 189 |
|
|---|
| 190 | ; Advanced PIO mode 3 and above
|
|---|
| 191 | mov dl, [di+DPT_ADVANCED_ATA.bPioMode]
|
|---|
| 192 | or dl, PIO_FLOW_CONTROL_MODE_xxx
|
|---|
| 193 |
|
|---|
| 194 | .IordyNotSupported:
|
|---|
| 195 | mov si, FEATURE_SET_TRANSFER_MODE
|
|---|
| 196 | call AH23h_SetControllerFeatures
|
|---|
| 197 | STORE_ERROR_FLAG_TO_DPT FLG_INITERROR_FAILED_TO_SET_PIO_MODE
|
|---|
| 198 | %endif ; MODULE_ADVANCED_ATA
|
|---|
| 199 |
|
|---|
| 200 |
|
|---|
| 201 | %ifdef MODULE_FEATURE_SETS
|
|---|
| 202 | ;;; InitStandbyTimer
|
|---|
| 203 | ; Initialize the standby timer (if supported)
|
|---|
| 204 | test BYTE [di+DPT.bFlagsHigh], FLGH_DPT_POWER_MANAGEMENT_SUPPORTED
|
|---|
| 205 | jz SHORT .NoPowerManagementSupport
|
|---|
| 206 |
|
|---|
| 207 | mov al, COMMAND_IDLE
|
|---|
| 208 | mov dl, [cs:ROMVARS.bIdleTimeout]
|
|---|
| 209 | mov bx, TIMEOUT_AND_STATUS_TO_WAIT(TIMEOUT_BSY, FLG_STATUS_BSY)
|
|---|
| 210 | call Idepack_StoreNonExtParametersAndIssueCommandFromAL
|
|---|
| 211 | STORE_ERROR_FLAG_TO_DPT FLG_INITERROR_FAILED_TO_INITIALIZE_STANDBY_TIMER
|
|---|
| 212 | .NoPowerManagementSupport:
|
|---|
| 213 | %endif ; MODULE_FEATURE_SETS
|
|---|
| 214 |
|
|---|
| 215 |
|
|---|
| 216 | ; There might have been several errors so just return one error code for them all
|
|---|
| 217 | .ReturnWithErrorCodeInAH:
|
|---|
| 218 | %ifdef MODULE_ADVANCED_ATA
|
|---|
| 219 | mov ah, [di+DPT.bInitError]
|
|---|
| 220 | test ah, ah ; Clears CF
|
|---|
| 221 | jz SHORT .ReturnWithSuccess
|
|---|
| 222 | mov ah, RET_HD_RESETFAIL
|
|---|
| 223 | stc
|
|---|
| 224 | .ReturnWithSuccess:
|
|---|
| 225 | %endif
|
|---|
| 226 |
|
|---|
| 227 | pop bx
|
|---|
| 228 | pop dx
|
|---|
| 229 | pop si
|
|---|
| 230 | pop es
|
|---|
| 231 | ret
|
|---|
| 232 |
|
|---|
| 233 |
|
|---|
| 234 | .rgbWriteCacheCommands:
|
|---|
| 235 | db 0 ; DEFAULT_WRITE_CACHE
|
|---|
| 236 | db FEATURE_DISABLE_WRITE_CACHE ; DISABLE_WRITE_CACHE
|
|---|
| 237 | db FEATURE_ENABLE_WRITE_CACHE ; ENABLE_WRITE_CACHE
|
|---|
| 238 |
|
|---|
| 239 |
|
|---|
| 240 |
|
|---|
| 241 | ;--------------------------------------------------------------------
|
|---|
| 242 | ; SetErrorFlagFromALwithErrorCodeInAH
|
|---|
| 243 | ; Parameters:
|
|---|
| 244 | ; AH: BIOS Error Code
|
|---|
| 245 | ; AL: Error flag to set
|
|---|
| 246 | ; DS:DI: Ptr to DPT
|
|---|
| 247 | ; CF: Set if error code in AH
|
|---|
| 248 | ; Clear if AH = 0
|
|---|
| 249 | ; Returns:
|
|---|
| 250 | ; CF: Clear if no error
|
|---|
| 251 | ; Set if error flag was set
|
|---|
| 252 | ; Corrupts registers:
|
|---|
| 253 | ; Nothing
|
|---|
| 254 | ;--------------------------------------------------------------------
|
|---|
| 255 | IgnoreInvalidCommandError:
|
|---|
| 256 | xor ah, ah ; Clears CF
|
|---|
| 257 | SetErrorFlagFromALwithErrorCodeInAH:
|
|---|
| 258 | jnc SHORT .NoErrorFlagToSet
|
|---|
| 259 | cmp ah, RET_HD_INVALID
|
|---|
| 260 | jbe SHORT IgnoreInvalidCommandError
|
|---|
| 261 |
|
|---|
| 262 | or [di+DPT.bInitError], al
|
|---|
| 263 | stc
|
|---|
| 264 | .NoErrorFlagToSet:
|
|---|
| 265 | ret
|
|---|
| 266 |
|
|---|
| 267 |
|
|---|
| 268 | %ifdef MODULE_8BIT_IDE_ADVANCED
|
|---|
| 269 | ;--------------------------------------------------------------------
|
|---|
| 270 | ; AH9h_SetModeFromALtoXTCF
|
|---|
| 271 | ; Parameters:
|
|---|
| 272 | ; AL: XT-CF Mode to set
|
|---|
| 273 | ; DS:DI: Ptr to DPT (in RAMVARS segment)
|
|---|
| 274 | ; SS:BP: Ptr to IDEPACK
|
|---|
| 275 | ; Returns:
|
|---|
| 276 | ; AH: Int 13h return status
|
|---|
| 277 | ; CF: Clear if successful or device is not XT-CF
|
|---|
| 278 | ; Set if failed to set mode for XT-CF
|
|---|
| 279 | ; Corrupts registers:
|
|---|
| 280 | ; AL, BX, CX, DX, SI
|
|---|
| 281 | ;--------------------------------------------------------------------
|
|---|
| 282 | AH9h_SetModeFromALtoXTCF:
|
|---|
| 283 | call AccessDPT_IsThisDeviceXTCF
|
|---|
| 284 | jne SHORT IgnoreInvalidCommandError
|
|---|
| 285 | jmp AH1Eh_ChangeXTCFmodeBasedOnModeInAL
|
|---|
| 286 | %endif ; MODULE_8BIT_IDE_ADVANCED
|
|---|
| 287 |
|
|---|
| 288 | %ifdef MODULE_8BIT_IDE
|
|---|
| 289 | ;--------------------------------------------------------------------
|
|---|
| 290 | ; AH9h_Enable8bitModeForDevice8bitAta
|
|---|
| 291 | ; Parameters:
|
|---|
| 292 | ; DS:DI: Ptr to DPT (in RAMVARS segment)
|
|---|
| 293 | ; SS:BP: Ptr to IDEPACK
|
|---|
| 294 | ; Returns:
|
|---|
| 295 | ; AH: Int 13h return status
|
|---|
| 296 | ; CF: Clear if successful or device is not DEVICE_8BIT_ATA
|
|---|
| 297 | ; Set if failed to set 8-bit mode for DEVICE_8BIT_ATA
|
|---|
| 298 | ; Corrupts registers:
|
|---|
| 299 | ; AL, BX, CX, DX, SI
|
|---|
| 300 | ;--------------------------------------------------------------------
|
|---|
| 301 | AH9h_Enable8bitModeForDevice8bitAta:
|
|---|
| 302 | cmp BYTE [di+DPT_ATA.bDevice], DEVICE_8BIT_ATA
|
|---|
| 303 | jne SHORT IgnoreInvalidCommandError
|
|---|
| 304 | jmp AH23h_Enable8bitPioMode
|
|---|
| 305 | %endif
|
|---|
