Context Navigation

source: xtideuniversalbios/trunk/XTIDE_Universal_BIOS/Src/Handlers/Int13h.asm@ 566

Visit:

Last change on this file since 566 was 561, checked in by aitotat@…, 11 years ago

Changes to XTIDE Universal BIOS:

MODULE_VERY_LATE_INITIALIZATION is not included on AT builds by default.
Very late initialization now uses 32h instead of 20h for temporary vector (untested but 20h might cause problems with ROM DOS).

File size: 16.1 KB

Rev	Line
[90]	1	; Project name : XTIDE Universal BIOS
[3]	2	; Description : Int 13h BIOS functions (Floppy and Hard disk).
	3
[376]	4	;
[445]	5	; XTIDE Universal BIOS and Associated Tools
[526]	6	; Copyright (C) 2009-2010 by Tomi Tilli, 2011-2013 by XTIDE Universal BIOS Team.
[376]	7	;
	8	; This program is free software; you can redistribute it and/or modify
	9	; it under the terms of the GNU General Public License as published by
	10	; the Free Software Foundation; either version 2 of the License, or
	11	; (at your option) any later version.
[445]	12	;
[376]	13	; This program is distributed in the hope that it will be useful,
	14	; but WITHOUT ANY WARRANTY; without even the implied warranty of
	15	; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
[445]	16	; GNU General Public License for more details.
[376]	17	; Visit http://www.gnu.org/licenses/old-licenses/gpl-2.0.html
[445]	18	;
[376]	19
[3]	20	; Section containing code
	21	SECTION .text
	22
	23	;--------------------------------------------------------------------
	24	; Int 13h software interrupt handler.
[417]	25	; This handler changes stack to top of stolen conventional memory
	26	; and then calls the actual INT 13h handler (Int13h_DiskFunctionsHandler).
	27	;
	28	; Int13h_DiskFunctionsHandlerWithStackChange
	29	; Parameters:
	30	; AH: Bios function
	31	; DL: Drive number
	32	; Other: Depends on function
	33	; Returns:
	34	; Depends on function
	35	;--------------------------------------------------------------------
	36	%ifdef RELOCATE_INT13H_STACK
	37	ALIGN JUMP_ALIGN
	38	Int13h_DiskFunctionsHandlerWithStackChange:
[525]	39	sti ; Enable interrupts
	40	; TODO: Maybe we need to save Flags (DF) as well?
	41	push ds ; Save DS:DI on the original stack
[417]	42	push di
	43	call RamVars_GetSegmentToDS
	44
	45	; Store entry registers to RAMVARS
[525]	46	%ifdef USE_386
	47	pop DWORD [RAMVARS.dwStackChangeDSDI]
	48	%else
	49	pop WORD [RAMVARS.wStackChangeDI] ; Pop DS:DI to the top of what
	50	pop WORD [RAMVARS.wStackChangeDS] ; is to become the new stack
	51	%endif
[417]	52	mov [RAMVARS.fpInt13hEntryStack], sp
	53	mov [RAMVARS.fpInt13hEntryStack+2], ss
	54
	55	; Load new stack and restore DS and DI
[525]	56	mov di, ds ; We can save 2 bytes by using PUSH/POP but it's slower
	57	mov ss, di ; No need to wrap with CLI/STI since this is for AT only (286+)
	58	mov sp, RAMVARS.rgbTopOfStack-4
	59	pop di ; DI before stack change
	60	pop ds ; DS before stack change
[417]	61
	62	; Call INT 13h
	63	pushf
	64	push cs
	65	call Int13h_DiskFunctionsHandler
	66
	67	; Restore stack (we must not corrupt FLAGS!)
	68	%ifdef USE_386
	69	lss sp, [ss:RAMVARS.fpInt13hEntryStack]
	70	%else
[525]	71	cli
[417]	72	mov sp, [ss:RAMVARS.fpInt13hEntryStack]
	73	mov ss, [ss:RAMVARS.fpInt13hEntryStack+2]
[525]	74	sti
[417]	75	%endif
	76	retf 2 ; Skip FLAGS from stack
	77	%endif ; RELOCATE_INT13H_STACK
	78
	79
	80	;--------------------------------------------------------------------
	81	; Int 13h software interrupt handler.
[3]	82	; Jumps to specific function defined in AH.
	83	;
