1 | ; Project name : XTIDE Universal BIOS
|
---|
2 | ; Description : Int 13h function AH=15h, Read Disk Drive Size.
|
---|
3 |
|
---|
4 | ;
|
---|
5 | ; XTIDE Universal BIOS and Associated Tools
|
---|
6 | ; Copyright (C) 2009-2010 by Tomi Tilli, 2011-2013 by XTIDE Universal BIOS Team.
|
---|
7 | ;
|
---|
8 | ; This program is free software; you can redistribute it and/or modify
|
---|
9 | ; it under the terms of the GNU General Public License as published by
|
---|
10 | ; the Free Software Foundation; either version 2 of the License, or
|
---|
11 | ; (at your option) any later version.
|
---|
12 | ;
|
---|
13 | ; This program is distributed in the hope that it will be useful,
|
---|
14 | ; but WITHOUT ANY WARRANTY; without even the implied warranty of
|
---|
15 | ; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
---|
16 | ; GNU General Public License for more details.
|
---|
17 | ; Visit http://www.gnu.org/licenses/old-licenses/gpl-2.0.html
|
---|
18 | ;
|
---|
19 |
|
---|
20 | ; Section containing code
|
---|
21 | SECTION .text
|
---|
22 |
|
---|
23 | ;--------------------------------------------------------------------
|
---|
24 | ; Int 13h function AH=15h, Read Disk Drive Size.
|
---|
25 | ;
|
---|
26 | ; It is unclear what is the total number of sectors to return.
|
---|
27 | ; Award BIOS from 1997 returns full capacity instead of L-CHS limit
|
---|
28 | ; like we do. I think it makes more sense if this function returns
|
---|
29 | ; L-CHS limit.
|
---|
30 | ;
|
---|
31 | ; AH15h_HandlerForReadDiskDriveSize
|
---|
32 | ; Parameters:
|
---|
33 | ; DL: Translated Drive number
|
---|
34 | ; DS:DI: Ptr to DPT (in RAMVARS segment)
|
---|
35 | ; SS:BP: Ptr to IDEPACK
|
---|
36 | ; Returns with INTPACK:
|
---|
37 | ; If successful:
|
---|
38 | ; AH: Hard Disk: 3 (Hard disk accessible)
|
---|
39 | ; Floppy: 1 (Floppy disk, without change detection)
|
---|
40 | ; CX:DX: Total number of sectors
|
---|
41 | ; CF: 0
|
---|
42 | ; If failed:
|
---|
43 | ; AH: 0 (Drive not present)
|
---|
44 | ; CX:DX: 0
|
---|
45 | ; CF: 1
|
---|
46 | ;--------------------------------------------------------------------
|
---|
47 | AH15h_HandlerForReadDiskDriveSize:
|
---|
48 | %ifdef MODULE_SERIAL_FLOPPY
|
---|
49 | mov cl, 1 ; 1 = floppy disk, no change detection
|
---|
50 |
|
---|
51 | test dl,dl ; DO NOT store the sector count if this is a
|
---|
52 | jns .FloppyDrive ; floppy disk, some OS's depend on this not
|
---|
53 | ; happening for floppies in order to boot.
|
---|
54 | %endif
|
---|
55 |
|
---|
56 | call AH15h_GetSectorCountToBXDXAX
|
---|
57 | mov [bp+IDEPACK.intpack+INTPACK.cx], dx ; HIWORD to CX
|
---|
58 | xchg [bp+IDEPACK.intpack+INTPACK.dx], ax ; LOWORD to DX, AL gets drive number
|
---|
59 |
|
---|
60 | xor ah, ah
|
---|
61 | %ifdef MODULE_SERIAL_FLOPPY
|
---|
62 | mov cl, 3 ; 3 = Hard Disk Accessible
|
---|
63 | .FloppyDrive:
|
---|
64 |
|
---|
65 | call Int13h_SetErrorCodeToBdaAndToIntpackInSSBPfromAH_ALHasDriveNumber ; Store success to BDA and CF
|
---|
66 | mov [bp+IDEPACK.intpack+INTPACK.ah], cl
|
---|
67 | %else
|
---|
68 | call Int13h_SetErrorCodeToBdaAndToIntpackInSSBPfromAH ; Store success to BDA and CF
|
---|
69 | mov BYTE [bp+IDEPACK.intpack+INTPACK.ah], 3
|
---|
70 | %endif
|
---|
71 |
|
---|
72 | jmp Int13h_ReturnFromHandlerWithoutStoringErrorCode
|
---|
73 |
|
---|
74 |
|
---|
75 | ;--------------------------------------------------------------------
|
---|
76 | ; AH15h_GetSectorCountFromForeignDriveToDXAX:
|
---|
77 | ; AH15h_GetSectorCountToBXDXAX:
|
---|
78 | ; Parameters:
|
---|
79 | ; DL: Drive number (AH15h_GetSectorCountFromForeignDriveToDXAX only)
|
---|
80 | ; DS: RAMVARS segment
|
---|
81 | ; DS:DI: Ptr to DPT (AH15h_GetSectorCountToDXAX only)
|
---|
82 | ; Returns:
|
---|
83 | ; DX:AX: Total sector count
|
---|
84 | ; BX: Zero
|
---|
85 | ; Corrupts registers:
|
---|
86 | ; CX
|
---|
87 | ;--------------------------------------------------------------------
|
---|
88 | %ifdef MODULE_BOOT_MENU
|
---|
89 | AH15h_GetSectorCountFromForeignDriveToDXAX:
|
---|
90 | mov ah, GET_DRIVE_PARAMETERS
|
---|
91 | call Int13h_CallPreviousInt13hHandler
|
---|
92 | jmp SHORT ConvertAH08hReturnValuesToSectorCount
|
---|
93 | %endif
|
---|
94 |
|
---|
95 | AH15h_GetSectorCountToBXDXAX:
|
---|
96 | call AH8h_GetDriveParameters
|
---|
97 | ; Fall to ConvertAH08hReturnValuesToSectorCount
|
---|
98 |
|
---|
99 | ConvertAH08hReturnValuesToSectorCount:
|
---|
100 | call Address_ExtractLCHSparametersFromOldInt13hAddress
|
---|
101 | mov al, bh ; AL = Max head number
|
---|
102 | inc cx ; Max cylinder number to cylinder count
|
---|
103 | inc ax ; Max head number to head count (AH=8h returns max 254 so no overflow to AH)
|
---|
104 | mul bl ; AX = Head count * Sectors per track
|
---|
105 | mul cx ; DX:AX = Total sector count for AH=0xh transfer functions
|
---|
106 | xor bx, bx
|
---|
107 | ret
|
---|