source: xtideuniversalbios/trunk/XTIDE_Universal_BIOS/Src/Handlers/Int13h/AH0h_HReset.asm @ 501

Last change on this file since 501 was 501, checked in by aitotat@…, 9 years ago

Changes to XTIDE Universal BIOS:

  • XTIDE rev 2 and modded XTIDE rev 1 work again (fixed A0<->A3 swap when accessing Control Block Registers).
  • System INT 13h handler is no longer copied to INT 40h (testing if something uses INT 40h).
  • Removed controller hardware reset: now AH=0h and AH=Dh will only re-initialize drives (SB16 Tertiary and Quaternary IDE should now be safe to use when using Secondary IDE).
File size: 6.8 KB
Line 
1; Project name  :   XTIDE Universal BIOS
2; Description   :   Int 13h function AH=0h, Disk Controller Reset.
3
4;
5; XTIDE Universal BIOS and Associated Tools
6; Copyright (C) 2009-2010 by Tomi Tilli, 2011-2012 by XTIDE Universal BIOS Team.
7;
8; This program is free software; you can redistribute it and/or modify
9; it under the terms of the GNU General Public License as published by
10; the Free Software Foundation; either version 2 of the License, or
11; (at your option) any later version.
12;
13; This program is distributed in the hope that it will be useful,
14; but WITHOUT ANY WARRANTY; without even the implied warranty of
15; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
16; GNU General Public License for more details.
17; Visit http://www.gnu.org/licenses/old-licenses/gpl-2.0.html
18;
19
20; Section containing code
21SECTION .text
22
23;--------------------------------------------------------------------
24; Int 13h function AH=0h, Disk Controller Reset.
25;
26; Note: We handle all AH=0h calls, even for drives handled by other
27; BIOSes!
28;
29; AH0h_HandlerForDiskControllerReset
30;   Parameters:
31;       DL:     Translated Drive number (ignored so all drives are reset)
32;               If bit 7 is set all hard disks and floppy disks reset.
33;       DS:DI:  Ptr to DPT (or Null if foreign drive)
34;       SS:BP:  Ptr to IDEPACK
35;   Returns with INTPACK:
36;       AH:     Int 13h return status (from drive requested in DL)
37;       CF:     0 if successful, 1 if error
38;--------------------------------------------------------------------
39AH0h_HandlerForDiskControllerReset:
40    xor     bx, bx                      ; Zero BH to assume no errors
41    or      bl, dl                      ; Copy requested drive to BL
42
43%ifdef MODULE_SERIAL_FLOPPY
44;
45; "Reset" emulated serial floppy drives, if any.  There is nothing to actually do for this reset,
46; but record the proper error return code if one of these floppy drives is the drive requested.
47;
48    call    RamVars_UnpackFlopCntAndFirstToAL
49    cbw                                                 ; Clears AH (there are flop drives) or ffh (there are not)
50                                                        ; Either AH has success code (flop drives are present)
51                                                        ; or it doesn't matter because we won't match drive ffh
52
53    cwd                                                 ; clears DX (there are flop drives) or ffffh (there are not)
54
55    adc     dl, al                                      ; second drive (CF set) if present
56                                                        ; If no drive is present, this will result in ffh which
57                                                        ; won't match a drive
58    call    BackupErrorCodeFromTheRequestedDriveToBH
59    mov     dl, al                                      ; We may end up doing the first drive twice (if there is
60    call    BackupErrorCodeFromTheRequestedDriveToBH    ; only one drive), but doing it again is not harmful.
61%endif
62
63    ; Reset foreign Floppy and Hard Drives (those handled by other BIOSes)
64    call    ResetForeignDrives
65    test    bl, bl                                      ; If we were called with a floppy disk, then we are done,
66    jns     SHORT .SkipHardDiskReset                    ; don't do hard disks.
67
68    ; Resetting our hard disks will modify dl and bl to be idevars offset based instead of drive number based,
69    ; such that this call must be the last in the list of reset routines called.
70    ;
71    ; This needs to happen after ResetForeignDrives, as that call may have set the error code for 80h,
72    ; and we need to override that value if we are xlate'd into 80h with one of our drives.
73    ;
74    call    ResetHardDisksHandledByOurBIOS
75
76.SkipHardDiskReset:
77    mov     ah, bh
78    jmp     Int13h_ReturnFromHandlerAfterStoringErrorCodeFromAH
79
80
81;--------------------------------------------------------------------
82; ResetForeignDrives
83;   Parameters:
84;       BL:     Requested Floppy or Hard Drive (DL when entering AH=00h)
85;       DS:     RAMVARS segment
86;   Returns:
87;       BH:     Error code from requested drive (if available)
88;   Corrupts registers:
89;       AX, DL
90;--------------------------------------------------------------------
91ResetForeignDrives:
92    ; If there are drives after our drives, those are already reset
93    ; since our INT 13h was called by some other BIOS.
94    ; We only need to reset drives from the previous INT 13h handler.
95    ; There could be more in chain but let the previous one handle them.
96    mov     dl, [RAMVARS.bFirstDrv]
97    or      dl, 80h                 ; We may not have our drives at all so change 0 to 80h!
98    MIN_U   dl, bl
99
100    xor     ah, ah                  ; Disk Controller Reset
101    call    Int13h_CallPreviousInt13hHandler
102;;; fall-through to BackupErrorCodeFromTheRequestedDriveToBH
103
104
105;--------------------------------------------------------------------
106; BackupErrorCodeFromTheRequestedDriveToBH
107;   Parameters:
108;       AH:     Error code from the last resetted drive
109;       DL:     Drive last resetted
110;       BL:     Requested drive (DL when entering AH=00h)
111;   Returns:
112;       BH:     Backuped error code
113;   Corrupts registers:
114;       Nothing
115;--------------------------------------------------------------------
116BackupErrorCodeFromTheRequestedDriveToBH:
117    cmp     dl, bl              ; Requested drive?
118    eCMOVE  bh, ah
119    ret
120
121
122
123; This defines what is called when resetting our drives at the end of drive detection.
124AH0h_ResetAllOurHardDisksAtTheEndOfDriveInitialization equ ResetHardDisksHandledByOurBIOS.ErrorCodeNotUsed
125
126;--------------------------------------------------------------------
127; ResetHardDisksHandledByOurBIOS
128;   Parameters:
129;       BL:     Requested drive (DL when entering AH=00h)
130;       DS:DI:  Ptr to DPT for requested drive
131;               If DPT pointer is not available, or error result in BH won't be used anyway,
132;               enter through .ErrorCodeNotUsed.
133;       SS:BP:  Ptr to IDEPACK
134;   Returns:
135;       BH:     Error code from requested drive (if available)
136;   Corrupts registers:
137;       AX, BX, CX, DX, SI, DI
138;--------------------------------------------------------------------
139ResetHardDisksHandledByOurBIOS:
140    xor     bl, bl                                      ; Assume Null IdevarsOffset for now, assuming foreign drive
141    test    di, di
142    jz      SHORT .ErrorCodeNotUsed
143    mov     bl, [di+DPT.bIdevarsOffset]                 ; replace drive number with Idevars pointer for cmp with dl
144
145.ErrorCodeNotUsed:                                      ; BH will be garbage on exit if this entry point is used,
146                                                        ; but reset of all drives will still happen
147
148    mov     dl, ROMVARS.ideVars0                        ; starting Idevars offset
149
150    ; Get count of ALL Idevars structures, not just the ones that are configured.  This may seem odd,
151    ; but it catches the .ideVarsSerialAuto structure, which would not be scanned if the count from
152    ; RamVars_GetIdeControllerCountToCX was used.  Unused controllers won't make a difference, since no DPT
153    ; will point to them.  Performance isn't an issue, as this is a reset operation.
154    ;
155    mov     cx, (ROMVARS.ideVarsEnd - ROMVARS.ideVarsBegin) / IDEVARS_size
156
157.loop:
158    call    FindDPT_ForIdevarsOffsetInDL                ; look for the first drive on this controller, if any
159    jc      SHORT .notFound
160
161    call    AHDh_ResetDrive                             ; reset master and slave on that controller
162    call    BackupErrorCodeFromTheRequestedDriveToBH    ; save error code if same controller as drive from entry
163
164.notFound:
165    add     dl, IDEVARS_size                            ; move Idevars pointer forward
166    loop    .loop
167
168.done:
169    ret
Note: See TracBrowser for help on using the repository browser.