source: xtideuniversalbios/trunk/XTIDE_Universal_BIOS/Src/Device/IDE/IdeDPT.asm @ 608

Last change on this file since 608 was 608, checked in by aitotat, 3 years ago

XT-CF gave false positive for PDC20x30 VLB-controller detection. Advanced controller detection is now done only for 16- and 32-bit standard IDE devices.

File size: 5.3 KB
Line 
1; Project name  :   XTIDE Universal BIOS
2; Description   :   Sets IDE Device specific parameters to DPT.
3
4;
5; XTIDE Universal BIOS and Associated Tools
6; Copyright (C) 2009-2010 by Tomi Tilli, 2011-2013 by XTIDE Universal BIOS Team.
7;
8; This program is free software; you can redistribute it and/or modify
9; it under the terms of the GNU General Public License as published by
10; the Free Software Foundation; either version 2 of the License, or
11; (at your option) any later version.
12;
13; This program is distributed in the hope that it will be useful,
14; but WITHOUT ANY WARRANTY; without even the implied warranty of
15; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
16; GNU General Public License for more details.
17; Visit http://www.gnu.org/licenses/old-licenses/gpl-2.0.html
18;
19
20; Section containing code
21SECTION .text
22
23;--------------------------------------------------------------------
24; IdeDPT_Finalize
25;   Parameters:
26;       DS:DI:  Ptr to Disk Parameter Table
27;       ES:SI:  Ptr to 512-byte ATA information read from the drive
28;       CS:BP:  Ptr to IDEVARS for the controller
29;   Returns:
30;       CF:     Clear, IDE interface only supports hard disks
31;   Corrupts registers:
32;       AX, BX, CX, DX
33;--------------------------------------------------------------------
34IdeDPT_Finalize:    ; Unused entrypoint OK
35
36%ifdef MODULE_POWER_MANAGEMENT
37;--------------------------------------------------------------------
38; .DetectPowerManagementSupport
39;   Parameters:
40;       DS:DI:  Ptr to Disk Parameter Table
41;       ES:SI:  Ptr to 512-byte ATA information read from the drive
42;   Returns:
43;       Nothing
44;   Corrupts registers:
45;       AL
46;--------------------------------------------------------------------
47.DetectPowerManagementSupport:
48    mov     al, [es:si+ATA6.wSetSup82]
49    and     al, A6_wSetSup82_POWERMAN   ; A6_wSetSup82_POWERMAN (bit 3) is the same
50    or      [di+DPT.bFlagsHigh], al     ; bit as FLGH_DPT_POWER_MANAGEMENT_SUPPORTED
51%endif ; MODULE_POWER_MANAGEMENT
52
53
54;--------------------------------------------------------------------
55; .StoreDeviceType
56;   Parameters:
57;       DS:DI:  Ptr to Disk Parameter Table
58;       CS:BP:  Ptr to IDEVARS for the controller
59;   Returns:
60;       Nothing
61;   Corrupts registers:
62;       AL
63;--------------------------------------------------------------------
64.StoreDeviceType:
65    call    IdeDPT_StoreDeviceTypeToDPTinDSDIfromIdevarsInCSBP
66
67
68;--------------------------------------------------------------------
69; .StoreBlockMode
70;   Parameters:
71;       DS:DI:  Ptr to Disk Parameter Table
72;   Returns:
73;       Nothing
74;   Corrupts registers:
75;       Nothing
76;--------------------------------------------------------------------
77.StoreBlockMode:
78    mov     BYTE [di+DPT_ATA.bBlockSize], 1
79
80
81%ifdef MODULE_ADVANCED_ATA
82;--------------------------------------------------------------------
83; .StorePioModeAndTimings
84;   Parameters:
85;       DS:DI:  Ptr to Disk Parameter Table
86;       ES:SI:  Ptr to 512-byte ATA information read from the drive
87;       CS:BP:  Ptr to IDEVARS for the controller
88;   Returns:
89;       Nothing
90;   Corrupts registers:
91;       AX, BX, CX
92;--------------------------------------------------------------------
93.StorePioMode:
94    call    AtaID_GetMaxPioModeToAXandMinCycleTimeToCX
95    mov     [di+DPT_ADVANCED_ATA.wMinPioCycleTime], cx
96    mov     [di+DPT_ADVANCED_ATA.bPioMode], al
97    or      [di+DPT.bFlagsHigh], ah
98
99
100;--------------------------------------------------------------------
101; .DetectAdvancedIdeController
102;   Parameters:
103;       DS:DI:  Ptr to Disk Parameter Table
104;       ES:SI:  Ptr to 512-byte ATA information read from the drive
105;       CS:BP:  Ptr to IDEVARS for the controller
106;   Returns:
107;       Nothing
108;   Corrupts registers:
109;       AX, BX, CX, DX
110;--------------------------------------------------------------------
111.DetectAdvancedIdeController:
112    ; Detection is only relevant on standard devices. XT-CF seems to give false positive for
113    ; PDC20x30 detection so better to skip detection for 8-bit devices
114    cmp     BYTE [di+DPT_ATA.bDevice], DEVICE_32BIT_ATA
115    ja      SHORT .NoAdvancedControllerDetected
116   
117    mov     bx, [di+DPT.wBasePort]
118    call    AdvAtaInit_DetectControllerForIdeBaseInBX
119    mov     [di+DPT_ADVANCED_ATA.wControllerID], ax ; Store zero if none detected
120    mov     [di+DPT_ADVANCED_ATA.wControllerBasePort], dx
121    jnc     SHORT .NoAdvancedControllerDetected
122
123    ; Use highest common PIO mode from controller and drive.
124    ; Many VLB controllers support PIO modes up to 2.
125    call    AdvAtaInit_GetControllerMaxPioModeToALandMinPioCycleTimeToBX
126    jnz     SHORT .ChangeTo32bitDevice
127
128    and     [di+DPT.bFlagsHigh], ah     ; Mask off FLGH_DPT_IORDY if IORDY not supported
129    MIN_U   [di+DPT_ADVANCED_ATA.bPioMode], al
130    mov     [di+DPT_ADVANCED_ATA.wMinPioCycleTime], bx
131
132    ; We have detected 32-bit controller so change Device Type since
133    ; it might have been set to 16-bit on IDEVARS
134.ChangeTo32bitDevice:
135    mov     BYTE [di+DPT_ATA.bDevice], DEVICE_32BIT_ATA
136.NoAdvancedControllerDetected:
137%endif  ; MODULE_ADVANCED_ATA
138
139
140; End DPT
141    clc
142    ret
143
144
145;--------------------------------------------------------------------
146; IdeDPT_StoreDeviceTypeToDPTinDSDIfromIdevarsInCSBP
147;   Parameters:
148;       DS:DI:  Ptr to Disk Parameter Table
149;       CS:BP:  Ptr to IDEVARS for the controller
150;   Returns:
151;       Nothing
152;   Corrupts registers:
153;       AL
154;--------------------------------------------------------------------
155IdeDPT_StoreDeviceTypeToDPTinDSDIfromIdevarsInCSBP:
156    mov     al, [cs:bp+IDEVARS.bDevice]
157    mov     [di+DPT_ATA.bDevice], al
158    ret
Note: See TracBrowser for help on using the repository browser.