Context Navigation

source: xtideuniversalbios/trunk/XTIDE_Universal_BIOS/Src/Device/IDE/IdeTransfer.asm@ 439

Visit:

Last change on this file since 439 was 421, checked in by aitotat@…, 13 years ago

Changes to XTIDE Universal BIOS:

Addressing modes are now NORMAL, LARGE and LBA.
L-CHS parameters are now generated differently for drives with 8192 or less cylinders.

File size: 12.7 KB

Rev	Line
[150]	1	; Project name : XTIDE Universal BIOS
	2	; Description : IDE Device transfer functions.
	3
[376]	4	;
	5	; XTIDE Universal BIOS and Associated Tools
	6	; Copyright (C) 2009-2010 by Tomi Tilli, 2011-2012 by XTIDE Universal BIOS Team.
	7	;
	8	; This program is free software; you can redistribute it and/or modify
	9	; it under the terms of the GNU General Public License as published by
	10	; the Free Software Foundation; either version 2 of the License, or
	11	; (at your option) any later version.
	12	;
	13	; This program is distributed in the hope that it will be useful,
	14	; but WITHOUT ANY WARRANTY; without even the implied warranty of
	15	; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
	16	; GNU General Public License for more details.
	17	; Visit http://www.gnu.org/licenses/old-licenses/gpl-2.0.html
	18	;
	19
[150]	20	; Structure containing variables for PIO transfer functions.
	21	; This struct must not be larger than IDEPACK without INTPACK.
[414]	22	struc PIOVARS ; Must not be larger than 9 bytes! See IDEPACK in RamVars.inc.
	23	.wDataPort resb 2 ; 0-1, IDE Data Port
	24	.fnXfer resb 2 ; 2-3, Offset to transfer function
	25	.wSectorsInBlock resb 2 ; 4-5, Block size in sectors
[363]	26	.bSectorsLeft resb 1 ; 6, Sectors left to transfer
[218]	27	resb 1 ; 7, IDEPACK.bDeviceControl
[363]	28	.bSectorsDone resb 1 ; 8, Number of sectors xferred
[150]	29	endstruc
	30
	31
	32	; Section containing code
	33	SECTION .text
	34
	35	;--------------------------------------------------------------------
	36	; IdeTransfer_StartWithCommandInAL
	37	; Parameters:
	38	; AL: IDE command that was used to start the transfer
[171]	39	; (all PIO read and write commands including Identify Device)
[218]	40	; ES:SI: Ptr to normalized data buffer
[150]	41	; DS:DI: Ptr to DPT (in RAMVARS segment)
	42	; SS:BP: Ptr to IDEPACK
	43	; Returns:
	44	; AH: INT 13h Error Code
[218]	45	; CX: Number of successfully transferred sectors
[150]	46	; CF: Cleared if success, Set if error
	47	; Corrupts registers:
[218]	48	; AL, BX, DX, SI, ES
[150]	49	;--------------------------------------------------------------------
	50	ALIGN JUMP_ALIGN
	51	IdeTransfer_StartWithCommandInAL:
[157]	52	; Are we reading or writing?
[171]	53	test al, 16 ; Bit 4 is cleared on all the read commands but set on 3 of the 4 write commands
[242]	54	mov ah, [bp+IDEPACK.bSectorCount]
	55	jnz SHORT WriteToDrive
[171]	56	cmp al, COMMAND_WRITE_MULTIPLE
[242]	57	je SHORT WriteToDrive
	58	; Fall to ReadFromDrive
[150]	59
	60	;--------------------------------------------------------------------
[242]	61	; ReadFromDrive
[150]	62	; Parameters:
[242]	63	; AH: Number of sectors to transfer (1...128)
	64	; ES:SI: Normalized ptr to buffer to receive data
[150]	65	; DS:DI: Ptr to DPT (in RAMVARS segment)
	66	; SS:BP: Ptr to PIOVARS
	67	; Returns:
[242]	68	; DS:DI: Ptr to DPT (in RAMVARS segment)
[150]	69	; AH: BIOS Error code
[218]	70	; CX: Number of successfully transferred sectors
[294]	71	; CF: 0 if transfer successful
[150]	72	; 1 if any error
	73	; Corrupts registers:
[218]	74	; AL, BX, DX, SI, ES
[150]	75	;--------------------------------------------------------------------
[242]	76	ReadFromDrive:
	77	; Prepare to read data to ESSI
	78	mov bx, g_rgfnPioRead
	79	call InitializePiovarsInSSBPwithSectorCountInAH
	80
	81	; Wait until drive is ready to transfer
	82	call IdeWait_IRQorDRQ ; Wait until ready to transfer
