| 1 | ; Project name : XTIDE Universal BIOS
|
|---|
| 2 | ; Description : Int 13h function AH=9h, Initialize Drive Parameters.
|
|---|
| 3 |
|
|---|
| 4 | ;
|
|---|
| 5 | ; XTIDE Universal BIOS and Associated Tools
|
|---|
| 6 | ; Copyright (C) 2009-2010 by Tomi Tilli, 2011-2012 by XTIDE Universal BIOS Team.
|
|---|
| 7 | ;
|
|---|
| 8 | ; This program is free software; you can redistribute it and/or modify
|
|---|
| 9 | ; it under the terms of the GNU General Public License as published by
|
|---|
| 10 | ; the Free Software Foundation; either version 2 of the License, or
|
|---|
| 11 | ; (at your option) any later version.
|
|---|
| 12 | ;
|
|---|
| 13 | ; This program is distributed in the hope that it will be useful,
|
|---|
| 14 | ; but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|---|
| 15 | ; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|---|
| 16 | ; GNU General Public License for more details.
|
|---|
| 17 | ; Visit http://www.gnu.org/licenses/old-licenses/gpl-2.0.html
|
|---|
| 18 | ;
|
|---|
| 19 |
|
|---|
| 20 | ; Section containing code
|
|---|
| 21 | SECTION .text
|
|---|
| 22 |
|
|---|
| 23 | ;--------------------------------------------------------------------
|
|---|
| 24 | ; STORE_ERROR_FLAG_TO_DPT
|
|---|
| 25 | ; Parameters:
|
|---|
| 26 | ; %1: Error flag to set
|
|---|
| 27 | ; AH: BIOS Error Code
|
|---|
| 28 | ; DS:DI: Ptr to DPT
|
|---|
| 29 | ; CF: Set if error code in AH
|
|---|
| 30 | ; Returns:
|
|---|
| 31 | ; CF: Clear if no error
|
|---|
| 32 | ; Set if error flag was set
|
|---|
| 33 | ; Corrupts registers:
|
|---|
| 34 | ; Nothing
|
|---|
| 35 | ;--------------------------------------------------------------------
|
|---|
| 36 | %macro STORE_ERROR_FLAG_TO_DPT 1
|
|---|
| 37 | mov al, %1
|
|---|
| 38 | call SetErrorFlagFromALwithErrorCodeInAH
|
|---|
| 39 | %endmacro
|
|---|
| 40 |
|
|---|
| 41 |
|
|---|
| 42 | ;--------------------------------------------------------------------
|
|---|
| 43 | ; Int 13h function AH=9h, Initialize Drive Parameters.
|
|---|
| 44 | ;
|
|---|
| 45 | ; AH9h_HandlerForInitializeDriveParameters
|
|---|
| 46 | ; Parameters:
|
|---|
| 47 | ; DL: Translated Drive number
|
|---|
| 48 | ; DS:DI: Ptr to DPT (in RAMVARS segment)
|
|---|
| 49 | ; SS:BP: Ptr to IDEPACK
|
|---|
| 50 | ; Returns with INTPACK:
|
|---|
| 51 | ; AH: Int 13h return status
|
|---|
| 52 | ; CF: 0 if successful, 1 if error
|
|---|
| 53 | ;--------------------------------------------------------------------
|
|---|
| 54 | AH9h_HandlerForInitializeDriveParameters:
|
|---|
| 55 | %ifndef USE_186
|
|---|
| 56 | call AH9h_InitializeDriveForUse
|
|---|
| 57 | jmp Int13h_ReturnFromHandlerAfterStoringErrorCodeFromAH
|
|---|
| 58 | %else
|
|---|
| 59 | push Int13h_ReturnFromHandlerAfterStoringErrorCodeFromAH
|
|---|
| 60 | ; Fall to AH9h_InitializeDriveForUse
|
|---|
| 61 | %endif
|
|---|
| 62 |
|
|---|
| 63 |
|
|---|
| 64 | ;--------------------------------------------------------------------
|
|---|
| 65 | ; Initialize drive to be ready for use.
|
|---|
| 66 | ;
|
|---|
| 67 | ; AH9h_InitializeDriveForUse
|
|---|
| 68 | ; Parameters:
|
|---|
| 69 | ; DS:DI: Ptr to DPT (in RAMVARS segment)
|
|---|
| 70 | ; SS:BP: Ptr to IDEPACK
|
|---|
| 71 | ; Returns:
|
|---|
| 72 | ; AH: Int 13h return status
|
|---|
| 73 | ; CF: 0 if successful, 1 if error
|
|---|
| 74 | ; Corrupts registers:
|
|---|
| 75 | ; AL, BX, CX, DX
|
|---|
| 76 | ;--------------------------------------------------------------------
|
|---|
| 77 | AH9h_InitializeDriveForUse:
|
|---|
| 78 | xor ax, ax ; Clear AH to assume no errors
|
|---|
| 79 |
|
|---|
| 80 | %ifdef MODULE_ADVANCED_ATA
|
|---|
| 81 | ; Clear Initialization Error flags from DPT
|
|---|
| 82 | mov [di+DPT.bInitError], al
|
|---|
| 83 | %endif
|
|---|
| 84 |
|
|---|
| 85 | %ifdef MODULE_SERIAL
|
|---|
| 86 | ; No need to do this for serial devices
|
|---|
| 87 | test BYTE [di+DPT.bFlagsHigh], FLGH_DPT_SERIAL_DEVICE ; Clears CF
|
|---|
| 88 | jz SHORT .ContinueInitialization
|
|---|
| 89 | ret ; With AH and CF cleared
|
|---|
| 90 | .ContinueInitialization:
|
|---|
| 91 | %endif
|
|---|
| 92 |
|
|---|
| 93 | push es
|
|---|
| 94 | push si
|
|---|
| 95 |
|
|---|
| 96 |
|
|---|
| 97 | ;;; SelectDrive
|
|---|
| 98 | ; Try to select drive and wait until ready
|
|---|
| 99 | call AccessDPT_GetDriveSelectByteForOldInt13hToAL
|
|---|
| 100 | mov [bp+IDEPACK.bDrvAndHead], al
|
|---|
| 101 | call Device_SelectDrive
|
|---|
| 102 | STORE_ERROR_FLAG_TO_DPT FLG_INITERROR_FAILED_TO_SELECT_DRIVE
|
|---|
| 103 | jnc SHORT .ContinueInitializationSinceDriveSelectedSuccesfully
|
|---|
| 104 | jmp .ReturnWithErrorCodeInAH
|
|---|
| 105 | .ContinueInitializationSinceDriveSelectedSuccesfully:
|
|---|
| 106 |
|
|---|
| 107 |
|
|---|
| 108 | ;;; InitializeDeviceParameters
|
|---|
| 109 | ; Initialize CHS parameters if LBA is not used and
|
|---|
| 110 | ; user has specified P-CHS parameters
|
|---|
| 111 | test BYTE [di+DPT.bFlagsLow], FLGL_DPT_ASSISTED_LBA
|
|---|
| 112 | jnz SHORT .SkipInitializeDeviceParameters ; No need to initialize CHS parameters if LBA mode enabled
|
|---|
| 113 | call AccessDPT_GetPointerToDRVPARAMStoCSBX
|
|---|
| 114 | test BYTE [cs:bx+DRVPARAMS.wFlags], FLG_DRVPARAMS_USERCHS ; User specified P-CHS?
|
|---|
| 115 | jz SHORT .SkipInitializeDeviceParameters
|
|---|
| 116 |
|
|---|
| 117 | ; Initialize Logical Sectors per Track and Max Head number
|
|---|
| 118 | mov ax, [cs:bx+DRVPARAMS.wHeadsAndSectors]
|
|---|
| 119 | dec ax ; Max Head number
|
|---|
| 120 | xchg al, ah ; Heads now in AH
|
|---|
| 121 | mov dx, ax ; Sectors per Track now in DL
|
|---|
| 122 | mov al, COMMAND_INITIALIZE_DEVICE_PARAMETERS
|
|---|
| 123 | mov bx, TIMEOUT_AND_STATUS_TO_WAIT(TIMEOUT_BSY, FLG_STATUS_BSY)
|
|---|
| 124 | call Idepack_StoreNonExtParametersAndIssueCommandFromAL
|
|---|
| 125 | STORE_ERROR_FLAG_TO_DPT FLG_INITERROR_FAILED_TO_INITIALIZE_CHS_PARAMETERS
|
|---|
| 126 | .SkipInitializeDeviceParameters:
|
|---|
| 127 |
|
|---|
| 128 |
|
|---|
| 129 | ;;; Enable 8-bit PIO Transfer Mode for Lo-tech XT-CF (CF and Microdrives only)
|
|---|
| 130 | call AH9h_Enable8bitPioModeForXTCF
|
|---|
| 131 | STORE_ERROR_FLAG_TO_DPT FLG_INITERROR_FAILED_TO_ENABLE_8BIT_PIO_MODE
|
|---|
| 132 |
|
|---|
| 133 |
|
|---|
| 134 | ;;; SetWriteCache
|
|---|
| 135 | ; Enable or Disable Write Cache
|
|---|
| 136 | call AccessDPT_GetPointerToDRVPARAMStoCSBX
|
|---|
| 137 | mov bl, [cs:bx+DRVPARAMS.wFlags]
|
|---|
| 138 | push bx ; Save .wFlags for later use in InitializeBlockMode
|
|---|
| 139 | and bx, BYTE MASK_DRVPARAMS_WRITECACHE
|
|---|
| 140 | jz SHORT .SkipSetWriteCache ; DEFAULT_WRITE_CACHE
|
|---|
| 141 | mov si, [cs:bx+.rgbWriteCacheCommands]
|
|---|
| 142 | call AH23h_SetControllerFeatures
|
|---|
| 143 | STORE_ERROR_FLAG_TO_DPT FLG_INITERROR_FAILED_TO_SET_WRITE_CACHE
|
|---|
| 144 | .SkipSetWriteCache:
|
|---|
| 145 |
|
|---|
| 146 |
|
|---|
| 147 | ;;; RecalibrateDrive
|
|---|
| 148 | ; Recalibrate drive by seeking to cylinder 0
|
|---|
| 149 | call AH11h_RecalibrateDrive
|
|---|
| 150 | STORE_ERROR_FLAG_TO_DPT FLG_INITERROR_FAILED_TO_RECALIBRATE_DRIVE
|
|---|
| 151 |
|
|---|
| 152 |
|
|---|
| 153 | ;;; InitializeBlockMode
|
|---|
| 154 | ; Initialize block mode transfers
|
|---|
| 155 | pop ax ; Restore .wFlags saved in SetWriteCache
|
|---|
| 156 | test BYTE [di+DPT.bFlagsHigh], FLGH_DPT_BLOCK_MODE_SUPPORTED
|
|---|
| 157 | jz SHORT .BlockModeNotSupportedOrDisabled
|
|---|
| 158 | test al, FLG_DRVPARAMS_BLOCKMODE
|
|---|
| 159 | jz SHORT .BlockModeNotSupportedOrDisabled
|
|---|
| 160 |
|
|---|
| 161 | ; Try block sizes until we find largest possible supported by drive
|
|---|
| 162 | mov bl, 128
|
|---|
| 163 | .TryNextBlockSize:
|
|---|
| 164 | mov al, bl
|
|---|
| 165 | call AH24h_SetBlockSize ; Stores block size to DPT
|
|---|
| 166 | jnc SHORT .SupportedBlockSizeFound
|
|---|
| 167 | shr bl, 1
|
|---|
| 168 | jnc SHORT .TryNextBlockSize
|
|---|
| 169 | STORE_ERROR_FLAG_TO_DPT FLG_INITERROR_FAILED_TO_SET_BLOCK_MODE
|
|---|
| 170 | .BlockModeNotSupportedOrDisabled:
|
|---|
| 171 | .SupportedBlockSizeFound:
|
|---|
| 172 |
|
|---|
| 173 |
|
|---|
| 174 | %ifdef MODULE_ADVANCED_ATA
|
|---|
| 175 | ;;; InitializePioMode
|
|---|
| 176 | ; Initialize fastest supported PIO mode
|
|---|
| 177 | mov dl, PIO_DEFAULT_MODE_DISABLE_IORDY
|
|---|
| 178 | test BYTE [di+DPT.bFlagsHigh], FLGH_DPT_IORDY
|
|---|
| 179 | jz SHORT .IordyNotSupported
|
|---|
| 180 |
|
|---|
| 181 | ; Advanced PIO mode 3 and above
|
|---|
| 182 | mov dl, [di+DPT_ADVANCED_ATA.bPioMode]
|
|---|
| 183 | or dl, PIO_FLOW_CONTROL_MODE_xxx
|
|---|
| 184 |
|
|---|
| 185 | .IordyNotSupported:
|
|---|
| 186 | mov si, FEATURE_SET_TRANSFER_MODE
|
|---|
| 187 | call AH23h_SetControllerFeatures
|
|---|
| 188 | STORE_ERROR_FLAG_TO_DPT FLG_INITERROR_FAILED_TO_SET_PIO_MODE
|
|---|
| 189 | %endif ; MODULE_ADVANCED_ATA
|
|---|
| 190 |
|
|---|
| 191 |
|
|---|
| 192 | %ifdef MODULE_FEATURE_SETS
|
|---|
| 193 | ;;; InitStandbyTimer
|
|---|
| 194 | ; Initialize the standby timer (if supported)
|
|---|
| 195 | test BYTE [di+DPT.bFlagsHigh], FLGH_DPT_POWER_MANAGEMENT_SUPPORTED
|
|---|
| 196 | jz SHORT .NoPowerManagementSupport
|
|---|
| 197 |
|
|---|
| 198 | mov al, COMMAND_IDLE
|
|---|
| 199 | mov dl, [cs:ROMVARS.bIdleTimeout]
|
|---|
| 200 | mov bx, TIMEOUT_AND_STATUS_TO_WAIT(TIMEOUT_BSY, FLG_STATUS_BSY)
|
|---|
| 201 | call Idepack_StoreNonExtParametersAndIssueCommandFromAL
|
|---|
| 202 | STORE_ERROR_FLAG_TO_DPT FLG_INITERROR_FAILED_TO_INITIALIZE_STANDBY_TIMER
|
|---|
| 203 | .NoPowerManagementSupport:
|
|---|
| 204 | %endif ; MODULE_FEATURE_SETS
|
|---|
| 205 |
|
|---|
| 206 |
|
|---|
| 207 | ; There might have been several errors so just return one error code for them all
|
|---|
| 208 | .ReturnWithErrorCodeInAH:
|
|---|
| 209 | %ifdef MODULE_ADVANCED_ATA
|
|---|
| 210 | mov ah, [di+DPT.bInitError]
|
|---|
| 211 | test ah, ah ; Clears CF
|
|---|
| 212 | jz SHORT .ReturnWithSuccess
|
|---|
| 213 | mov ah, RET_HD_RESETFAIL
|
|---|
| 214 | stc
|
|---|
| 215 | .ReturnWithSuccess:
|
|---|
| 216 | %endif
|
|---|
| 217 |
|
|---|
| 218 | pop si
|
|---|
| 219 | pop es
|
|---|
| 220 | ret
|
|---|
| 221 |
|
|---|
| 222 |
|
|---|
| 223 | .rgbWriteCacheCommands:
|
|---|
| 224 | db 0 ; DEFAULT_WRITE_CACHE
|
|---|
| 225 | db FEATURE_DISABLE_WRITE_CACHE ; DISABLE_WRITE_CACHE
|
|---|
| 226 | db FEATURE_ENABLE_WRITE_CACHE ; ENABLE_WRITE_CACHE
|
|---|
| 227 |
|
|---|
| 228 |
|
|---|
| 229 |
|
|---|
| 230 | ;--------------------------------------------------------------------
|
|---|
| 231 | ; SetErrorFlagFromALwithErrorCodeInAH
|
|---|
| 232 | ; Parameters:
|
|---|
| 233 | ; AH: BIOS Error Code
|
|---|
| 234 | ; AL: Error flag to set
|
|---|
| 235 | ; DS:DI: Ptr to DPT
|
|---|
| 236 | ; CF: Set if error code in AH
|
|---|
| 237 | ; Clear if AH = 0
|
|---|
| 238 | ; Returns:
|
|---|
| 239 | ; CF: Clear if no error
|
|---|
| 240 | ; Set if error flag was set
|
|---|
| 241 | ; Corrupts registers:
|
|---|
| 242 | ; Nothing
|
|---|
| 243 | ;--------------------------------------------------------------------
|
|---|
| 244 | IgnoreInvalidCommandError:
|
|---|
| 245 | xor ah, ah ; Clears CF
|
|---|
| 246 | SetErrorFlagFromALwithErrorCodeInAH:
|
|---|
| 247 | jnc SHORT .NoErrorFlagToSet
|
|---|
| 248 | cmp ah, RET_HD_INVALID
|
|---|
| 249 | jbe SHORT IgnoreInvalidCommandError
|
|---|
| 250 |
|
|---|
| 251 | or [di+DPT.bInitError], al
|
|---|
| 252 | stc
|
|---|
| 253 | .NoErrorFlagToSet:
|
|---|
| 254 | ret
|
|---|
| 255 |
|
|---|
| 256 |
|
|---|
| 257 | ;--------------------------------------------------------------------
|
|---|
| 258 | ; AH9h_Enable8bitPioModeForXTCF
|
|---|
| 259 | ; Parameters:
|
|---|
| 260 | ; DS:DI: Ptr to DPT
|
|---|
| 261 | ; Returns:
|
|---|
| 262 | ; AH: Int 13h return status
|
|---|
| 263 | ; CF: 0 if successful, 1 if error
|
|---|
| 264 | ; Corrupts registers:
|
|---|
| 265 | ; AL, BX, CX, DX
|
|---|
| 266 | ;--------------------------------------------------------------------
|
|---|
| 267 | AH9h_Enable8bitPioModeForXTCF:
|
|---|
| 268 | eMOVZX bx, BYTE [di+DPT.bIdevarsOffset]
|
|---|
| 269 | cmp BYTE [cs:bx+IDEVARS.bDevice], DEVICE_8BIT_XTCF
|
|---|
| 270 | je SHORT .Enable8bitMode
|
|---|
| 271 | xor ah, ah ; Do nothing for this device
|
|---|
| 272 | ret
|
|---|
| 273 | .Enable8bitMode:
|
|---|
| 274 | mov si, FEATURE_ENABLE_8BIT_PIO_TRANSFER_MODE
|
|---|
| 275 | jmp AH23h_SetControllerFeatures
|
|---|
