source: xtideuniversalbios/trunk/XTIDE_Universal_BIOS/Src/Handlers/Int13h/AH1Eh_XTCF.asm @ 525

Last change on this file since 525 was 525, checked in by krille_n_@…, 11 years ago

Changes:

  • Made some improvements to the stack switching in Int13h.asm.
  • Added a tail-call optimized variant of the CALL_MENU_LIBRARY macro (JMP_MENU_LIBRARY).
  • Other optimizations and fixes.
File size: 5.2 KB
Line 
1; Project name  :   XTIDE Universal BIOS
2; Description   :   Int 13h function AH=1Eh, Lo-tech XT-CF features.
3
4;
5; XTIDE Universal BIOS and Associated Tools
6; Copyright (C) 2009-2010 by Tomi Tilli, 2011-2012 by XTIDE Universal BIOS Team.
7;
8; This program is free software; you can redistribute it and/or modify
9; it under the terms of the GNU General Public License as published by
10; the Free Software Foundation; either version 2 of the License, or
11; (at your option) any later version.
12;
13; This program is distributed in the hope that it will be useful,
14; but WITHOUT ANY WARRANTY; without even the implied warranty of
15; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
16; GNU General Public License for more details.
17; Visit http://www.gnu.org/licenses/old-licenses/gpl-2.0.html
18;
19
20; Section containing code
21SECTION .text
22
23;--------------------------------------------------------------------
24; Int 13h function AH=1Eh, Lo-tech XT-CF features.
25; This function is supported only by XTIDE Universal BIOS.
26;
27; AH1Eh_HandlerForXTCFfeatures
28;   Parameters:
29;       AL, CX: Same as in INTPACK
30;       DL:     Translated Drive number
31;       DS:DI:  Ptr to DPT (in RAMVARS segment)
32;       SS:BP:  Ptr to IDEPACK
33;   Parameters on INTPACK:
34;       AL:     XT-CF subcommand (see XTCF.inc for more info)
35;   Returns with INTPACK:
36;       AH:     Int 13h return status
37;       CF:     0 if successful, 1 if error
38;--------------------------------------------------------------------
39AH1Eh_HandlerForXTCFfeatures:
40%ifndef USE_186
41    call    ProcessXTCFsubcommandFromAL
42    jmp     Int13h_ReturnFromHandlerAfterStoringErrorCodeFromAH
43%else
44    push    Int13h_ReturnFromHandlerAfterStoringErrorCodeFromAH
45    ; Fall to ProcessXTCFsubcommandFromAL
46%endif
47
48
49;--------------------------------------------------------------------
50; ProcessXTCFsubcommandFromAL
51;   Parameters:
52;       AL:     XT-CF subcommand (see XTCF.inc for more info)
53;       DS:DI:  Ptr to DPT (in RAMVARS segment)
54;       SS:BP:  Ptr to IDEPACK
55;   Returns:
56;       AH:     Int 13h return status
57;       CF:     0 if successful, 1 if error
58;   Corrupts registers:
59;       AL, BX, CX, DX, SI
60;--------------------------------------------------------------------
61ProcessXTCFsubcommandFromAL:
62    ; IS_THIS_DRIVE_XTCF. We check this for all commands.
63    call    AccessDPT_IsThisDeviceXTCF
64    jne     SHORT XTCFnotFound
65    and     ax, BYTE 7Fh                ; Subcommand now in AX (clears AH and CF)
66    jz      SHORT .ReturnWithSuccess    ; IS_THIS_DRIVE_XTCF
67
68    ; READ_XTCF_CONTROL_REGISTER_TO_DH
69    dec     ax                          ; Subcommand
70    jnz     SHORT .SkipReadXtcfControlRegisterToDH
71    mov     dx, [di+DPT.wBasePort]
72    add     dl, XTCF_CONTROL_REGISTER   ; Will never overflow (keeps CF cleared)
73    in      al, dx
74    mov     [bp+IDEPACK.intpack+INTPACK.dh], al
75.ReturnWithSuccess:
76    ret     ; With AH and CF cleared
77
78.SkipReadXtcfControlRegisterToDH:
79    ; WRITE_DH_TO_XTCF_CONTROL_REGISTER
80    dec     ax                          ; Subcommand
81    jnz     SHORT XTCFnotFound          ; Invalid subcommand
82    mov     al, [bp+IDEPACK.intpack+INTPACK.dh]
83    ; Fall to AH1Eh_ChangeXTCFmodeBasedOnControlRegisterInAL
84
85
86;--------------------------------------------------------------------
87; AH1Eh_ChangeXTCFmodeBasedOnControlRegisterInAL
88;   Parameters:
89;       AL:     XT-CF Control Register
90;       DS:DI:  Ptr to DPT (in RAMVARS segment)
91;       SS:BP:  Ptr to IDEPACK
92;   Returns:
93;       AH:     Int 13h return status
94;       CF:     0 if successful, 1 if error
95;   Corrupts registers:
96;       AL, BX, CX, DX, SI
97;--------------------------------------------------------------------
98AH1Eh_ChangeXTCFmodeBasedOnControlRegisterInAL:
99    ; Output Control Register
100    mov     dx, [di+DPT.wBasePort]
101    add     dl, XTCF_CONTROL_REGISTER
102    out     dx, al
103
104    ; We always need to enable 8-bit mode since 16-bit mode is restored
105    ; when controller is reset (AH=00h or 0Dh)
106    ePUSH_T bx, AH23h_Enable8bitPioMode
107
108    ; Convert Control Register Contents to device code
109    test    al, al
110    jz      SHORT .Set8bitPioMode
111    cmp     al, XTCF_MEMORY_MAPPED_MODE
112    jae     SHORT .SetMemoryMappedMode
113
114    ; Set DMA Mode
115    mov     BYTE [di+DPT_ATA.bDevice], DEVICE_8BIT_XTCF_DMA
116    mov     al, [di+DPT_ATA.bBlockSize]
117    cmp     al, XTCF_DMA_MODE_MAX_BLOCK_SIZE
118    jbe     SHORT AH24h_SetBlockSize
119    mov     al, XTCF_DMA_MODE_MAX_BLOCK_SIZE
120    jmp     SHORT AH24h_SetBlockSize
121
122.SetMemoryMappedMode:
123    mov     al, DEVICE_8BIT_XTCF_MEMMAP
124    SKIP2B  bx
125
126.Set8bitPioMode:
127    mov     al, DEVICE_8BIT_XTCF_PIO8
128    mov     [di+DPT_ATA.bDevice], al
129    ret     ; Via AH23h_Enable8bitPioMode
130
131
132;--------------------------------------------------------------------
133; AH1Eh_DetectXTCFwithBasePortInDX
134;   Parameters:
135;       DX:     Base I/O port address to check
136;   Returns:
137;       AH:     RET_HD_SUCCESS if XT-CF is found from port
138;               RET_HD_INVALID if XT-CF is not found
139;       CF:     Cleared if XT-CF found
140;               Set if XT-CF not found
141;   Corrupts registers:
142;       AL
143;--------------------------------------------------------------------
144AH1Eh_DetectXTCFwithBasePortInDX:
145    push    dx
146    add     dl, XTCF_CONTROL_REGISTER_INVERTED_in   ; set DX to XT-CF config register (inverted)
147    in      al, dx      ; get value
148    mov     ah, al      ; save in ah
149    inc     dx          ; set DX to XT-CF config register (non-inverted)
150    in      al, dx      ; get value
151    not     al          ; invert value
152    pop     dx
153    sub     ah, al      ; do they match? (clear AH if they do)
154    jz      SHORT XTCFfound
155
156XTCFnotFound:
157AH1Eh_LoadInvalidCommandToAHandSetCF:
158    stc                 ; set carry flag since XT-CF not found
159    mov     ah, RET_HD_INVALID
160XTCFfound:
161    ret                 ; and return
Note: See TracBrowser for help on using the repository browser.