[218]	83	jc SHORT ReturnWithTransferErrorInAH
[242]	84	xchg si, di ; ES:DI now points buffer
[218]	85
[363]	86	mov cx, [bp+PIOVARS.wSectorsInBlock] ; Max 128
[242]	87
[150]	88	ALIGN JUMP_ALIGN
[242]	89	.ReadNextBlockFromDrive:
[150]	90	mov dx, [bp+PIOVARS.wDataPort]
[363]	91	cmp [bp+PIOVARS.bSectorsLeft], cl
[242]	92	jbe SHORT .ReadLastBlockFromDrive
[218]	93	call [bp+PIOVARS.fnXfer]
[169]	94
[218]	95	; Wait until ready for next block and check for errors
[242]	96	xchg di, si ; DS:DI now points DPT
[218]	97	call IdeWait_IRQorDRQ ; Wait until ready to transfer
	98	jc SHORT ReturnWithTransferErrorInAH
[242]	99	xchg si, di ; ES:DI now points buffer
[169]	100
[363]	101	; Increment number of successfully read sectors
	102	mov cx, [bp+PIOVARS.wSectorsInBlock]
	103	sub [bp+PIOVARS.bSectorsLeft], cl
	104	add [bp+PIOVARS.bSectorsDone], cl
[242]	105	jmp SHORT .ReadNextBlockFromDrive
[150]	106
	107	ALIGN JUMP_ALIGN
[242]	108	.ReadLastBlockFromDrive:
[363]	109	mov cl, [bp+PIOVARS.bSectorsLeft] ; CH is already zero
[419]	110	push cx
[150]	111	call [bp+PIOVARS.fnXfer] ; Transfer possibly partial block
	112
[242]	113	; Check for errors in last block
	114	mov di, si ; DS:DI now points DPT
	115	CheckErrorsAfterTransferringLastBlock:
[417]	116	mov bx, TIMEOUT_AND_STATUS_TO_WAIT(TIMEOUT_DRQ, FLG_STATUS_BSY)
[242]	117	call IdeWait_PollStatusFlagInBLwithTimeoutInBH
[419]	118	pop cx ; [bp+PIOVARS.bSectorsLeft]
	119	jc SHORT ReturnWithTransferErrorInAH
[150]	120
[421]	121	; All sectors succesfully transferred
[419]	122	add cx, [bp+PIOVARS.bSectorsDone] ; Never sets CF
	123	ret
	124
[242]	125	; Return number of successfully read sectors
	126	ReturnWithTransferErrorInAH:
[370]	127	%ifdef USE_386
	128	movzx cx, [bp+PIOVARS.bSectorsDone]
	129	%else
[363]	130	mov cl, [bp+PIOVARS.bSectorsDone]
	131	mov ch, 0 ; Preserve CF
[370]	132	%endif
[242]	133	ret
	134
	135
[150]	136	;--------------------------------------------------------------------
[242]	137	; WriteToDrive
[150]	138	; Parameters:
[242]	139	; AH: Number of sectors to transfer (1...128)
	140	; DS:DI: Ptr to DPT (in RAMVARS segment)
	141	; ES:SI: Normalized ptr to buffer containing data
[150]	142	; SS:BP: Ptr to PIOVARS
	143	; Returns:
	144	; AH: BIOS Error code
[218]	145	; CX: Number of successfully transferred sectors
[294]	146	; CF: 0 if transfer successful
[150]	147	; 1 if any error
	148	; Corrupts registers:
[218]	149	; AL, BX, DX, SI, ES
[150]	150	;--------------------------------------------------------------------
	151	ALIGN JUMP_ALIGN
[242]	152	WriteToDrive:
	153	; Prepare to write data from ESSI
	154	mov bx, g_rgfnPioWrite
	155	call InitializePiovarsInSSBPwithSectorCountInAH
	156
	157	; Always poll when writing first block (IRQs are generated for following blocks)
	158	mov bx, TIMEOUT_AND_STATUS_TO_WAIT(TIMEOUT_DRQ, FLG_STATUS_DRQ)
	159	call IdeWait_PollStatusFlagInBLwithTimeoutInBH
