source: xtideuniversalbios/trunk/XTIDE_Universal_BIOS/Src/Device/IDE/IdeWait.asm @ 417

Last change on this file since 417 was 400, checked in by aitotat@…, 12 years ago

Changes to XTIDE Universal BIOS:

  • Moved 8-bit device support to MODULE_8BIT_IDE.
  • JR-IDE/ISA support requires a lot less bytes.
  • AT builds now always use full operating mode.
File size: 4.6 KB
RevLine 
[150]1; Project name  :   XTIDE Universal BIOS
2; Description   :   IDE Device wait functions.
3
[376]4;
5; XTIDE Universal BIOS and Associated Tools 
6; Copyright (C) 2009-2010 by Tomi Tilli, 2011-2012 by XTIDE Universal BIOS Team.
7;
8; This program is free software; you can redistribute it and/or modify
9; it under the terms of the GNU General Public License as published by
10; the Free Software Foundation; either version 2 of the License, or
11; (at your option) any later version.
12; 
13; This program is distributed in the hope that it will be useful,
14; but WITHOUT ANY WARRANTY; without even the implied warranty of
15; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
16; GNU General Public License for more details.     
17; Visit http://www.gnu.org/licenses/old-licenses/gpl-2.0.html
18;       
19
[150]20; Section containing code
21SECTION .text
22
23;--------------------------------------------------------------------
24; IdeWait_IRQorDRQ
25;   Parameters:
26;       DS:DI:  Ptr to DPT (in RAMVARS segment)
[267]27;       SS:BP:  Ptr to IDEPACK, PIOVARS or MEMPIOVARS
[150]28;   Returns:
29;       AH:     INT 13h Error Code
30;       CF:     Cleared if success, Set if error
31;   Corrupts registers:
32;       AL, BX, CX, DX
33;--------------------------------------------------------------------
[400]34IdeWait_IRQorDRQ:
[150]35    mov     bx, TIMEOUT_AND_STATUS_TO_WAIT(TIMEOUT_DRQ, FLG_STATUS_DRQ)
[400]36
37%ifdef MODULE_IRQ
[150]38    test    BYTE [bp+IDEPACK.bDeviceControl], FLG_DEVCONTROL_nIEN
[400]39    jnz     SHORT IdeWait_PollStatusFlagInBLwithTimeoutInBH ; Interrupt disabled
[238]40%endif
[150]41    ; Fall to IdeWait_IRQorStatusFlagInBLwithTimeoutInBH
42
43
44;--------------------------------------------------------------------
45; IdeWait_IRQorStatusFlagInBLwithTimeoutInBH
46;   Parameters:
47;       BH:     Timeout ticks
48;       BL:     IDE Status Register bit to wait
49;       DS:DI:  Ptr to DPT (in RAMVARS segment)
50;   Returns:
51;       AH:     INT 13h Error Code
52;       CF:     Cleared if success, Set if error
53;   Corrupts registers:
54;       AL, BX, CX, DX
55;--------------------------------------------------------------------
[400]56IdeWait_IRQorStatusFlagInBLwithTimeoutInBH:
57%ifdef MODULE_IRQ
58    call    IdeIrq_WaitForIRQ
[238]59%endif
[150]60    ; Always fall to IdeWait_PollStatusFlagInBLwithTimeoutInBH for error processing
61
62
63;--------------------------------------------------------------------
64; IdeWait_PollStatusFlagInBLwithTimeoutInBH
65;   Parameters:
66;       BH:     Timeout ticks
67;       BL:     IDE Status Register bit to poll
68;       DS:DI:  Ptr to DPT (in RAMVARS segment)
69;   Returns:
70;       AH:     INT 13h Error Code
71;       CF:     Cleared if success, Set if error
72;   Corrupts registers:
73;       AL, BX, CX, DX
74;--------------------------------------------------------------------
[400]75IdeWait_PollStatusFlagInBLwithTimeoutInBH:
[150]76    mov     ah, bl
[155]77    mov     cl, bh
78    call    Timer_InitializeTimeoutWithTicksInCL
[150]79    and     ah, ~FLG_STATUS_BSY
[400]80    jz      SHORT PollBsyOnly
[150]81    ; Fall to PollBsyAndFlgInAH
82
83;--------------------------------------------------------------------
84; PollBsyAndFlgInAH
85;   Parameters:
86;       AH:     Status Register Flag to poll (until set) when device not busy
87;       DS:DI:  Ptr to DPT (in RAMVARS segment)
88;   Returns:
89;       AH:     BIOS Error code
90;       CF:     Clear if wait completed successfully (no errors)
91;               Set if any error
92;   Corrupts registers:
93;       AL, BX, CX, DX
94;--------------------------------------------------------------------
[400]95IdePollBsyAndFlgInAH:
96    call    IdeIO_InputStatusRegisterToAL       ; Discard contents of first read
97
[150]98.PollLoop:
[400]99    call    IdeIO_InputStatusRegisterToAL
[150]100    test    al, FLG_STATUS_BSY                  ; Controller busy?
101    jnz     SHORT .UpdateTimeout                ;  If so, jump to timeout update
102    test    al, ah                              ; Test secondary flag
[400]103    jnz     SHORT IdeError_GetBiosErrorCodeToAHfromPolledStatusRegisterInAL
[150]104.UpdateTimeout:
[155]105    call    Timer_SetCFifTimeout
[150]106    jnc     SHORT .PollLoop                     ; Loop if time left
[400]107    call    IdeError_GetBiosErrorCodeToAHfromPolledStatusRegisterInAL
[150]108    jc      SHORT .ReturnErrorCodeInAH
109    mov     ah, RET_HD_TIMEOUT                  ; Expected bit never got set
110    stc
111.ReturnErrorCodeInAH:
112    ret
113
114
115;--------------------------------------------------------------------
116; PollBsyOnly
117;   Parameters:
118;       DS:DI:  Ptr to DPT (in RAMVARS segment)
119;   Returns:
120;       AH:     BIOS Error code
121;       CF:     Clear if wait completed successfully (no errors)
122;               Set if any error
123;   Corrupts registers:
124;       AL, BX, CX, DX
125;--------------------------------------------------------------------
[400]126PollBsyOnly:
127    call    IdeIO_InputStatusRegisterToAL       ; Discard contents of first read
128
[150]129.PollLoop:
[400]130    call    IdeIO_InputStatusRegisterToAL
[150]131    test    al, FLG_STATUS_BSY                  ; Controller busy?
[400]132    jz      SHORT IdeError_GetBiosErrorCodeToAHfromPolledStatusRegisterInAL
[155]133    call    Timer_SetCFifTimeout                ; Update timeout counter
[150]134    jnc     SHORT .PollLoop                     ; Loop if time left (sets CF on timeout)
[400]135    jmp     SHORT IdeError_GetBiosErrorCodeToAHfromPolledStatusRegisterInAL
Note: See TracBrowser for help on using the repository browser.