[148]	84	; Note to developers: Do not make recursive INT 13h calls!
	85	;
	86	; Int13h_DiskFunctionsHandler
[3]	87	; Parameters:
	88	; AH: Bios function
	89	; DL: Drive number
[148]	90	; Other: Depends on function
[3]	91	; Returns:
	92	; Depends on function
	93	;--------------------------------------------------------------------
	94	ALIGN JUMP_ALIGN
[148]	95	Int13h_DiskFunctionsHandler:
[525]	96	%ifndef RELOCATE_INT13H_STACK
[3]	97	sti ; Enable interrupts
[556]	98	%endif
[150]	99	cld ; String instructions to increment pointers
[443]	100	CREATE_FRAME_INTPACK_TO_SSBP SIZE_OF_IDEPACK_WITHOUT_INTPACK
[3]	101	call RamVars_GetSegmentToDS
[294]	102
[493]	103	%ifdef MODULE_DRIVEXLATE
[148]	104	call DriveXlate_ToOrBack
[395]	105	%endif
[322]	106	call FindDPT_ForDriveNumberInDL ; DS:DI points to our DPT, or NULL if not our drive
	107	jc SHORT .NotOurDrive ; DPT not found so this is not one of our drives
[258]	108
[294]	109	.OurFunction:
[3]	110	; Jump to correct BIOS function
[148]	111	eMOVZX bx, ah
[445]	112	eSHL_IM bx, 1
[165]	113	cmp ah, 25h ; Possible EBIOS function?
[417]	114	%ifndef MODULE_EBIOS
	115	ja SHORT UnsupportedFunction
	116	jmp [cs:bx+g_rgw13hFuncJump] ; Jump to BIOS function
	117
	118	%else ; If using MODULE_EBIOS
[165]	119	ja SHORT .JumpToEbiosFunction
[148]	120	jmp [cs:bx+g_rgw13hFuncJump] ; Jump to BIOS function
[3]	121
[165]	122	ALIGN JUMP_ALIGN
	123	.JumpToEbiosFunction:
[542]	124	test BYTE [di+DPT.bFlagsLow], FLGL_DPT_LBA
[417]	125	jz SHORT UnsupportedFunction ; No eINT 13h for CHS drives
[322]	126	sub bl, 41h<<1 ; BX = Offset to eINT 13h jump table
[417]	127	jb SHORT UnsupportedFunction
[167]	128	cmp ah, 48h
[417]	129	ja SHORT UnsupportedFunction
[165]	130	jmp [cs:bx+g_rgwEbiosFunctionJumpTable]
[417]	131	%endif ; MODULE_EBIOS
[3]	132
[417]	133
[322]	134	ALIGN JUMP_ALIGN
	135	.NotOurDrive:
	136	test ah, ah
	137	jz SHORT .OurFunction ; We handle all function 0h requests (resets)
[260]	138
[556]	139	%ifndef MODULE_SERIAL_FLOPPY
	140	; Without floppy support, we handle only hard disk traffic for function 08h.
	141	test dl, dl
	142	jns SHORT Int13h_DirectCallToAnotherBios
	143	%endif
	144	; With floppy support, we handle all traffic for function 08h, as we need to wrap both hard disk and floppy drive counts.
	145	cmp ah, GET_DRIVE_PARAMETERS
[322]	146	je SHORT .OurFunction
	147	; Fall to Int13h_DirectCallToAnotherBios
	148
[417]	149
[3]	150	;--------------------------------------------------------------------
[417]	151	; UnsupportedFunction
[3]	152	; Int13h_DirectCallToAnotherBios
	153	; Parameters:
[148]	154	; DL: Translated drive number
[3]	155	; DS: RAMVARS segment
[150]	156	; SS:BP: Ptr to IDEPACK
[148]	157	; BX, DI: Corrupted on Int13h_DiskFunctionsHandler
[161]	158	; Other: Function specific INT 13h parameters
[3]	159	; Returns:
	160	; Depends on function
	161	; Corrupts registers:
	162	; Flags
	163	;--------------------------------------------------------------------
	164	ALIGN JUMP_ALIGN
[417]	165	UnsupportedFunction:
[3]	166	Int13h_DirectCallToAnotherBios:
[557]	167	%ifdef MODULE_DRIVEXLATE
	168	; Disable drive number translations in case of recursive INT 13h calls
	169	mov [RAMVARS.xlateVars+XLATEVARS.bXlatedDrv], dl
	170	push WORD [RAMVARS.xlateVars+XLATEVARS.wFDandHDswap]