[218]	160	jc SHORT ReturnWithTransferErrorInAH
[150]	161
[363]	162	mov cx, [bp+PIOVARS.wSectorsInBlock] ; Max 128
[242]	163
[218]	164	ALIGN JUMP_ALIGN
[242]	165	.WriteNextBlockToDrive:
[150]	166	mov dx, [bp+PIOVARS.wDataPort]
[363]	167	cmp [bp+PIOVARS.bSectorsLeft], cl
[242]	168	jbe SHORT .WriteLastBlockToDrive
[218]	169	call [bp+PIOVARS.fnXfer]
[169]	170
[218]	171	; Wait until ready for next block and check for errors
	172	call IdeWait_IRQorDRQ ; Wait until ready to transfer
	173	jc SHORT ReturnWithTransferErrorInAH
[150]	174
[363]	175	; Increment number of successfully written sectors
	176	mov cx, [bp+PIOVARS.wSectorsInBlock]
	177	sub [bp+PIOVARS.bSectorsLeft], cl
	178	add [bp+PIOVARS.bSectorsDone], cl
[242]	179	jmp SHORT .WriteNextBlockToDrive
[169]	180
[150]	181	ALIGN JUMP_ALIGN
[242]	182	.WriteLastBlockToDrive:
[363]	183	mov cl, [bp+PIOVARS.bSectorsLeft] ; CH is already zero
[419]	184	push cx
[242]	185	%ifdef USE_186
	186	push CheckErrorsAfterTransferringLastBlock
	187	jmp [bp+PIOVARS.fnXfer] ; Transfer possibly partial block
	188	%else
[150]	189	call [bp+PIOVARS.fnXfer] ; Transfer possibly partial block
[242]	190	jmp SHORT CheckErrorsAfterTransferringLastBlock
	191	%endif
[218]	192
[150]	193
	194	;--------------------------------------------------------------------
[218]	195	; InitializePiovarsInSSBPwithSectorCountInAH
[150]	196	; Parameters:
[218]	197	; AH: Number of sectors to transfer (1...128)
[150]	198	; BX: Offset to transfer function lookup table
	199	; DS:DI: Ptr to DPT (in RAMVARS segment)
[169]	200	; SS:BP: Ptr to PIOVARS
[167]	201	; Returns:
[169]	202	; Nothing
[150]	203	; Corrupts registers:
[242]	204	; AX, BX, DX
[150]	205	;--------------------------------------------------------------------
	206	ALIGN JUMP_ALIGN
[218]	207	InitializePiovarsInSSBPwithSectorCountInAH:
	208	; Store sizes
[363]	209	mov [bp+PIOVARS.bSectorsLeft], ah
[370]	210	eMOVZX ax, [di+DPT_ATA.bBlockSize]
[363]	211	mov [bp+PIOVARS.wSectorsInBlock], ax
	212	mov [bp+PIOVARS.bSectorsDone], ah ; Zero
[150]	213
	214	; Get transfer function based on bus type
[158]	215	xchg ax, bx ; Lookup table offset to AX
[242]	216	mov bl, [di+DPT.bIdevarsOffset] ; CS:BX now points to IDEVARS
[150]	217	mov dx, [cs:bx+IDEVARS.wPort] ; Load IDE Data port address
[400]	218	mov bl, [di+DPT_ATA.bDevice]
[150]	219	add bx, ax
[363]	220
[242]	221	mov [bp+PIOVARS.wDataPort], dx
[150]	222	mov ax, [cs:bx] ; Load offset to transfer function
	223	mov [bp+PIOVARS.fnXfer], ax
	224	ret
	225
	226
	227	;--------------------------------------------------------------------
[361]	228	; ReadBlockFromXtideRev1 XTIDE rev 1
	229	; ReadBlockFromXtideRev2 XTIDE rev 2 or rev 1 with swapped A0 and A3 (chuck-mod)
	230	; ReadBlockFrom16bitDataPort Normal 16-bit IDE
	231	; ReadBlockFrom32bitDataPort VLB/PCI 32-bit IDE
[150]	232	; Parameters:
[363]	233	; CX: Block size in 512 byte sectors
[150]	234	; DX: IDE Data port address
[242]	235	; ES:DI: Normalized ptr to buffer to receive data
[150]	236	; Returns:
	237	; Nothing
	238	; Corrupts registers:
	239	; AX, BX, CX
	240	;--------------------------------------------------------------------
[400]	241	%ifdef MODULE_8BIT_IDE
	242
