source: xtideuniversalbios/trunk/XTIDE_Universal_BIOS/Src/Handlers/Int13h/AH0h_HReset.asm @ 520

Last change on this file since 520 was 520, checked in by aitotat@…, 9 years ago

Changes to XTIDE Universal BIOS:

  • Slave drives are again initialized properly
  • Delay for Hotkeybar now works properly
File size: 7.9 KB
Line 
1; Project name  :   XTIDE Universal BIOS
2; Description   :   Int 13h function AH=0h, Disk Controller Reset.
3
4;
5; XTIDE Universal BIOS and Associated Tools
6; Copyright (C) 2009-2010 by Tomi Tilli, 2011-2012 by XTIDE Universal BIOS Team.
7;
8; This program is free software; you can redistribute it and/or modify
9; it under the terms of the GNU General Public License as published by
10; the Free Software Foundation; either version 2 of the License, or
11; (at your option) any later version.
12;
13; This program is distributed in the hope that it will be useful,
14; but WITHOUT ANY WARRANTY; without even the implied warranty of
15; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
16; GNU General Public License for more details.
17; Visit http://www.gnu.org/licenses/old-licenses/gpl-2.0.html
18;
19
20; Section containing code
21SECTION .text
22
23;--------------------------------------------------------------------
24; Int 13h function AH=0h, Disk Controller Reset.
25;
26; Note: We handle all AH=0h calls, even for drives handled by other
27; BIOSes!
28;
29; AH0h_HandlerForDiskControllerReset
30;   Parameters:
31;       DL:     Translated Drive number (ignored so all drives are reset)
32;               If bit 7 is set all hard disks and floppy disks reset.
33;       DS:DI:  Ptr to DPT (or Null if foreign drive)
34;       SS:BP:  Ptr to IDEPACK
35;   Returns with INTPACK:
36;       AH:     Int 13h return status (from drive requested in DL)
37;       CF:     0 if successful, 1 if error
38;--------------------------------------------------------------------
39AH0h_HandlerForDiskControllerReset:
40    ; Reset foreign Floppy and Hard Drives (those handled by other BIOSes)
41    eMOVZX  bx, dl                                      ; Copy requested drive to BL and zero BH to assume no errors
42
43    xor     ah, ah                                      ; Disk Controller Reset
44    call    Int13h_CallPreviousInt13hHandler            ; Reset floppy drives only or floppy drives and foreign hard disks
45    call    BackupErrorCodeFromTheRequestedDriveToBH
46
47%ifdef MODULE_SERIAL_FLOPPY
48;
49; "Reset" emulated serial floppy drives, if any.  There is nothing to actually do for this reset,
50; but record the proper error return code if one of these floppy drives is the drive requested.
51;
52    call    RamVars_UnpackFlopCntAndFirstToAL
53    cbw                                                 ; Clears AH (there are flop drives) or ffh (there are not)
54                                                        ; Either AH has success code (flop drives are present)
55                                                        ; or it doesn't matter because we won't match drive ffh
56
57    cwd                                                 ; clears DX (there are flop drives) or ffffh (there are not)
58
59    adc     dl, al                                      ; second drive (CF set) if present
60                                                        ; If no drive is present, this will result in ffh which
61                                                        ; won't match a drive
62    call    BackupErrorCodeFromTheRequestedDriveToBH
63    mov     dl, al                                      ; We may end up doing the first drive twice (if there is
64    call    BackupErrorCodeFromTheRequestedDriveToBH    ; only one drive), but doing it again is not harmful.
65%endif
66    test    bl, bl                                      ; If we were called with a floppy disk, then we are done,
67    jns     SHORT .SkipHardDiskReset                    ; don't do hard disks.
68
69    ; Resetting our hard disks will modify dl and bl to be idevars offset based instead of drive number based,
70    ; such that this call must be the last in the list of reset routines called.
71    ;
72    ; This needs to happen after ResetForeignDrives, as that call may have set the error code for 80h,
73    ; and we need to override that value if we are xlate'd into 80h with one of our drives.
74    ;
75    call    ResetHardDisksHandledByOurBIOS
76
77.SkipHardDiskReset:
78    mov     ah, bh
79    jmp     Int13h_ReturnFromHandlerAfterStoringErrorCodeFromAH
80
81
82;--------------------------------------------------------------------
83; BackupErrorCodeFromTheRequestedDriveToBH
84;   Parameters:
85;       AH:     Error code from the last resetted drive
86;       DL:     Drive last resetted
87;       BL:     Requested drive (DL when entering AH=00h)
88;   Returns:
89;       BH:     Backuped error code
90;   Corrupts registers:
91;       Nothing
92;--------------------------------------------------------------------
93BackupErrorCodeFromTheRequestedDriveToBH:
94    cmp     dl, bl              ; Requested drive?
95    eCMOVE  bh, ah
96    ret
97
98
99
100; This defines what is called when resetting our drives at the end of drive detection.
101AH0h_ResetAllOurHardDisksAtTheEndOfDriveInitialization equ ResetHardDisksHandledByOurBIOS.ErrorCodeNotUsed
102
103;--------------------------------------------------------------------
104; ResetHardDisksHandledByOurBIOS
105;   Parameters:
106;       BL:     Requested drive (DL when entering AH=00h)
107;       DS:DI:  Ptr to DPT for requested drive
108;               If DPT pointer is not available, or error result in BH won't be used anyway,
109;               enter through .ErrorCodeNotUsed.
110;       SS:BP:  Ptr to IDEPACK
111;   Returns:
112;       BH:     Error code from requested drive (if available)
113;   Corrupts registers:
114;       AX, BX, CX, DX, SI, DI
115;--------------------------------------------------------------------
116ResetHardDisksHandledByOurBIOS:
117    xor     bl, bl                                      ; Assume Null IdevarsOffset for now, assuming foreign drive
118    test    di, di
119    jz      SHORT .ErrorCodeNotUsed
120    mov     bl, [di+DPT.bIdevarsOffset]                 ; replace drive number with Idevars pointer for cmp with dl
121.ErrorCodeNotUsed:
122
123    mov     si, ControllerResetForDPTinDSDI
124    call    .CallSIforEveryController                   ; Reset all drives to power on settings
125    mov     si, ControllerInitForMasterOrSingleDPTinDSDI
126    ; Fall to .CallSIforEveryController                 ; Initialize all controllers (Master and Slave drives)
127
128.CallSIforEveryController:                              ; BH will be garbage on exit if this entry point is used,
129                                                        ; but reset of all drives will still happen
130
131    mov     dl, ROMVARS.ideVars0                        ; starting Idevars offset
132
133    ; Get count of ALL Idevars structures, not just the ones that are configured.  This may seem odd,
134    ; but it catches the .ideVarsSerialAuto structure, which would not be scanned if the count from
135    ; RamVars_GetIdeControllerCountToCX was used.  Unused controllers won't make a difference, since no DPT
136    ; will point to them.  Performance isn't an issue, as this is a reset operation.
137    ;
138    mov     cx, NUMBER_OF_IDEVARS
139
140.loop:
141    push    si
142    call    FindDPT_ForIdevarsOffsetInDL                ; look for the first drive on this controller, if any
143    pop     si
144    jc      SHORT .notFound
145
146    push    bx
147    push    cx
148    push    dx
149    call    si                                          ; Reset Master AND Slave or initialize Master OR Slave drive
150    pop     dx
151    pop     cx
152    pop     bx
153    call    BackupErrorCodeFromTheRequestedDriveToBH    ; save error code if same controller as drive from entry
154
155.notFound:
156    add     dl, IDEVARS_size                            ; move Idevars pointer forward
157    loop    .loop
158    ret
159
160
161;--------------------------------------------------------------------
162; ControllerResetForDPTinDSDI
163;   Parameters:
164;       DS:DI:  Ptr to DPT for drive to reset (resets both Master and Slave drive)
165;       SS:BP:  Ptr to IDEPACK
166;   Returns:
167;       AH:     Int 13h return status
168;   Corrupts registers:
169;       AL, BX, CX, DX
170;--------------------------------------------------------------------
171ControllerResetForDPTinDSDI:
172%ifdef MODULE_IRQ
173    call    Interrupts_UnmaskInterruptControllerForDriveInDSDI
174%endif
175%ifdef MODULE_ADVANCED_ATA
176    call    Device_ResetMasterAndSlaveController
177    jmp     AdvAtaInit_InitializeControllerForDPTinDSDI
178%else
179    jmp     Device_ResetMasterAndSlaveController
180%endif
181
182
183;--------------------------------------------------------------------
184; ControllerInitForMasterOrSingleDPTinDSDI
185;   Parameters:
186;       DS:DI:  Ptr to DPT for Master or Single Drive (initializes both Master and Slave drive)
187;       SS:BP:  Ptr to IDEPACK
188;   Returns:
189;       AH:     Int 13h return status
190;   Corrupts registers:
191;       AL, BX, CX, DX
192;--------------------------------------------------------------------
193ControllerInitForMasterOrSingleDPTinDSDI:
194    call    AH9h_InitializeDriveForUse          ; Init Master or Single drive
195    push    ax                                  ; Store error code
196
197    eMOVZX  ax, BYTE [di+DPT.bIdevarsOffset]    ; Clear AH
198    add     di, BYTE LARGEST_DPT_SIZE           ; Slave drive or next controller
199    cmp     [di+DPT.bIdevarsOffset], al
200    jne     SHORT .NoSlaveDrivePresent
201
202    call    AH9h_InitializeDriveForUse          ; Init Slave drive
203.NoSlaveDrivePresent:
204    pop     bx
205    MAX_U   ah, bh                              ; Return error code from either drive
206    ret
Note: See TracBrowser for help on using the repository browser.