[558]	171	call DriveXlate_Reset ; No translation
[557]	172	%endif
	173
	174	push bp ; Store offset to IDEPACK (SS:SP now points it)
	175
	176	; Simulate INT by pushing flags and return address
	177	push WORD [bp+IDEPACK.intpack+INTPACK.flags]
[561]	178	%if 0
	179	; No standard INT 13h function uses FLAGS as parameters so no need to restore them
[557]	180	popf
[561]	181	pushf
	182	%endif
[557]	183	push cs
	184	ePUSH_T di, .ReturnFromAnotherBios ; Can not corrupt flags
	185
	186	; Push old INT 13h handler and restore registers
	187	push WORD [RAMVARS.fpOldI13h+2]
	188	push WORD [RAMVARS.fpOldI13h]
[150]	189	mov bx, [bp+IDEPACK.intpack+INTPACK.bx]
	190	mov di, [bp+IDEPACK.intpack+INTPACK.di]
	191	mov ds, [bp+IDEPACK.intpack+INTPACK.ds]
	192	mov bp, [bp+IDEPACK.intpack+INTPACK.bp]
[557]	193	retf ; "Return" to old INT 13h
	194	.ReturnFromAnotherBios:
[3]	195
[557]	196	%if 0
	197	; We need to restore our pointer to IDEPACK but we cannot corrupt any register
	198	push ax ; Dummy WORD
	199	cli
	200	xchg bp, sp
	201	mov [bp], sp ; Replace dummy WORD with returned BP
	202	mov sp, [bp+2] ; Load offset to IDEPACK
	203	xchg sp, bp
	204	sti ; We would have set IF anyway when exiting INT 13h
	205	pop WORD [bp+IDEPACK.intpack+INTPACK.bp]
	206	%endif
	207	; Actually we can corrupt BP since no standard INT 13h function uses it as return
	208	; register. Above code is kept here just in case if there is some non-standard function.
	209	; POP BP below also belongs to the above code.
	210	pop bp ; Clean IDEPACK offset from stack
[556]	211
[557]	212	; Store remaining returned values to INTPACK
[148]	213	%ifdef USE_386
[557]	214	; We do not use GS or FS at the moment
[322]	215	; mov [bp+IDEPACK.intpack+INTPACK.gs], gs
	216	; mov [bp+IDEPACK.intpack+INTPACK.fs], fs
[148]	217	%endif
[150]	218	mov [bp+IDEPACK.intpack+INTPACK.es], es
	219	mov [bp+IDEPACK.intpack+INTPACK.ds], ds
	220	mov [bp+IDEPACK.intpack+INTPACK.di], di
	221	mov [bp+IDEPACK.intpack+INTPACK.si], si
	222	mov [bp+IDEPACK.intpack+INTPACK.bx], bx
[493]	223	%ifdef MODULE_DRIVEXLATE
[150]	224	mov [bp+IDEPACK.intpack+INTPACK.dh], dh
[414]	225	%else
	226	mov [bp+IDEPACK.intpack+INTPACK.dx], dx
	227	%endif
[150]	228	mov [bp+IDEPACK.intpack+INTPACK.cx], cx
	229	mov [bp+IDEPACK.intpack+INTPACK.ax], ax
[148]	230	pushf
[150]	231	pop WORD [bp+IDEPACK.intpack+INTPACK.flags]
[148]	232	call RamVars_GetSegmentToDS
[414]	233
[493]	234	%ifdef MODULE_DRIVEXLATE
[557]	235	; Restore drive number translation back to what it was
	236	pop WORD [RAMVARS.xlateVars+XLATEVARS.wFDandHDswap]
[414]	237	cmp dl, [RAMVARS.xlateVars+XLATEVARS.bXlatedDrv] ; DL is still drive number?
[557]	238	je SHORT Int13h_ReturnFromHandlerAfterStoringErrorCodeFromAH
[414]	239	mov [bp+IDEPACK.intpack+INTPACK.dl], dl ; Something is returned in DL
	240	%endif