[150]	243	ALIGN JUMP_ALIGN
[361]	244	ReadBlockFromXtideRev1:
[363]	245	UNROLL_SECTORS_IN_CX_TO_QWORDS
[370]	246	mov bl, 8 ; Bit mask for toggling data low/high reg
[150]	247	ALIGN JUMP_ALIGN
	248	.InswLoop:
[152]	249	XTIDE_INSW
	250	XTIDE_INSW
	251	XTIDE_INSW
	252	XTIDE_INSW
[150]	253	loop .InswLoop
	254	ret
	255
[361]	256	;--------------------------------------------------------------------
	257	%ifndef USE_186 ; 8086/8088 compatible WORD read
[150]	258	ALIGN JUMP_ALIGN
[361]	259	ReadBlockFromXtideRev2:
[363]	260	UNROLL_SECTORS_IN_CX_TO_QWORDS
[152]	261	ALIGN JUMP_ALIGN
	262	.ReadNextQword:
	263	in ax, dx ; Read 1st WORD
	264	stosw ; Store 1st WORD to [ES:DI]
	265	in ax, dx
	266	stosw ; 2nd
	267	in ax, dx
	268	stosw ; 3rd
	269	in ax, dx
	270	stosw ; 4th
	271	loop .ReadNextQword
	272	ret
	273	%endif
[150]	274
[400]	275	%endif ; MODULE_8BIT_IDE
	276
[361]	277	;--------------------------------------------------------------------
[401]	278	%ifdef USE_186
[152]	279	ALIGN JUMP_ALIGN
[361]	280	ReadBlockFrom16bitDataPort:
[363]	281	xchg cl, ch ; Sectors to WORDs
[152]	282	rep
	283	db 6Dh ; INSW (we want this in XT build)
	284	ret
[401]	285	%endif
[152]	286
[361]	287	;--------------------------------------------------------------------
[401]	288	%ifdef USE_AT
[152]	289	ALIGN JUMP_ALIGN
[361]	290	ReadBlockFrom32bitDataPort:
[363]	291	db 0C1h ; SHL
	292	db 0E1h ; CX
	293	db 7 ; 7 (Sectors to DWORDs)
[152]	294	rep
	295	db 66h ; Override operand size to 32-bit
	296	db 6Dh ; INSW/INSD
	297	ret
[401]	298	%endif
[152]	299
	300
[150]	301	;--------------------------------------------------------------------
[361]	302	; WriteBlockToXtideRev1 XTIDE rev 1
	303	; WriteBlockToXtideRev2 XTIDE rev 2 or rev 1 with swapped A0 and A3 (chuck-mod)
	304	; WriteBlockToFastXtide Fast XTIDE (CPLD v2 project)
	305	; WriteBlockTo16bitDataPort Normal 16-bit IDE
	306	; WriteBlockTo32bitDataPort VLB/PCI 32-bit IDE
[150]	307	; Parameters:
[363]	308	; CX: Block size in 512-byte sectors
[150]	309	; DX: IDE Data port address
	310	; ES:SI: Normalized ptr to buffer containing data
	311	; Returns:
	312	; Nothing
	313	; Corrupts registers:
[417]	314	; AX, BX, CX, DX
[150]	315	;--------------------------------------------------------------------
[400]	316	%ifdef MODULE_8BIT_IDE
	317
[150]	318	ALIGN JUMP_ALIGN
[361]	319	WriteBlockToXtideRev1:
[150]	320	push ds
[363]	321	UNROLL_SECTORS_IN_CX_TO_QWORDS
[370]	322	mov bl, 8 ; Bit mask for toggling data low/high reg
[152]	323	push es ; Copy ES...
	324	pop ds ; ...to DS
[150]	325	ALIGN JUMP_ALIGN
	326	.OutswLoop:
[152]	327	XTIDE_OUTSW
	328	XTIDE_OUTSW
	329	XTIDE_OUTSW
	330	XTIDE_OUTSW
[150]	331	loop .OutswLoop
	332	pop ds
	333	ret
	334
[361]	335	;--------------------------------------------------------------------
[150]	336	ALIGN JUMP_ALIGN
[361]	337	WriteBlockToXtideRev2:
[363]	338	UNROLL_SECTORS_IN_CX_TO_QWORDS
[152]	339	push ds
	340	push es ; Copy ES...
	341	pop ds ; ...to DS
	342	ALIGN JUMP_ALIGN
	343	.WriteNextQword:
	344	XTIDE_MOD_OUTSW
	345	XTIDE_MOD_OUTSW
	346	XTIDE_MOD_OUTSW
	347	XTIDE_MOD_OUTSW
	348	loop .WriteNextQword
	349	pop ds
	350	ret
