1 | ; Project name : XTIDE Universal BIOS |
---|
2 | ; Description : Int 13h function AH=0h, Disk Controller Reset. |
---|
3 | |
---|
4 | ; |
---|
5 | ; XTIDE Universal BIOS and Associated Tools |
---|
6 | ; Copyright (C) 2009-2010 by Tomi Tilli, 2011-2012 by XTIDE Universal BIOS Team. |
---|
7 | ; |
---|
8 | ; This program is free software; you can redistribute it and/or modify |
---|
9 | ; it under the terms of the GNU General Public License as published by |
---|
10 | ; the Free Software Foundation; either version 2 of the License, or |
---|
11 | ; (at your option) any later version. |
---|
12 | ; |
---|
13 | ; This program is distributed in the hope that it will be useful, |
---|
14 | ; but WITHOUT ANY WARRANTY; without even the implied warranty of |
---|
15 | ; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
---|
16 | ; GNU General Public License for more details. |
---|
17 | ; Visit http://www.gnu.org/licenses/old-licenses/gpl-2.0.html |
---|
18 | ; |
---|
19 | |
---|
20 | ; Section containing code |
---|
21 | SECTION .text |
---|
22 | |
---|
23 | ;-------------------------------------------------------------------- |
---|
24 | ; Int 13h function AH=0h, Disk Controller Reset. |
---|
25 | ; |
---|
26 | ; Note: We handle all AH=0h calls, even for drives handled by other |
---|
27 | ; BIOSes! |
---|
28 | ; |
---|
29 | ; AH0h_HandlerForDiskControllerReset |
---|
30 | ; Parameters: |
---|
31 | ; DL: Translated Drive number (ignored so all drives are reset) |
---|
32 | ; If bit 7 is set all hard disks and floppy disks reset. |
---|
33 | ; DS:DI: Ptr to DPT (or Null if foreign drive) |
---|
34 | ; SS:BP: Ptr to IDEPACK |
---|
35 | ; Returns with INTPACK: |
---|
36 | ; AH: Int 13h return status (from drive requested in DL) |
---|
37 | ; CF: 0 if successful, 1 if error |
---|
38 | ;-------------------------------------------------------------------- |
---|
39 | AH0h_HandlerForDiskControllerReset: |
---|
40 | ; Reset Floppy Drives with INT 40h |
---|
41 | xor bx, bx ; Zero BH to assume no errors |
---|
42 | or bl, dl ; Copy requested drive to BL |
---|
43 | eCMOVS dl, bh ; Reset Floppy Drive(s) with 00h since DL has Hard Drive number |
---|
44 | |
---|
45 | xor ah, ah ; Disk Controller Reset |
---|
46 | int BIOS_DISKETTE_INTERRUPT_40h |
---|
47 | call BackupErrorCodeFromTheRequestedDriveToBH |
---|
48 | ; We do not reset Hard Drives if DL was 0xh on entry |
---|
49 | |
---|
50 | |
---|
51 | %ifdef MODULE_SERIAL_FLOPPY |
---|
52 | ; |
---|
53 | ; "Reset" emulated serial floppy drives, if any. There is nothing to actually do for this reset, |
---|
54 | ; but record the proper error return code if one of these floppy drives is the drive requested. |
---|
55 | ; |
---|
56 | call RamVars_UnpackFlopCntAndFirstToAL |
---|
57 | cbw ; Clears AH (there are flop drives) or ffh (there are not) |
---|
58 | ; Either AH has success code (flop drives are present) |
---|
59 | ; or it doesn't matter because we won't match drive ffh |
---|
60 | |
---|
61 | cwd ; clears DX (there are flop drives) or ffffh (there are not) |
---|
62 | |
---|
63 | adc dl, al ; second drive (CF set) if present |
---|
64 | ; If no drive is present, this will result in ffh which |
---|
65 | ; won't match a drive |
---|
66 | call BackupErrorCodeFromTheRequestedDriveToBH |
---|
67 | mov dl, al ; We may end up doing the first drive twice (if there is |
---|
68 | call BackupErrorCodeFromTheRequestedDriveToBH ; only one drive), but doing it again is not harmful. |
---|
69 | %endif |
---|
70 | |
---|
71 | ; Reset foreign Hard Drives (those handled by other BIOSes) |
---|
72 | test bl, bl ; If we were called with a floppy disk, then we are done, |
---|
73 | jns SHORT .SkipHardDiskReset ; don't do hard disks. |
---|
74 | call ResetForeignHardDisks |
---|
75 | |
---|
76 | ; Resetting our hard disks will modify dl and bl to be idevars offset based instead of drive number based, |
---|
77 | ; such that this call must be the last in the list of reset routines called. |
---|
78 | ; |
---|
79 | ; This needs to happen after ResetForeignHardDisks, as that call may have set the error code for 80h, |
---|
80 | ; and we need to override that value if we are xlate'd into 80h with one of our drives. |
---|
81 | ; |
---|
82 | call ResetHardDisksHandledByOurBIOS |
---|
83 | |
---|
84 | .SkipHardDiskReset: |
---|
85 | mov ah, bh |
---|
86 | jmp Int13h_ReturnFromHandlerAfterStoringErrorCodeFromAH |
---|
87 | |
---|
88 | |
---|
89 | ;-------------------------------------------------------------------- |
---|
90 | ; ResetForeignHardDisks |
---|
91 | ; Parameters: |
---|
92 | ; BL: Requested Hard Drive (DL when entering AH=00h) |
---|
93 | ; DS: RAMVARS segment |
---|
94 | ; Returns: |
---|
95 | ; BH: Error code from requested drive (if available) |
---|
96 | ; Corrupts registers: |
---|
97 | ; AX, DL |
---|
98 | ;-------------------------------------------------------------------- |
---|
99 | ResetForeignHardDisks: |
---|
100 | ; If there are drives after our drives, those are already reset |
---|
101 | ; since our INT 13h was called by some other BIOS. |
---|
102 | ; We only need to reset drives from the previous INT 13h handler. |
---|
103 | ; There could be more in chain but let the previous one handle them. |
---|
104 | mov dl, [RAMVARS.bFirstDrv] |
---|
105 | or dl, 80h ; We may not have our drives at all! |
---|
106 | MIN_U dl, bl ; BL is always Hard Drive number |
---|
107 | |
---|
108 | xor ah, ah ; Disk Controller Reset |
---|
109 | call Int13h_CallPreviousInt13hHandler |
---|
110 | ;;; fall-through to BackupErrorCodeFromTheRequestedDriveToBH |
---|
111 | |
---|
112 | |
---|
113 | ;-------------------------------------------------------------------- |
---|
114 | ; BackupErrorCodeFromTheRequestedDriveToBH |
---|
115 | ; Parameters: |
---|
116 | ; AH: Error code from the last resetted drive |
---|
117 | ; DL: Drive last resetted |
---|
118 | ; BL: Requested drive (DL when entering AH=00h) |
---|
119 | ; Returns: |
---|
120 | ; BH: Backuped error code |
---|
121 | ; Corrupts registers: |
---|
122 | ; Nothing |
---|
123 | ;-------------------------------------------------------------------- |
---|
124 | BackupErrorCodeFromTheRequestedDriveToBH: |
---|
125 | cmp dl, bl ; Requested drive? |
---|
126 | eCMOVE bh, ah |
---|
127 | ret |
---|
128 | |
---|
129 | |
---|
130 | |
---|
131 | ; This defines what is called when resetting our drives at the end of drive detection. |
---|
132 | AH0h_ResetAllOurHardDisksAtTheEndOfDriveInitialization equ ResetHardDisksHandledByOurBIOS.ErrorCodeNotUsed |
---|
133 | |
---|
134 | ;-------------------------------------------------------------------- |
---|
135 | ; ResetHardDisksHandledByOurBIOS |
---|
136 | ; Parameters: |
---|
137 | ; DS:DI: Ptr to DPT for requested drive |
---|
138 | ; If DPT pointer is not available, or error result in BH won't be used anyway, |
---|
139 | ; enter through .ErrorCodeNotUsed. |
---|
140 | ; SS:BP: Ptr to IDEPACK |
---|
141 | ; Returns: |
---|
142 | ; BH: Error code from requested drive (if available) |
---|
143 | ; Corrupts registers: |
---|
144 | ; AX, BX, CX, DX, SI, DI |
---|
145 | ;-------------------------------------------------------------------- |
---|
146 | ResetHardDisksHandledByOurBIOS: |
---|
147 | xor bl, bl ; Assume Null IdevarsOffset for now, assuming foreign drive |
---|
148 | test di, di |
---|
149 | jz SHORT .ErrorCodeNotUsed |
---|
150 | mov bl, [di+DPT.bIdevarsOffset] ; replace drive number with Idevars pointer for cmp with dl |
---|
151 | |
---|
152 | .ErrorCodeNotUsed: ; BH will be garbage on exit if this entry point is used, |
---|
153 | ; but reset of all drives will still happen |
---|
154 | |
---|
155 | mov dl, ROMVARS.ideVars0 ; starting Idevars offset |
---|
156 | |
---|
157 | ; Get count of ALL Idevars structures, not just the ones that are configured. This may seem odd, |
---|
158 | ; but it catches the .ideVarsSerialAuto structure, which would not be scanned if the count from |
---|
159 | ; RamVars_GetIdeControllerCountToCX was used. Unused controllers won't make a difference, since no DPT |
---|
160 | ; will point to them. Performance isn't an issue, as this is a reset operation. |
---|
161 | ; |
---|
162 | mov cx, (ROMVARS.ideVarsEnd - ROMVARS.ideVarsBegin) / IDEVARS_size |
---|
163 | |
---|
164 | .loop: |
---|
165 | call FindDPT_ForIdevarsOffsetInDL ; look for the first drive on this controller, if any |
---|
166 | jc SHORT .notFound |
---|
167 | |
---|
168 | call AHDh_ResetDrive ; reset master and slave on that controller |
---|
169 | call BackupErrorCodeFromTheRequestedDriveToBH ; save error code if same controller as drive from entry |
---|
170 | |
---|
171 | .notFound: |
---|
172 | add dl, IDEVARS_size ; move Idevars pointer forward |
---|
173 | loop .loop |
---|
174 | |
---|
175 | .done: |
---|
176 | NoForeignDrivesToReset: |
---|
177 | ret |
---|