[249]	241	jmp SHORT Int13h_ReturnFromHandlerAfterStoringErrorCodeFromAH
[3]	242
[417]	243
[260]	244	%ifdef MODULE_SERIAL_FLOPPY
	245	;--------------------------------------------------------------------
	246	; Int13h_ReturnSuccessForFloppy
	247	;
	248	; Some operations, such as format of a floppy disk track, should just
	249	; return success, while for hard disks it should be treated as unsupported.
	250	;--------------------------------------------------------------------
	251	ALIGN JUMP_ALIGN
	252	Int13h_ReturnSuccessForFloppy:
	253	test dl, dl
[417]	254	js SHORT UnsupportedFunction
[294]	255	xor ah, ah
[417]	256	jmp SHORT Int13h_ReturnFromHandlerAfterStoringErrorCodeFromAH
[260]	257	%endif
[3]	258
[417]	259
[3]	260	;--------------------------------------------------------------------
[249]	261	; Int13h_ReturnFromHandlerAfterStoringErrorCodeFromAHandTransferredSectorsFromCL
	262	; Parameters:
	263	; AH: BIOS Error code
	264	; CL: Number of sectors actually transferred
	265	; SS:BP: Ptr to IDEPACK
	266	; Returns:
	267	; All registers are loaded from INTPACK
	268	;--------------------------------------------------------------------
	269	ALIGN JUMP_ALIGN
	270	Int13h_ReturnFromHandlerAfterStoringErrorCodeFromAHandTransferredSectorsFromCL:
	271	mov [bp+IDEPACK.intpack+INTPACK.al], cl
	272	; Fall to Int13h_ReturnFromHandlerAfterStoringErrorCodeFromAH
	273
[417]	274
[249]	275	;--------------------------------------------------------------------
[148]	276	; Int13h_ReturnFromHandlerAfterStoringErrorCodeFromAH
	277	; Int13h_ReturnFromHandlerWithoutStoringErrorCode
[32]	278	; Parameters:
[148]	279	; AH: BIOS Error code
[150]	280	; SS:BP: Ptr to IDEPACK
[32]	281	; Returns:
[148]	282	; All registers are loaded from INTPACK
[32]	283	;--------------------------------------------------------------------
	284	ALIGN JUMP_ALIGN
[148]	285	Int13h_ReturnFromHandlerAfterStoringErrorCodeFromAH:
[258]	286	%ifdef MODULE_SERIAL_FLOPPY
	287	mov al, [bp+IDEPACK.intpack+INTPACK.dl]
[294]	288	Int13h_ReturnFromHandlerAfterStoringErrorCodeFromAH_ALHasDriveNumber:
[258]	289	call Int13h_SetErrorCodeToBdaAndToIntpackInSSBPfromAH_ALHasDriveNumber
[414]	290
[258]	291	%else
[150]	292	call Int13h_SetErrorCodeToBdaAndToIntpackInSSBPfromAH
[258]	293	%endif
[414]	294
[148]	295	Int13h_ReturnFromHandlerWithoutStoringErrorCode:
[417]	296	; Always return with interrupts enabled since there are programs that rely
	297	; on INT 13h to enable interrupts.
	298	or BYTE [bp+IDEPACK.intpack+INTPACK.flags+1], (FLG_FLAGS_IF>>8)
	299	mov sp, bp ; This makes possible to exit anytime, no matter what is on stack
[443]	300	RESTORE_FRAME_INTPACK_FROM_SSBP SIZE_OF_IDEPACK_WITHOUT_INTPACK
[32]	301
	302
	303	;--------------------------------------------------------------------
[148]	304	; Int13h_CallPreviousInt13hHandler
[3]	305	; Parameters:
[148]	306	; AH: INT 13h function to call
	307	; DL: Drive number
	308	; DS: RAMVARS segment
[3]	309	; Returns:
	310	; Depends on function
[294]	311	; NOTE: ES:DI needs to be returned from the previous interrupt
[258]	312	; handler, for floppy DPT in function 08h
[3]	313	; Corrupts registers:
[258]	314	; None
[3]	315	;--------------------------------------------------------------------
	316	ALIGN JUMP_ALIGN
[148]	317	Int13h_CallPreviousInt13hHandler:
[557]	318	pushf ; Simulate INT by pushing flags
	319	call far [RAMVARS.fpOldI13h]
[148]	320	ret
[28]	321
[35]	322
[150]	323	;--------------------------------------------------------------------
	324	; Int13h_SetErrorCodeToBdaAndToIntpackInSSBPfromAH
	325	; Int13h_SetErrorCodeToIntpackInSSBPfromAH
	326	; Parameters:
	327	; AH: BIOS error code (00h = no error)
	328	; SS:BP: Ptr to IDEPACK
	329	; Returns:
	330	; SS:BP: Ptr to IDEPACK with error condition set
	331	; Corrupts registers:
	332	; DS, DI
	333	;--------------------------------------------------------------------
	334	ALIGN JUMP_ALIGN
[258]	335	%ifdef MODULE_SERIAL_FLOPPY
	336	Int13h_SetErrorCodeToBdaAndToIntpackInSSBPfromAH_ALHasDriveNumber:
	337	; Store error code to BDA
	338	mov bx, BDA.bHDLastSt
	339	test al, al
[414]	340	js SHORT .HardDisk
[258]	341	mov bl, BDA.bFDRetST & 0xff
	342	.HardDisk:
	343	LOAD_BDA_SEGMENT_TO ds, di
[294]	344	mov [bx], ah
[417]	345	; Fall to Int13h_SetErrorCodeToIntpackInSSBPfromAH
	346
[258]	347	%else
[150]	348	Int13h_SetErrorCodeToBdaAndToIntpackInSSBPfromAH:
	349	; Store error code to BDA
[294]	350	LOAD_BDA_SEGMENT_TO ds, di
[150]	351	mov [BDA.bHDLastSt], ah
[417]	352	; Fall to Int13h_SetErrorCodeToIntpackInSSBPfromAH
[258]	353	%endif
[35]	354
[150]	355	; Store error code to INTPACK
	356	Int13h_SetErrorCodeToIntpackInSSBPfromAH:
	357	mov [bp+IDEPACK.intpack+INTPACK.ah], ah
	358	test ah, ah
	359	jnz SHORT .SetCFtoIntpack
	360	and BYTE [bp+IDEPACK.intpack+INTPACK.flags], ~FLG_FLAGS_CF
	361	ret
	362	.SetCFtoIntpack:
	363	or BYTE [bp+IDEPACK.intpack+INTPACK.flags], FLG_FLAGS_CF
	364	ret
	365
	366
[3]	367	; Jump table for correct BIOS function
	368	ALIGN WORD_ALIGN
	369	g_rgw13hFuncJump:
[417]	370	dw AH0h_HandlerForDiskControllerReset ; 00h, Disk Controller Reset (All)
	371	dw AH1h_HandlerForReadDiskStatus ; 01h, Read Disk Status (All)
	372	dw AH2h_HandlerForReadDiskSectors ; 02h, Read Disk Sectors (All)
	373	dw AH3h_HandlerForWriteDiskSectors ; 03h, Write Disk Sectors (All)
	374	dw AH4h_HandlerForVerifyDiskSectors ; 04h, Verify Disk Sectors (All)
[260]	375	%ifdef MODULE_SERIAL_FLOPPY
[417]	376	dw Int13h_ReturnSuccessForFloppy ; 05h, Format Disk Track (XT, AT, EISA)
[260]	377	%else
[417]	378	dw UnsupportedFunction ; 05h, Format Disk Track (XT, AT, EISA)
[260]	379	%endif
[417]	380	dw UnsupportedFunction ; 06h, Format Disk Track with Bad Sectors (XT)
	381	dw UnsupportedFunction ; 07h, Format Multiple Cylinders (XT)
	382	dw AH8h_HandlerForReadDiskDriveParameters ; 08h, Read Disk Drive Parameters (All)
	383	dw AH9h_HandlerForInitializeDriveParameters ; 09h, Initialize Drive Parameters (All)
	384	dw UnsupportedFunction ; 0Ah, Read Disk Sectors with ECC (XT, AT, EISA)
	385	dw UnsupportedFunction ; 0Bh, Write Disk Sectors with ECC (XT, AT, EISA)
	386	dw AHCh_HandlerForSeek ; 0Ch, Seek (All)
[507]	387	dw AH9h_HandlerForInitializeDriveParameters ; 0Dh, Alternate Disk Reset (All)
[417]	388	dw UnsupportedFunction ; 0Eh, Read Sector Buffer (XT, PS/1), ESDI Undocumented Diagnostic (PS/2)
	389	dw UnsupportedFunction ; 0Fh, Write Sector Buffer (XT, PS/1), ESDI Undocumented Diagnostic (PS/2)
	390	dw AH10h_HandlerForCheckDriveReady ; 10h, Check Drive Ready (All)
	391	dw AH11h_HandlerForRecalibrate ; 11h, Recalibrate (All)
	392	dw UnsupportedFunction ; 12h, Controller RAM Diagnostic (XT)
	393	dw UnsupportedFunction ; 13h, Drive Diagnostic (XT)
