source: xtideuniversalbios/trunk/XTIDE_Universal_BIOS/Src/Handlers/Int13h.asm @ 540

Last change on this file since 540 was 540, checked in by aitotat@…, 11 years ago

Changes to XTIDE Universal BIOS:

  • Improved interrupt handling: INT 15h AH=91h is no longer called if AH=90h was not called.
File size: 15.9 KB
Line 
1; Project name  :   XTIDE Universal BIOS
2; Description   :   Int 13h BIOS functions (Floppy and Hard disk).
3
4;
5; XTIDE Universal BIOS and Associated Tools
6; Copyright (C) 2009-2010 by Tomi Tilli, 2011-2013 by XTIDE Universal BIOS Team.
7;
8; This program is free software; you can redistribute it and/or modify
9; it under the terms of the GNU General Public License as published by
10; the Free Software Foundation; either version 2 of the License, or
11; (at your option) any later version.
12;
13; This program is distributed in the hope that it will be useful,
14; but WITHOUT ANY WARRANTY; without even the implied warranty of
15; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
16; GNU General Public License for more details.
17; Visit http://www.gnu.org/licenses/old-licenses/gpl-2.0.html
18;
19
20; Section containing code
21SECTION .text
22
23;--------------------------------------------------------------------
24; Int 13h software interrupt handler.
25; This handler changes stack to top of stolen conventional memory
26; and then calls the actual INT 13h handler (Int13h_DiskFunctionsHandler).
27;
28; Int13h_DiskFunctionsHandlerWithStackChange
29;   Parameters:
30;       AH:     Bios function
31;       DL:     Drive number
32;       Other:  Depends on function
33;   Returns:
34;       Depends on function
35;--------------------------------------------------------------------
36%ifdef RELOCATE_INT13H_STACK
37ALIGN JUMP_ALIGN
38Int13h_DiskFunctionsHandlerWithStackChange:
39    sti         ; Enable interrupts
40    ; TODO: Maybe we need to save Flags (DF) as well?
41    push    ds  ; Save DS:DI on the original stack
42    push    di
43    call    RamVars_GetSegmentToDS
44
45    ; Store entry registers to RAMVARS
46%ifdef USE_386
47    pop     DWORD [RAMVARS.dwStackChangeDSDI]
48%else
49    pop     WORD [RAMVARS.wStackChangeDI]   ; Pop DS:DI to the top of what
50    pop     WORD [RAMVARS.wStackChangeDS]   ; is to become the new stack
51%endif
52    mov     [RAMVARS.fpInt13hEntryStack], sp
53    mov     [RAMVARS.fpInt13hEntryStack+2], ss
54
55    ; Load new stack and restore DS and DI
56    mov     di, ds      ; We can save 2 bytes by using PUSH/POP but it's slower
57    mov     ss, di      ; No need to wrap with CLI/STI since this is for AT only (286+)
58    mov     sp, RAMVARS.rgbTopOfStack-4
59    pop     di          ; DI before stack change
60    pop     ds          ; DS before stack change
61
62    ; Call INT 13h
63    pushf
64    push    cs
65    call    Int13h_DiskFunctionsHandler
66
67    ; Restore stack (we must not corrupt FLAGS!)
68%ifdef USE_386
69    lss     sp, [ss:RAMVARS.fpInt13hEntryStack]
70%else
71    cli
72    mov     sp, [ss:RAMVARS.fpInt13hEntryStack]
73    mov     ss, [ss:RAMVARS.fpInt13hEntryStack+2]
74    sti
75%endif
76    retf    2           ; Skip FLAGS from stack
77%endif ; RELOCATE_INT13H_STACK
78
79
80;--------------------------------------------------------------------
81; Int 13h software interrupt handler.
82; Jumps to specific function defined in AH.
83;
84; Note to developers: Do not make recursive INT 13h calls!
85;
86; Int13h_DiskFunctionsHandler
87;   Parameters:
88;       AH:     Bios function
89;       DL:     Drive number
90;       Other:  Depends on function
91;   Returns:
92;       Depends on function
93;--------------------------------------------------------------------
94ALIGN JUMP_ALIGN
95Int13h_DiskFunctionsHandler:
96%ifndef RELOCATE_INT13H_STACK
97    sti                                 ; Enable interrupts
98%endif
99    cld                                 ; String instructions to increment pointers
100    CREATE_FRAME_INTPACK_TO_SSBP    SIZE_OF_IDEPACK_WITHOUT_INTPACK
101    call    RamVars_GetSegmentToDS
102
103%ifdef MODULE_DRIVEXLATE
104    call    DriveXlate_ToOrBack
105    mov     [RAMVARS.xlateVars+XLATEVARS.bXlatedDrv], dl
106%endif
107    call    FindDPT_ForDriveNumberInDL  ; DS:DI points to our DPT, or NULL if not our drive
108    jc      SHORT .NotOurDrive          ; DPT not found so this is not one of our drives
109
110.OurFunction:
111    ; Jump to correct BIOS function
112    eMOVZX  bx, ah
113    eSHL_IM bx, 1
114    cmp     ah, 25h                     ; Possible EBIOS function?
115%ifndef MODULE_EBIOS
116    ja      SHORT UnsupportedFunction
117    jmp     [cs:bx+g_rgw13hFuncJump]    ; Jump to BIOS function
118
119%else ; If using MODULE_EBIOS
120    ja      SHORT .JumpToEbiosFunction
121    jmp     [cs:bx+g_rgw13hFuncJump]    ; Jump to BIOS function
122
123ALIGN JUMP_ALIGN
124.JumpToEbiosFunction:
125    test    BYTE [di+DPT.bFlagsLow], FLGL_DPT_LBA_AND_EBIOS_SUPPORTED
126    jz      SHORT UnsupportedFunction   ; No eINT 13h for CHS drives
127    sub     bl, 41h<<1                  ; BX = Offset to eINT 13h jump table
128    jb      SHORT UnsupportedFunction
129    cmp     ah, 48h
130    ja      SHORT UnsupportedFunction
131    jmp     [cs:bx+g_rgwEbiosFunctionJumpTable]
132%endif  ; MODULE_EBIOS
133
134
135ALIGN JUMP_ALIGN
136.NotOurDrive:
137    test    ah, ah
138    jz      SHORT .OurFunction          ; We handle all function 0h requests (resets)
139
140%ifndef MODULE_SERIAL_FLOPPY
141; Without floppy support, we handle only hard disk traffic for function 08h.
142    test    dl, dl
143    jns     SHORT Int13h_DirectCallToAnotherBios
144%endif
145; With floppy support, we handle all traffic for function 08h, as we need to wrap both hard disk and floppy drive counts.
146    cmp     ah, 8
147    je      SHORT .OurFunction
148    ; Fall to Int13h_DirectCallToAnotherBios
149
150
151;--------------------------------------------------------------------
152; UnsupportedFunction
153; Int13h_DirectCallToAnotherBios
154;   Parameters:
155;       DL:     Translated drive number
156;       DS:     RAMVARS segment
157;       SS:BP:  Ptr to IDEPACK
158;       BX, DI: Corrupted on Int13h_DiskFunctionsHandler
159;       Other:  Function specific INT 13h parameters
160;   Returns:
161;       Depends on function
162;   Corrupts registers:
163;       Flags
164;--------------------------------------------------------------------
165ALIGN JUMP_ALIGN
166UnsupportedFunction:
167Int13h_DirectCallToAnotherBios:
168    call    ExchangeCurrentInt13hHandlerWithOldInt13hHandler
169    mov     bx, [bp+IDEPACK.intpack+INTPACK.bx]
170    mov     di, [bp+IDEPACK.intpack+INTPACK.di]
171    mov     ds, [bp+IDEPACK.intpack+INTPACK.ds]
172    push    WORD [bp+IDEPACK.intpack+INTPACK.flags]
173    popf
174    push    bp
175    mov     bp, [bp+IDEPACK.intpack+INTPACK.bp]
176    int     BIOS_DISK_INTERRUPT_13h ; Can safely do as much recursion as it wants
177
178    ; Store returned values to INTPACK
179    pop     bp  ; Standard INT 13h functions never uses BP as return register
180%ifdef USE_386
181;   mov     [bp+IDEPACK.intpack+INTPACK.gs], gs
182;   mov     [bp+IDEPACK.intpack+INTPACK.fs], fs
183%endif
184    mov     [bp+IDEPACK.intpack+INTPACK.es], es
185    mov     [bp+IDEPACK.intpack+INTPACK.ds], ds
186    mov     [bp+IDEPACK.intpack+INTPACK.di], di
187    mov     [bp+IDEPACK.intpack+INTPACK.si], si
188    mov     [bp+IDEPACK.intpack+INTPACK.bx], bx
189%ifdef MODULE_DRIVEXLATE
190    mov     [bp+IDEPACK.intpack+INTPACK.dh], dh
191%else
192    mov     [bp+IDEPACK.intpack+INTPACK.dx], dx
193%endif
194    mov     [bp+IDEPACK.intpack+INTPACK.cx], cx
195    mov     [bp+IDEPACK.intpack+INTPACK.ax], ax
196    pushf
197    pop     WORD [bp+IDEPACK.intpack+INTPACK.flags]
198    call    RamVars_GetSegmentToDS
199
200%ifdef MODULE_DRIVEXLATE
201    cmp     dl, [RAMVARS.xlateVars+XLATEVARS.bXlatedDrv]    ; DL is still drive number?
202    je      SHORT .ExchangeInt13hHandlers
203    mov     [bp+IDEPACK.intpack+INTPACK.dl], dl ; Something is returned in DL
204ALIGN JUMP_ALIGN
205.ExchangeInt13hHandlers:
206%endif
207
208%ifdef USE_186
209    push    Int13h_ReturnFromHandlerAfterStoringErrorCodeFromAH
210    jmp     SHORT ExchangeCurrentInt13hHandlerWithOldInt13hHandler
211%else
212    call    ExchangeCurrentInt13hHandlerWithOldInt13hHandler
213    jmp     SHORT Int13h_ReturnFromHandlerAfterStoringErrorCodeFromAH
214%endif
215
216
217%ifdef MODULE_SERIAL_FLOPPY
218;--------------------------------------------------------------------
219; Int13h_ReturnSuccessForFloppy
220;
221; Some operations, such as format of a floppy disk track, should just
222; return success, while for hard disks it should be treated as unsupported.
223;--------------------------------------------------------------------
224ALIGN JUMP_ALIGN
225Int13h_ReturnSuccessForFloppy:
226    test    dl, dl
227    js      SHORT UnsupportedFunction
228    xor     ah, ah
229    jmp     SHORT Int13h_ReturnFromHandlerAfterStoringErrorCodeFromAH
230%endif
231
232
233;--------------------------------------------------------------------
234; Int13h_ReturnFromHandlerAfterStoringErrorCodeFromAHandTransferredSectorsFromCL
235;   Parameters:
236;       AH:     BIOS Error code
237;       CL:     Number of sectors actually transferred
238;       SS:BP:  Ptr to IDEPACK
239;   Returns:
240;       All registers are loaded from INTPACK
241;--------------------------------------------------------------------
242ALIGN JUMP_ALIGN
243Int13h_ReturnFromHandlerAfterStoringErrorCodeFromAHandTransferredSectorsFromCL:
244    mov     [bp+IDEPACK.intpack+INTPACK.al], cl
245    ; Fall to Int13h_ReturnFromHandlerAfterStoringErrorCodeFromAH
246
247
248;--------------------------------------------------------------------
249; Int13h_ReturnFromHandlerAfterStoringErrorCodeFromAH
250; Int13h_ReturnFromHandlerWithoutStoringErrorCode
251;   Parameters:
252;       AH:     BIOS Error code
253;       SS:BP:  Ptr to IDEPACK
254;   Returns:
255;       All registers are loaded from INTPACK
256;--------------------------------------------------------------------
257ALIGN JUMP_ALIGN
258Int13h_ReturnFromHandlerAfterStoringErrorCodeFromAH:
259%ifdef MODULE_SERIAL_FLOPPY
260    mov     al, [bp+IDEPACK.intpack+INTPACK.dl]
261Int13h_ReturnFromHandlerAfterStoringErrorCodeFromAH_ALHasDriveNumber:
262    call    Int13h_SetErrorCodeToBdaAndToIntpackInSSBPfromAH_ALHasDriveNumber
263
264%else
265    call    Int13h_SetErrorCodeToBdaAndToIntpackInSSBPfromAH
266%endif
267
268Int13h_ReturnFromHandlerWithoutStoringErrorCode:
269    ; Always return with interrupts enabled since there are programs that rely
270    ; on INT 13h to enable interrupts.
271    or      BYTE [bp+IDEPACK.intpack+INTPACK.flags+1], (FLG_FLAGS_IF>>8)
272    mov     sp, bp  ; This makes possible to exit anytime, no matter what is on stack
273    RESTORE_FRAME_INTPACK_FROM_SSBP     SIZE_OF_IDEPACK_WITHOUT_INTPACK
274
275
276;--------------------------------------------------------------------
277; Int13h_CallPreviousInt13hHandler
278;   Parameters:
279;       AH:     INT 13h function to call
280;       DL:     Drive number
281;       DS:     RAMVARS segment
282;   Returns:
283;       Depends on function
284;       NOTE: ES:DI needs to be returned from the previous interrupt
285;             handler, for floppy DPT in function 08h
286;   Corrupts registers:
287;       None
288;--------------------------------------------------------------------
289ALIGN JUMP_ALIGN
290Int13h_CallPreviousInt13hHandler:
291    call    ExchangeCurrentInt13hHandlerWithOldInt13hHandler
292    int     BIOS_DISK_INTERRUPT_13h
293;;;  fall-through to ExchangeCurrentInt13hHandlerWithOldInt13hHandler
294
295;--------------------------------------------------------------------
296; ExchangeCurrentInt13hHandlerWithOldInt13hHandler
297;   Parameters:
298;       DS:     RAMVARS segment
299;   Returns:
300;       Nothing
301;   Corrupts registers:
302;       Nothing
303;       Note: Flags are preserved
304;--------------------------------------------------------------------
305ALIGN JUMP_ALIGN
306ExchangeCurrentInt13hHandlerWithOldInt13hHandler:
307    push    es
308    push    si
309    LOAD_BDA_SEGMENT_PRESERVE_FLAGS_TO  es, si
310    mov     si, [RAMVARS.fpOldI13h]
311    cli
312    xchg    si, [es:BIOS_DISK_INTERRUPT_13h*4]
313    mov     [RAMVARS.fpOldI13h], si
314    mov     si, [RAMVARS.fpOldI13h+2]
315    xchg    si, [es:BIOS_DISK_INTERRUPT_13h*4+2]
316    sti
317    mov     [RAMVARS.fpOldI13h+2], si
318    pop     si
319    pop     es
320    ret
321
322
323;--------------------------------------------------------------------
324; Int13h_SetErrorCodeToBdaAndToIntpackInSSBPfromAH
325; Int13h_SetErrorCodeToIntpackInSSBPfromAH
326;   Parameters:
327;       AH:     BIOS error code (00h = no error)
328;       SS:BP:  Ptr to IDEPACK
329;   Returns:
330;       SS:BP:  Ptr to IDEPACK with error condition set
331;   Corrupts registers:
332;       DS, DI
333;--------------------------------------------------------------------
334ALIGN JUMP_ALIGN
335%ifdef MODULE_SERIAL_FLOPPY
336Int13h_SetErrorCodeToBdaAndToIntpackInSSBPfromAH_ALHasDriveNumber:
337    ; Store error code to BDA
338    mov     bx, BDA.bHDLastSt
339    test    al, al
340    js      SHORT .HardDisk
341    mov     bl, BDA.bFDRetST & 0xff
342.HardDisk:
343    LOAD_BDA_SEGMENT_TO ds, di
344    mov     [bx], ah
345    ; Fall to Int13h_SetErrorCodeToIntpackInSSBPfromAH
346
347%else
348Int13h_SetErrorCodeToBdaAndToIntpackInSSBPfromAH:
349    ; Store error code to BDA
350    LOAD_BDA_SEGMENT_TO ds, di
351    mov     [BDA.bHDLastSt], ah
352    ; Fall to Int13h_SetErrorCodeToIntpackInSSBPfromAH
353%endif
354
355    ; Store error code to INTPACK
356Int13h_SetErrorCodeToIntpackInSSBPfromAH:
357    mov     [bp+IDEPACK.intpack+INTPACK.ah], ah
358    test    ah, ah
359    jnz     SHORT .SetCFtoIntpack
360    and     BYTE [bp+IDEPACK.intpack+INTPACK.flags], ~FLG_FLAGS_CF
361    ret
362.SetCFtoIntpack:
363    or      BYTE [bp+IDEPACK.intpack+INTPACK.flags], FLG_FLAGS_CF
364    ret
365
366
367; Jump table for correct BIOS function
368ALIGN WORD_ALIGN
369g_rgw13hFuncJump:
370    dw  AH0h_HandlerForDiskControllerReset          ; 00h, Disk Controller Reset (All)
371    dw  AH1h_HandlerForReadDiskStatus               ; 01h, Read Disk Status (All)
372    dw  AH2h_HandlerForReadDiskSectors              ; 02h, Read Disk Sectors (All)
373    dw  AH3h_HandlerForWriteDiskSectors             ; 03h, Write Disk Sectors (All)
374    dw  AH4h_HandlerForVerifyDiskSectors            ; 04h, Verify Disk Sectors (All)
375%ifdef MODULE_SERIAL_FLOPPY
376    dw  Int13h_ReturnSuccessForFloppy               ; 05h, Format Disk Track (XT, AT, EISA)
377%else
378    dw  UnsupportedFunction                         ; 05h, Format Disk Track (XT, AT, EISA)
379%endif
380    dw  UnsupportedFunction                         ; 06h, Format Disk Track with Bad Sectors (XT)
381    dw  UnsupportedFunction                         ; 07h, Format Multiple Cylinders (XT)
382    dw  AH8h_HandlerForReadDiskDriveParameters      ; 08h, Read Disk Drive Parameters (All)
383    dw  AH9h_HandlerForInitializeDriveParameters    ; 09h, Initialize Drive Parameters (All)
384    dw  UnsupportedFunction                         ; 0Ah, Read Disk Sectors with ECC (XT, AT, EISA)
385    dw  UnsupportedFunction                         ; 0Bh, Write Disk Sectors with ECC (XT, AT, EISA)
386    dw  AHCh_HandlerForSeek                         ; 0Ch, Seek (All)
387    dw  AH9h_HandlerForInitializeDriveParameters    ; 0Dh, Alternate Disk Reset (All)
388    dw  UnsupportedFunction                         ; 0Eh, Read Sector Buffer (XT, PS/1), ESDI Undocumented Diagnostic (PS/2)
389    dw  UnsupportedFunction                         ; 0Fh, Write Sector Buffer (XT, PS/1), ESDI Undocumented Diagnostic (PS/2)
390    dw  AH10h_HandlerForCheckDriveReady             ; 10h, Check Drive Ready (All)
391    dw  AH11h_HandlerForRecalibrate                 ; 11h, Recalibrate (All)
392    dw  UnsupportedFunction                         ; 12h, Controller RAM Diagnostic (XT)
393    dw  UnsupportedFunction                         ; 13h, Drive Diagnostic (XT)
394    dw  AH10h_HandlerForCheckDriveReady             ; 14h, Controller Internal Diagnostic (All)
395    dw  AH15h_HandlerForReadDiskDriveSize           ; 15h, Read Disk Drive Size (AT+)
396    dw  UnsupportedFunction                         ; 16h,
397    dw  UnsupportedFunction                         ; 17h,
398    dw  UnsupportedFunction                         ; 18h,
399    dw  UnsupportedFunction                         ; 19h, Park Heads (PS/2)
400    dw  UnsupportedFunction                         ; 1Ah, Format ESDI Drive (PS/2)
401    dw  UnsupportedFunction                         ; 1Bh, Get ESDI Manufacturing Header (PS/2)
402    dw  UnsupportedFunction                         ; 1Ch, ESDI Special Functions (PS/2)
403    dw  UnsupportedFunction                         ; 1Dh,
404%ifdef MODULE_8BIT_IDE_ADVANCED
405    dw  AH1Eh_HandlerForXTCFfeatures                ; 1Eh, Lo-tech XT-CF features (XTIDE Universal BIOS)
406%else
407    dw  UnsupportedFunction                         ; 1Eh,
408%endif
409    dw  UnsupportedFunction                         ; 1Fh,
410    dw  UnsupportedFunction                         ; 20h,
411    dw  UnsupportedFunction                         ; 21h, Read Disk Sectors, Multiple Blocks (PS/1)
412    dw  UnsupportedFunction                         ; 22h, Write Disk Sectors, Multiple Blocks (PS/1)
413    dw  AH23h_HandlerForSetControllerFeatures       ; 23h, Set Controller Features Register (PS/1)
414    dw  AH24h_HandlerForSetMultipleBlocks           ; 24h, Set Multiple Blocks (PS/1)
415    dw  AH25h_HandlerForGetDriveInformation         ; 25h, Get Drive Information (PS/1)
416
417%ifdef MODULE_EBIOS
418g_rgwEbiosFunctionJumpTable:
419    dw  AH41h_HandlerForCheckIfExtensionsPresent    ; 41h, Check if Extensions Present (EBIOS)*
420    dw  AH42h_HandlerForExtendedReadSectors         ; 42h, Extended Read Sectors (EBIOS)*
421    dw  AH43h_HandlerForExtendedWriteSectors        ; 43h, Extended Write Sectors (EBIOS)*
422    dw  AH44h_HandlerForExtendedVerifySectors       ; 44h, Extended Verify Sectors (EBIOS)*
423    dw  UnsupportedFunction                         ; 45h, Lock and Unlock Drive (EBIOS)***
424    dw  UnsupportedFunction                         ; 46h, Eject Media Request (EBIOS)***
425    dw  AH47h_HandlerForExtendedSeek                ; 47h, Extended Seek (EBIOS)*
426    dw  AH48h_HandlerForGetExtendedDriveParameters  ; 48h, Get Extended Drive Parameters (EBIOS)*
427;   dw  UnsupportedFunction                         ; 49h, Get Extended Disk Change Status (EBIOS)***
428;   dw  UnsupportedFunction                         ; 4Ah, Initiate Disk Emulation (Bootable CD-ROM)
429;   dw  UnsupportedFunction                         ; 4Bh, Terminate Disk Emulation (Bootable CD-ROM)
430;   dw  UnsupportedFunction                         ; 4Ch, Initiate Disk Emulation and Boot (Bootable CD-ROM)
431;   dw  UnsupportedFunction                         ; 4Dh, Return Boot Catalog (Bootable CD-ROM)
432;   dw  UnsupportedFunction                         ; 4Eh, Set Hardware Configuration (EBIOS)**
433;
434;   * = Enhanced Drive Access Support (minimum required EBIOS functions)
435;  ** = Enhanced Disk Drive (EDD) Support
436; *** = Drive Locking and Ejecting Support
437%endif
Note: See TracBrowser for help on using the repository browser.