[150] | 1 | ; Project name : XTIDE Universal BIOS |
---|
| 2 | ; Description : IDE Device transfer functions. |
---|
| 3 | |
---|
[376] | 4 | ; |
---|
[445] | 5 | ; XTIDE Universal BIOS and Associated Tools |
---|
[376] | 6 | ; Copyright (C) 2009-2010 by Tomi Tilli, 2011-2012 by XTIDE Universal BIOS Team. |
---|
| 7 | ; |
---|
| 8 | ; This program is free software; you can redistribute it and/or modify |
---|
| 9 | ; it under the terms of the GNU General Public License as published by |
---|
| 10 | ; the Free Software Foundation; either version 2 of the License, or |
---|
| 11 | ; (at your option) any later version. |
---|
[445] | 12 | ; |
---|
[376] | 13 | ; This program is distributed in the hope that it will be useful, |
---|
| 14 | ; but WITHOUT ANY WARRANTY; without even the implied warranty of |
---|
| 15 | ; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
---|
[445] | 16 | ; GNU General Public License for more details. |
---|
[376] | 17 | ; Visit http://www.gnu.org/licenses/old-licenses/gpl-2.0.html |
---|
[445] | 18 | ; |
---|
[376] | 19 | |
---|
[150] | 20 | ; Structure containing variables for PIO transfer functions. |
---|
| 21 | ; This struct must not be larger than IDEPACK without INTPACK. |
---|
[414] | 22 | struc PIOVARS ; Must not be larger than 9 bytes! See IDEPACK in RamVars.inc. |
---|
| 23 | .wDataPort resb 2 ; 0-1, IDE Data Port |
---|
| 24 | .fnXfer resb 2 ; 2-3, Offset to transfer function |
---|
| 25 | .wSectorsInBlock resb 2 ; 4-5, Block size in sectors |
---|
[363] | 26 | .bSectorsLeft resb 1 ; 6, Sectors left to transfer |
---|
[218] | 27 | resb 1 ; 7, IDEPACK.bDeviceControl |
---|
[363] | 28 | .bSectorsDone resb 1 ; 8, Number of sectors xferred |
---|
[150] | 29 | endstruc |
---|
| 30 | |
---|
| 31 | |
---|
| 32 | ; Section containing code |
---|
| 33 | SECTION .text |
---|
| 34 | |
---|
| 35 | ;-------------------------------------------------------------------- |
---|
| 36 | ; IdeTransfer_StartWithCommandInAL |
---|
| 37 | ; Parameters: |
---|
| 38 | ; AL: IDE command that was used to start the transfer |
---|
[171] | 39 | ; (all PIO read and write commands including Identify Device) |
---|
[218] | 40 | ; ES:SI: Ptr to normalized data buffer |
---|
[150] | 41 | ; DS:DI: Ptr to DPT (in RAMVARS segment) |
---|
| 42 | ; SS:BP: Ptr to IDEPACK |
---|
| 43 | ; Returns: |
---|
| 44 | ; AH: INT 13h Error Code |
---|
[218] | 45 | ; CX: Number of successfully transferred sectors |
---|
[150] | 46 | ; CF: Cleared if success, Set if error |
---|
| 47 | ; Corrupts registers: |
---|
[218] | 48 | ; AL, BX, DX, SI, ES |
---|
[150] | 49 | ;-------------------------------------------------------------------- |
---|
| 50 | ALIGN JUMP_ALIGN |
---|
| 51 | IdeTransfer_StartWithCommandInAL: |
---|
[157] | 52 | ; Are we reading or writing? |
---|
[171] | 53 | test al, 16 ; Bit 4 is cleared on all the read commands but set on 3 of the 4 write commands |
---|
[242] | 54 | mov ah, [bp+IDEPACK.bSectorCount] |
---|
| 55 | jnz SHORT WriteToDrive |
---|
[171] | 56 | cmp al, COMMAND_WRITE_MULTIPLE |
---|
[242] | 57 | je SHORT WriteToDrive |
---|
| 58 | ; Fall to ReadFromDrive |
---|
[150] | 59 | |
---|
| 60 | ;-------------------------------------------------------------------- |
---|
[242] | 61 | ; ReadFromDrive |
---|
[150] | 62 | ; Parameters: |
---|
[242] | 63 | ; AH: Number of sectors to transfer (1...128) |
---|
| 64 | ; ES:SI: Normalized ptr to buffer to receive data |
---|
[150] | 65 | ; DS:DI: Ptr to DPT (in RAMVARS segment) |
---|
| 66 | ; SS:BP: Ptr to PIOVARS |
---|
| 67 | ; Returns: |
---|
[242] | 68 | ; DS:DI: Ptr to DPT (in RAMVARS segment) |
---|
[150] | 69 | ; AH: BIOS Error code |
---|
[218] | 70 | ; CX: Number of successfully transferred sectors |
---|
[294] | 71 | ; CF: 0 if transfer successful |
---|
[150] | 72 | ; 1 if any error |
---|
| 73 | ; Corrupts registers: |
---|
[218] | 74 | ; AL, BX, DX, SI, ES |
---|
[150] | 75 | ;-------------------------------------------------------------------- |
---|
[242] | 76 | ReadFromDrive: |
---|
| 77 | ; Prepare to read data to ESSI |
---|
| 78 | mov bx, g_rgfnPioRead |
---|
| 79 | call InitializePiovarsInSSBPwithSectorCountInAH |
---|
| 80 | |
---|
| 81 | ; Wait until drive is ready to transfer |
---|
| 82 | call IdeWait_IRQorDRQ ; Wait until ready to transfer |
---|
[218] | 83 | jc SHORT ReturnWithTransferErrorInAH |
---|
[242] | 84 | xchg si, di ; ES:DI now points buffer |
---|
[218] | 85 | |
---|
[363] | 86 | mov cx, [bp+PIOVARS.wSectorsInBlock] ; Max 128 |
---|
[242] | 87 | |
---|
[150] | 88 | ALIGN JUMP_ALIGN |
---|
[242] | 89 | .ReadNextBlockFromDrive: |
---|
[150] | 90 | mov dx, [bp+PIOVARS.wDataPort] |
---|
[363] | 91 | cmp [bp+PIOVARS.bSectorsLeft], cl |
---|
[242] | 92 | jbe SHORT .ReadLastBlockFromDrive |
---|
[218] | 93 | call [bp+PIOVARS.fnXfer] |
---|
[169] | 94 | |
---|
[218] | 95 | ; Wait until ready for next block and check for errors |
---|
[242] | 96 | xchg di, si ; DS:DI now points DPT |
---|
[218] | 97 | call IdeWait_IRQorDRQ ; Wait until ready to transfer |
---|
| 98 | jc SHORT ReturnWithTransferErrorInAH |
---|
[242] | 99 | xchg si, di ; ES:DI now points buffer |
---|
[169] | 100 | |
---|
[363] | 101 | ; Increment number of successfully read sectors |
---|
| 102 | mov cx, [bp+PIOVARS.wSectorsInBlock] |
---|
| 103 | sub [bp+PIOVARS.bSectorsLeft], cl |
---|
| 104 | add [bp+PIOVARS.bSectorsDone], cl |
---|
[242] | 105 | jmp SHORT .ReadNextBlockFromDrive |
---|
[150] | 106 | |
---|
| 107 | ALIGN JUMP_ALIGN |
---|
[242] | 108 | .ReadLastBlockFromDrive: |
---|
[363] | 109 | mov cl, [bp+PIOVARS.bSectorsLeft] ; CH is already zero |
---|
[419] | 110 | push cx |
---|
[150] | 111 | call [bp+PIOVARS.fnXfer] ; Transfer possibly partial block |
---|
| 112 | |
---|
[242] | 113 | ; Check for errors in last block |
---|
| 114 | mov di, si ; DS:DI now points DPT |
---|
| 115 | CheckErrorsAfterTransferringLastBlock: |
---|
[417] | 116 | mov bx, TIMEOUT_AND_STATUS_TO_WAIT(TIMEOUT_DRQ, FLG_STATUS_BSY) |
---|
[242] | 117 | call IdeWait_PollStatusFlagInBLwithTimeoutInBH |
---|
[419] | 118 | pop cx ; [bp+PIOVARS.bSectorsLeft] |
---|
| 119 | jc SHORT ReturnWithTransferErrorInAH |
---|
[150] | 120 | |
---|
[445] | 121 | ; All sectors successfully transferred |
---|
[419] | 122 | add cx, [bp+PIOVARS.bSectorsDone] ; Never sets CF |
---|
| 123 | ret |
---|
| 124 | |
---|
[242] | 125 | ; Return number of successfully read sectors |
---|
| 126 | ReturnWithTransferErrorInAH: |
---|
[370] | 127 | %ifdef USE_386 |
---|
| 128 | movzx cx, [bp+PIOVARS.bSectorsDone] |
---|
| 129 | %else |
---|
[363] | 130 | mov cl, [bp+PIOVARS.bSectorsDone] |
---|
| 131 | mov ch, 0 ; Preserve CF |
---|
[370] | 132 | %endif |
---|
[242] | 133 | ret |
---|
| 134 | |
---|
| 135 | |
---|
[150] | 136 | ;-------------------------------------------------------------------- |
---|
[242] | 137 | ; WriteToDrive |
---|
[150] | 138 | ; Parameters: |
---|
[242] | 139 | ; AH: Number of sectors to transfer (1...128) |
---|
| 140 | ; DS:DI: Ptr to DPT (in RAMVARS segment) |
---|
| 141 | ; ES:SI: Normalized ptr to buffer containing data |
---|
[150] | 142 | ; SS:BP: Ptr to PIOVARS |
---|
| 143 | ; Returns: |
---|
| 144 | ; AH: BIOS Error code |
---|
[218] | 145 | ; CX: Number of successfully transferred sectors |
---|
[294] | 146 | ; CF: 0 if transfer successful |
---|
[150] | 147 | ; 1 if any error |
---|
| 148 | ; Corrupts registers: |
---|
[218] | 149 | ; AL, BX, DX, SI, ES |
---|
[150] | 150 | ;-------------------------------------------------------------------- |
---|
| 151 | ALIGN JUMP_ALIGN |
---|
[242] | 152 | WriteToDrive: |
---|
| 153 | ; Prepare to write data from ESSI |
---|
| 154 | mov bx, g_rgfnPioWrite |
---|
| 155 | call InitializePiovarsInSSBPwithSectorCountInAH |
---|
| 156 | |
---|
| 157 | ; Always poll when writing first block (IRQs are generated for following blocks) |
---|
| 158 | mov bx, TIMEOUT_AND_STATUS_TO_WAIT(TIMEOUT_DRQ, FLG_STATUS_DRQ) |
---|
| 159 | call IdeWait_PollStatusFlagInBLwithTimeoutInBH |
---|
[218] | 160 | jc SHORT ReturnWithTransferErrorInAH |
---|
[150] | 161 | |
---|
[363] | 162 | mov cx, [bp+PIOVARS.wSectorsInBlock] ; Max 128 |
---|
[242] | 163 | |
---|
[218] | 164 | ALIGN JUMP_ALIGN |
---|
[242] | 165 | .WriteNextBlockToDrive: |
---|
[150] | 166 | mov dx, [bp+PIOVARS.wDataPort] |
---|
[363] | 167 | cmp [bp+PIOVARS.bSectorsLeft], cl |
---|
[242] | 168 | jbe SHORT .WriteLastBlockToDrive |
---|
[218] | 169 | call [bp+PIOVARS.fnXfer] |
---|
[169] | 170 | |
---|
[218] | 171 | ; Wait until ready for next block and check for errors |
---|
| 172 | call IdeWait_IRQorDRQ ; Wait until ready to transfer |
---|
| 173 | jc SHORT ReturnWithTransferErrorInAH |
---|
[150] | 174 | |
---|
[363] | 175 | ; Increment number of successfully written sectors |
---|
| 176 | mov cx, [bp+PIOVARS.wSectorsInBlock] |
---|
| 177 | sub [bp+PIOVARS.bSectorsLeft], cl |
---|
| 178 | add [bp+PIOVARS.bSectorsDone], cl |
---|
[242] | 179 | jmp SHORT .WriteNextBlockToDrive |
---|
[169] | 180 | |
---|
[150] | 181 | ALIGN JUMP_ALIGN |
---|
[242] | 182 | .WriteLastBlockToDrive: |
---|
[363] | 183 | mov cl, [bp+PIOVARS.bSectorsLeft] ; CH is already zero |
---|
[419] | 184 | push cx |
---|
[242] | 185 | %ifdef USE_186 |
---|
| 186 | push CheckErrorsAfterTransferringLastBlock |
---|
| 187 | jmp [bp+PIOVARS.fnXfer] ; Transfer possibly partial block |
---|
| 188 | %else |
---|
[150] | 189 | call [bp+PIOVARS.fnXfer] ; Transfer possibly partial block |
---|
[242] | 190 | jmp SHORT CheckErrorsAfterTransferringLastBlock |
---|
| 191 | %endif |
---|
[218] | 192 | |
---|
[150] | 193 | |
---|
| 194 | ;-------------------------------------------------------------------- |
---|
[218] | 195 | ; InitializePiovarsInSSBPwithSectorCountInAH |
---|
[150] | 196 | ; Parameters: |
---|
[218] | 197 | ; AH: Number of sectors to transfer (1...128) |
---|
[150] | 198 | ; BX: Offset to transfer function lookup table |
---|
| 199 | ; DS:DI: Ptr to DPT (in RAMVARS segment) |
---|
[169] | 200 | ; SS:BP: Ptr to PIOVARS |
---|
[167] | 201 | ; Returns: |
---|
[169] | 202 | ; Nothing |
---|
[150] | 203 | ; Corrupts registers: |
---|
[242] | 204 | ; AX, BX, DX |
---|
[150] | 205 | ;-------------------------------------------------------------------- |
---|
| 206 | ALIGN JUMP_ALIGN |
---|
[218] | 207 | InitializePiovarsInSSBPwithSectorCountInAH: |
---|
| 208 | ; Store sizes |
---|
[363] | 209 | mov [bp+PIOVARS.bSectorsLeft], ah |
---|
[370] | 210 | eMOVZX ax, [di+DPT_ATA.bBlockSize] |
---|
[363] | 211 | mov [bp+PIOVARS.wSectorsInBlock], ax |
---|
| 212 | mov [bp+PIOVARS.bSectorsDone], ah ; Zero |
---|
[150] | 213 | |
---|
| 214 | ; Get transfer function based on bus type |
---|
[158] | 215 | xchg ax, bx ; Lookup table offset to AX |
---|
[242] | 216 | mov bl, [di+DPT.bIdevarsOffset] ; CS:BX now points to IDEVARS |
---|
[150] | 217 | mov dx, [cs:bx+IDEVARS.wPort] ; Load IDE Data port address |
---|
[400] | 218 | mov bl, [di+DPT_ATA.bDevice] |
---|
[150] | 219 | add bx, ax |
---|
[363] | 220 | |
---|
[242] | 221 | mov [bp+PIOVARS.wDataPort], dx |
---|
[150] | 222 | mov ax, [cs:bx] ; Load offset to transfer function |
---|
| 223 | mov [bp+PIOVARS.fnXfer], ax |
---|
| 224 | ret |
---|
| 225 | |
---|
| 226 | |
---|
| 227 | ;-------------------------------------------------------------------- |
---|
[361] | 228 | ; ReadBlockFromXtideRev1 XTIDE rev 1 |
---|
| 229 | ; ReadBlockFromXtideRev2 XTIDE rev 2 or rev 1 with swapped A0 and A3 (chuck-mod) |
---|
[444] | 230 | ; ReadBlockFrom8bitDataPort CF-XT when using 8-bit PIO |
---|
[361] | 231 | ; ReadBlockFrom16bitDataPort Normal 16-bit IDE |
---|
| 232 | ; ReadBlockFrom32bitDataPort VLB/PCI 32-bit IDE |
---|
[150] | 233 | ; Parameters: |
---|
[363] | 234 | ; CX: Block size in 512 byte sectors |
---|
[150] | 235 | ; DX: IDE Data port address |
---|
[242] | 236 | ; ES:DI: Normalized ptr to buffer to receive data |
---|
[150] | 237 | ; Returns: |
---|
| 238 | ; Nothing |
---|
| 239 | ; Corrupts registers: |
---|
| 240 | ; AX, BX, CX |
---|
| 241 | ;-------------------------------------------------------------------- |
---|
[400] | 242 | %ifdef MODULE_8BIT_IDE |
---|
| 243 | |
---|
[444] | 244 | ALIGN JUMP_ALIGN |
---|
| 245 | ReadBlockFromXtideRev1: |
---|
[445] | 246 | UNROLL_SECTORS_IN_CX_TO_OWORDS |
---|
[444] | 247 | mov bl, 8 ; Bit mask for toggling data low/high reg |
---|
| 248 | ALIGN JUMP_ALIGN |
---|
| 249 | .InswLoop: |
---|
[445] | 250 | %rep 8 ; WORDs |
---|
[444] | 251 | XTIDE_INSW |
---|
[445] | 252 | %endrep |
---|
[444] | 253 | loop .InswLoop |
---|
| 254 | ret |
---|
[150] | 255 | |
---|
[444] | 256 | ;-------------------------------------------------------------------- |
---|
| 257 | %ifndef USE_186 ; 8086/8088 compatible WORD read |
---|
| 258 | ALIGN JUMP_ALIGN |
---|
| 259 | ReadBlockFromXtideRev2: |
---|
[445] | 260 | UNROLL_SECTORS_IN_CX_TO_OWORDS |
---|
[444] | 261 | ALIGN JUMP_ALIGN |
---|
[445] | 262 | .ReadNextOword: |
---|
| 263 | %rep 8 ; WORDs |
---|
| 264 | in ax, dx ; Read WORD |
---|
| 265 | stosw ; Store WORD to [ES:DI] |
---|
| 266 | %endrep |
---|
| 267 | loop .ReadNextOword |
---|
[444] | 268 | ret |
---|
| 269 | %endif |
---|
[150] | 270 | |
---|
[444] | 271 | ;-------------------------------------------------------------------- |
---|
| 272 | %ifdef USE_186 |
---|
| 273 | ALIGN JUMP_ALIGN |
---|
| 274 | ReadBlockFrom8bitDataPort: |
---|
| 275 | shl cx, 9 ; Sectors to BYTEs |
---|
| 276 | rep insb |
---|
| 277 | ret |
---|
[442] | 278 | |
---|
[444] | 279 | %else ; If 8088/8086 |
---|
[445] | 280 | ALIGN JUMP_ALIGN |
---|
[444] | 281 | ReadBlockFrom8bitDataPort: |
---|
[445] | 282 | UNROLL_SECTORS_IN_CX_TO_OWORDS |
---|
[444] | 283 | ALIGN JUMP_ALIGN |
---|
[445] | 284 | .ReadNextOword: |
---|
| 285 | %rep 16 ; BYTEs |
---|
| 286 | in al, dx ; Read BYTE |
---|
| 287 | stosb ; Store BYTE to [ES:DI] |
---|
| 288 | %endrep |
---|
| 289 | loop .ReadNextOword |
---|
[444] | 290 | ret |
---|
| 291 | %endif |
---|
[400] | 292 | %endif ; MODULE_8BIT_IDE |
---|
| 293 | |
---|
[361] | 294 | ;-------------------------------------------------------------------- |
---|
[401] | 295 | %ifdef USE_186 |
---|
[444] | 296 | ALIGN JUMP_ALIGN |
---|
| 297 | ReadBlockFrom16bitDataPort: |
---|
| 298 | xchg cl, ch ; Sectors to WORDs |
---|
| 299 | rep insw |
---|
| 300 | ret |
---|
[401] | 301 | %endif |
---|
[152] | 302 | |
---|
[361] | 303 | ;-------------------------------------------------------------------- |
---|
[401] | 304 | %ifdef USE_AT |
---|
[444] | 305 | ALIGN JUMP_ALIGN |
---|
| 306 | ReadBlockFrom32bitDataPort: |
---|
| 307 | shl cx, 7 ; Sectors to DWORDs |
---|
| 308 | rep |
---|
| 309 | db 66h ; Override operand size to 32-bit |
---|
| 310 | db 6Dh ; INSW/INSD |
---|
| 311 | ret |
---|
[401] | 312 | %endif |
---|
[152] | 313 | |
---|
| 314 | |
---|
[150] | 315 | ;-------------------------------------------------------------------- |
---|
[361] | 316 | ; WriteBlockToXtideRev1 XTIDE rev 1 |
---|
| 317 | ; WriteBlockToXtideRev2 XTIDE rev 2 or rev 1 with swapped A0 and A3 (chuck-mod) |
---|
[444] | 318 | ; WriteBlockTo8bitDataPort XT-CF when using 8-bit PIO |
---|
[361] | 319 | ; WriteBlockTo16bitDataPort Normal 16-bit IDE |
---|
| 320 | ; WriteBlockTo32bitDataPort VLB/PCI 32-bit IDE |
---|
[150] | 321 | ; Parameters: |
---|
[363] | 322 | ; CX: Block size in 512-byte sectors |
---|
[150] | 323 | ; DX: IDE Data port address |
---|
| 324 | ; ES:SI: Normalized ptr to buffer containing data |
---|
| 325 | ; Returns: |
---|
| 326 | ; Nothing |
---|
| 327 | ; Corrupts registers: |
---|
[417] | 328 | ; AX, BX, CX, DX |
---|
[150] | 329 | ;-------------------------------------------------------------------- |
---|
[400] | 330 | %ifdef MODULE_8BIT_IDE |
---|
| 331 | |
---|
[444] | 332 | ALIGN JUMP_ALIGN |
---|
| 333 | WriteBlockToXtideRev1: |
---|
| 334 | push ds |
---|
| 335 | UNROLL_SECTORS_IN_CX_TO_QWORDS |
---|
| 336 | mov bl, 8 ; Bit mask for toggling data low/high reg |
---|
| 337 | push es ; Copy ES... |
---|
| 338 | pop ds ; ...to DS |
---|
| 339 | ALIGN JUMP_ALIGN |
---|
| 340 | .OutswLoop: |
---|
[445] | 341 | %rep 4 ; WORDs |
---|
[444] | 342 | XTIDE_OUTSW |
---|
[445] | 343 | %endrep |
---|
[444] | 344 | loop .OutswLoop |
---|
| 345 | pop ds |
---|
| 346 | ret |
---|
[150] | 347 | |
---|
[444] | 348 | ;-------------------------------------------------------------------- |
---|
| 349 | ALIGN JUMP_ALIGN |
---|
| 350 | WriteBlockToXtideRev2: |
---|
| 351 | UNROLL_SECTORS_IN_CX_TO_QWORDS |
---|
| 352 | push ds |
---|
| 353 | push es ; Copy ES... |
---|
| 354 | pop ds ; ...to DS |
---|
| 355 | ALIGN JUMP_ALIGN |
---|
| 356 | .WriteNextQword: |
---|
[445] | 357 | %rep 4 ; WORDs |
---|
[444] | 358 | XTIDE_MOD_OUTSW |
---|
[445] | 359 | %endrep |
---|
[444] | 360 | loop .WriteNextQword |
---|
| 361 | pop ds |
---|
| 362 | ret |
---|
[150] | 363 | |
---|
[444] | 364 | ;-------------------------------------------------------------------- |
---|
| 365 | %ifdef USE_186 |
---|
| 366 | ALIGN JUMP_ALIGN |
---|
| 367 | WriteBlockTo8bitDataPort: |
---|
| 368 | shl cx, 9 ; Sectors to BYTEs |
---|
| 369 | es ; Source is ES segment |
---|
| 370 | rep outsb |
---|
| 371 | ret |
---|
[442] | 372 | |
---|
[444] | 373 | %else ; If 8088/8086 |
---|
| 374 | ALIGN JUMP_ALIGN |
---|
| 375 | WriteBlockTo8bitDataPort: |
---|
| 376 | UNROLL_SECTORS_IN_CX_TO_DWORDS |
---|
| 377 | push ds |
---|
| 378 | push es |
---|
| 379 | pop ds |
---|
| 380 | ALIGN JUMP_ALIGN |
---|
| 381 | .WriteNextDword: |
---|
[445] | 382 | %rep 4 ; BYTEs |
---|
| 383 | lodsb ; Load BYTE from [DS:SI] |
---|
| 384 | out dx, al ; Write BYTE |
---|
| 385 | %endrep |
---|
[444] | 386 | loop .WriteNextDword |
---|
| 387 | pop ds |
---|
| 388 | ret |
---|
| 389 | %endif |
---|
[400] | 390 | %endif ; MODULE_8BIT_IDE |
---|
| 391 | |
---|
[361] | 392 | ;-------------------------------------------------------------------- |
---|
[402] | 393 | %ifdef USE_AT |
---|
[361] | 394 | ALIGN JUMP_ALIGN |
---|
| 395 | WriteBlockTo16bitDataPort: |
---|
[363] | 396 | xchg cl, ch ; Sectors to WORDs |
---|
[223] | 397 | es ; Source is ES segment |
---|
[444] | 398 | rep outsw |
---|
[152] | 399 | ret |
---|
| 400 | |
---|
[361] | 401 | ;-------------------------------------------------------------------- |
---|
[152] | 402 | ALIGN JUMP_ALIGN |
---|
[361] | 403 | WriteBlockTo32bitDataPort: |
---|
[444] | 404 | shl cx, 7 ; Sectors to DWORDs |
---|
[223] | 405 | es ; Source is ES segment |
---|
[152] | 406 | rep |
---|
| 407 | db 66h ; Override operand size to 32-bit |
---|
| 408 | db 6Fh ; OUTSW/OUTSD |
---|
| 409 | ret |
---|
[421] | 410 | %endif ; USE_AT |
---|
[152] | 411 | |
---|
| 412 | |
---|
[361] | 413 | |
---|
[150] | 414 | ; Lookup tables to get transfer function based on bus type |
---|
| 415 | ALIGN WORD_ALIGN |
---|
| 416 | g_rgfnPioRead: |
---|
[400] | 417 | %ifdef MODULE_8BIT_IDE |
---|
[401] | 418 | dw 0 ; 0, DEVICE_8BIT_JRIDE_ISA |
---|
[444] | 419 | dw ReadBlockFrom8bitDataPort ; 1, DEVICE_8BIT_XTCF |
---|
[400] | 420 | %ifdef USE_186 |
---|
[401] | 421 | dw ReadBlockFrom16bitDataPort ; 2, DEVICE_8BIT_XTIDE_REV2 |
---|
[400] | 422 | %else |
---|
[401] | 423 | dw ReadBlockFromXtideRev2 ; 2, DEVICE_8BIT_XTIDE_REV2 |
---|
[400] | 424 | %endif |
---|
[401] | 425 | dw ReadBlockFromXtideRev1 ; 3, DEVICE_XTIDE_REV1 |
---|
[400] | 426 | |
---|
[152] | 427 | %else |
---|
[400] | 428 | times COUNT_OF_8BIT_IDE_DEVICES dw 0 |
---|
[152] | 429 | %endif |
---|
[401] | 430 | %ifdef USE_AT |
---|
| 431 | dw ReadBlockFrom16bitDataPort ; 4, DEVICE_16BIT_ATA |
---|
| 432 | dw ReadBlockFrom32bitDataPort ; 5, DEVICE_32BIT_ATA |
---|
| 433 | %endif |
---|
[152] | 434 | |
---|
[400] | 435 | |
---|
[150] | 436 | g_rgfnPioWrite: |
---|
[400] | 437 | %ifdef MODULE_8BIT_IDE |
---|
[401] | 438 | dw 0 ; 0, DEVICE_8BIT_JRIDE_ISA |
---|
[444] | 439 | dw WriteBlockTo8bitDataPort ; 1, DEVICE_8BIT_XTCF |
---|
[401] | 440 | dw WriteBlockToXtideRev2 ; 2, DEVICE_XTIDE_REV2 |
---|
| 441 | dw WriteBlockToXtideRev1 ; 3, DEVICE_XTIDE_REV1 |
---|
[400] | 442 | |
---|
[361] | 443 | %else |
---|
[400] | 444 | times COUNT_OF_8BIT_IDE_DEVICES dw 0 |
---|
[361] | 445 | %endif |
---|
[401] | 446 | %ifdef USE_AT |
---|
| 447 | dw WriteBlockTo16bitDataPort ; 4, DEVICE_16BIT_ATA |
---|
| 448 | dw WriteBlockTo32bitDataPort ; 5, DEVICE_32BIT_ATA |
---|
| 449 | %endif |
---|