[150]	351
[361]	352	;--------------------------------------------------------------------
[152]	353	ALIGN JUMP_ALIGN
[361]	354	WriteBlockToFastXtide:
[363]	355	UNROLL_SECTORS_IN_CX_TO_QWORDS
[361]	356	push ds
	357	push es
	358	pop ds
[402]	359	or dl, (1<<4) ; Writes need A4 set
[361]	360	ALIGN JUMP_ALIGN
	361	.ReadNextQword:
	362	lodsw ; Load 1st WORD from [DS:SI]
	363	out dx, ax ; Write 1st WORD
	364	lodsw
	365	out dx, ax ; 2nd
	366	lodsw
	367	out dx, ax ; 3rd
	368	lodsw
	369	out dx, ax ; 4th
	370	loop .ReadNextQword
	371	pop ds
	372	ret
[400]	373	%endif ; MODULE_8BIT_IDE
	374
[421]	375
[361]	376	;--------------------------------------------------------------------
[402]	377	%ifdef USE_AT
[361]	378	ALIGN JUMP_ALIGN
	379	WriteBlockTo16bitDataPort:
[363]	380	xchg cl, ch ; Sectors to WORDs
[223]	381	es ; Source is ES segment
[152]	382	rep
[155]	383	db 6Fh ; OUTSW (we want this in XT build)
[152]	384	ret
	385
[361]	386	;--------------------------------------------------------------------
[152]	387	ALIGN JUMP_ALIGN
[361]	388	WriteBlockTo32bitDataPort:
[363]	389	db 0C1h ; SHL
	390	db 0E1h ; CX
	391	db 7 ; 7 (Sectors to DWORDs)
[223]	392	es ; Source is ES segment
[152]	393	rep
	394	db 66h ; Override operand size to 32-bit
	395	db 6Fh ; OUTSW/OUTSD
	396	ret
[421]	397	%endif ; USE_AT
[152]	398
	399
[361]	400
[150]	401	; Lookup tables to get transfer function based on bus type
	402	ALIGN WORD_ALIGN
	403	g_rgfnPioRead:
[400]	404	%ifdef MODULE_8BIT_IDE
[401]	405	dw 0 ; 0, DEVICE_8BIT_JRIDE_ISA
[400]	406	%ifdef USE_186
[401]	407	dw ReadBlockFrom16bitDataPort ; 1, DEVICE_FAST_XTIDE
	408	dw ReadBlockFrom16bitDataPort ; 2, DEVICE_8BIT_XTIDE_REV2
[400]	409	%else
[401]	410	dw ReadBlockFromXtideRev2 ; 1, DEVICE_FAST_XTIDE
	411	dw ReadBlockFromXtideRev2 ; 2, DEVICE_8BIT_XTIDE_REV2
[400]	412	%endif
[401]	413	dw ReadBlockFromXtideRev1 ; 3, DEVICE_XTIDE_REV1
[400]	414
[152]	415	%else
[400]	416	times COUNT_OF_8BIT_IDE_DEVICES dw 0
[152]	417	%endif
[401]	418	%ifdef USE_AT
	419	dw ReadBlockFrom16bitDataPort ; 4, DEVICE_16BIT_ATA
	420	dw ReadBlockFrom32bitDataPort ; 5, DEVICE_32BIT_ATA
	421	%endif
[152]	422
[400]	423
[150]	424	g_rgfnPioWrite:
[400]	425	%ifdef MODULE_8BIT_IDE
[401]	426	dw 0 ; 0, DEVICE_8BIT_JRIDE_ISA
	427	dw WriteBlockToFastXtide ; 1, DEVICE_FAST_XTIDE
	428	dw WriteBlockToXtideRev2 ; 2, DEVICE_XTIDE_REV2
	429	dw WriteBlockToXtideRev1 ; 3, DEVICE_XTIDE_REV1
[400]	430
[361]	431	%else
[400]	432	times COUNT_OF_8BIT_IDE_DEVICES dw 0
[361]	433	%endif
[401]	434	%ifdef USE_AT
	435	dw WriteBlockTo16bitDataPort ; 4, DEVICE_16BIT_ATA
	436	dw WriteBlockTo32bitDataPort ; 5, DEVICE_32BIT_ATA
	437	%endif

Note: See TracBrowser for help on using the repository browser.

Download in other formats: