1 | ; Project name : XTIDE Universal BIOS |
---|
2 | ; Description : Int 13h function AH=24h, Set Multiple Blocks. |
---|
3 | |
---|
4 | ; Section containing code |
---|
5 | SECTION .text |
---|
6 | |
---|
7 | ;-------------------------------------------------------------------- |
---|
8 | ; Int 13h function AH=24h, Set Multiple Blocks. |
---|
9 | ; |
---|
10 | ; AH24h_HandlerForSetMultipleBlocks |
---|
11 | ; Parameters: |
---|
12 | ; AL: Same as in INTPACK |
---|
13 | ; DL: Translated Drive number |
---|
14 | ; DS:DI: Ptr to DPT (in RAMVARS segment) |
---|
15 | ; SS:BP: Ptr to IDEPACK |
---|
16 | ; Parameters on INTPACK: |
---|
17 | ; AL: Number of Sectors per Block (1, 2, 4, 8, 16, 32, 64 or 128) |
---|
18 | ; Returns with INTPACK: |
---|
19 | ; AH: Int 13h return status |
---|
20 | ; CF: 0 if succesfull, 1 if error |
---|
21 | ;-------------------------------------------------------------------- |
---|
22 | ALIGN JUMP_ALIGN |
---|
23 | AH24h_HandlerForSetMultipleBlocks: |
---|
24 | test BYTE [di+DPT.bFlagsHigh], FLGH_DPT_BLOCK_MODE_SUPPORTED |
---|
25 | jnz SHORT .TryToSetBlockMode |
---|
26 | stc |
---|
27 | mov ah, RET_HD_INVALID |
---|
28 | jmp Int13h_ReturnFromHandlerAfterStoringErrorCodeFromAH |
---|
29 | |
---|
30 | ALIGN JUMP_ALIGN |
---|
31 | .TryToSetBlockMode: |
---|
32 | %ifndef USE_186 |
---|
33 | call AH24h_SetBlockSize |
---|
34 | jmp Int13h_ReturnFromHandlerAfterStoringErrorCodeFromAH |
---|
35 | %else |
---|
36 | push Int13h_ReturnFromHandlerAfterStoringErrorCodeFromAH |
---|
37 | ; Fall to AH24h_SetBlockSize |
---|
38 | %endif |
---|
39 | |
---|
40 | |
---|
41 | ;-------------------------------------------------------------------- |
---|
42 | ; AH24h_SetBlockSize |
---|
43 | ; Parameters: |
---|
44 | ; AL: Number of Sectors per Block (1, 2, 4, 8, 16, 32, 64 or 128) |
---|
45 | ; DS:DI: Ptr to DPT (in RAMVARS segment) |
---|
46 | ; SS:BP: Ptr to IDEPACK |
---|
47 | ; Returns: |
---|
48 | ; AH: Int 13h return status |
---|
49 | ; CF: 0 if succesfull, 1 if error |
---|
50 | ; Corrupts registers: |
---|
51 | ; AL, BX, CX, DX |
---|
52 | ;-------------------------------------------------------------------- |
---|
53 | ;ALIGN JUMP_ALIGN |
---|
54 | AH24h_SetBlockSize: |
---|
55 | push ax |
---|
56 | xchg dx, ax ; DL = Block size (Sector Count Register) |
---|
57 | mov al, COMMAND_SET_MULTIPLE_MODE |
---|
58 | mov bx, TIMEOUT_AND_STATUS_TO_WAIT(TIMEOUT_DRDY, FLG_STATUS_DRDY) |
---|
59 | call Idepack_StoreNonExtParametersAndIssueCommandFromAL |
---|
60 | pop bx |
---|
61 | jnc .StoreBlockSize |
---|
62 | mov bl, 1 ; Disable block mode |
---|
63 | .StoreBlockSize: ; Store new block size to DPT and return |
---|
64 | mov [di+DPT_ATA.bSetBlock], bl |
---|
65 | ret |
---|