[540]	394	dw AH10h_HandlerForCheckDriveReady ; 14h, Controller Internal Diagnostic (All)
[417]	395	dw AH15h_HandlerForReadDiskDriveSize ; 15h, Read Disk Drive Size (AT+)
	396	dw UnsupportedFunction ; 16h,
	397	dw UnsupportedFunction ; 17h,
	398	dw UnsupportedFunction ; 18h,
	399	dw UnsupportedFunction ; 19h, Park Heads (PS/2)
	400	dw UnsupportedFunction ; 1Ah, Format ESDI Drive (PS/2)
	401	dw UnsupportedFunction ; 1Bh, Get ESDI Manufacturing Header (PS/2)
	402	dw UnsupportedFunction ; 1Ch, ESDI Special Functions (PS/2)
	403	dw UnsupportedFunction ; 1Dh,
[493]	404	%ifdef MODULE_8BIT_IDE_ADVANCED
[471]	405	dw AH1Eh_HandlerForXTCFfeatures ; 1Eh, Lo-tech XT-CF features (XTIDE Universal BIOS)
	406	%else
[525]	407	dw UnsupportedFunction ; 1Eh,
[471]	408	%endif
[417]	409	dw UnsupportedFunction ; 1Fh,
	410	dw UnsupportedFunction ; 20h,
	411	dw UnsupportedFunction ; 21h, Read Disk Sectors, Multiple Blocks (PS/1)
	412	dw UnsupportedFunction ; 22h, Write Disk Sectors, Multiple Blocks (PS/1)
	413	dw AH23h_HandlerForSetControllerFeatures ; 23h, Set Controller Features Register (PS/1)
	414	dw AH24h_HandlerForSetMultipleBlocks ; 24h, Set Multiple Blocks (PS/1)
	415	dw AH25h_HandlerForGetDriveInformation ; 25h, Get Drive Information (PS/1)
[165]	416
[176]	417	%ifdef MODULE_EBIOS
[165]	418	g_rgwEbiosFunctionJumpTable:
[417]	419	dw AH41h_HandlerForCheckIfExtensionsPresent ; 41h, Check if Extensions Present (EBIOS)*
	420	dw AH42h_HandlerForExtendedReadSectors ; 42h, Extended Read Sectors (EBIOS)*
	421	dw AH43h_HandlerForExtendedWriteSectors ; 43h, Extended Write Sectors (EBIOS)*
	422	dw AH44h_HandlerForExtendedVerifySectors ; 44h, Extended Verify Sectors (EBIOS)*
	423	dw UnsupportedFunction ; 45h, Lock and Unlock Drive (EBIOS)***
	424	dw UnsupportedFunction ; 46h, Eject Media Request (EBIOS)***
	425	dw AH47h_HandlerForExtendedSeek ; 47h, Extended Seek (EBIOS)*
	426	dw AH48h_HandlerForGetExtendedDriveParameters ; 48h, Get Extended Drive Parameters (EBIOS)*
	427	; dw UnsupportedFunction ; 49h, Get Extended Disk Change Status (EBIOS)***
	428	; dw UnsupportedFunction ; 4Ah, Initiate Disk Emulation (Bootable CD-ROM)
	429	; dw UnsupportedFunction ; 4Bh, Terminate Disk Emulation (Bootable CD-ROM)
	430	; dw UnsupportedFunction ; 4Ch, Initiate Disk Emulation and Boot (Bootable CD-ROM)
	431	; dw UnsupportedFunction ; 4Dh, Return Boot Catalog (Bootable CD-ROM)
	432	; dw UnsupportedFunction ; 4Eh, Set Hardware Configuration (EBIOS)**
[150]	433	;
	434	; * = Enhanced Drive Access Support (minimum required EBIOS functions)
	435	; ** = Enhanced Disk Drive (EDD) Support
	436	; *** = Drive Locking and Ejecting Support
[181]	437	%endif

Note: See TracBrowser for help on using the repository browser.

Download in other formats: