source: xtideuniversalbios/trunk/XTIDE_Universal_BIOS/Src/Boot/BootMenuInfo.asm @ 376

Last change on this file since 376 was 376, checked in by gregli@…, 12 years ago

WIDE checkin... Added copyright and license information to sorce files, as per the GPL instructions for usage.

File size: 3.1 KB
Line 
1; Project name  :   XTIDE Universal BIOS
2; Description   :   Functions for generating and accessing drive
3;                   information to be displayed on boot menu.
4
5;
6; XTIDE Universal BIOS and Associated Tools 
7; Copyright (C) 2009-2010 by Tomi Tilli, 2011-2012 by XTIDE Universal BIOS Team.
8;
9; This program is free software; you can redistribute it and/or modify
10; it under the terms of the GNU General Public License as published by
11; the Free Software Foundation; either version 2 of the License, or
12; (at your option) any later version.
13; 
14; This program is distributed in the hope that it will be useful,
15; but WITHOUT ANY WARRANTY; without even the implied warranty of
16; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
17; GNU General Public License for more details.
18; Visit http://www.gnu.org/licenses/old-licenses/gpl-2.0.html               
19;
20               
21; Section containing code
22SECTION .text
23
24;--------------------------------------------------------------------
25; Creates new BOOTMENUINFO struct for detected hard disk.
26;
27; BootMenuInfo_CreateForHardDisk
28;   Parameters:
29;       DL:     Drive number
30;       DS:DI:  Ptr to Disk Parameter Table
31;       ES:SI:  Ptr to 512-byte ATA information read from the drive
32;   Returns:
33;       ES:BX:  Ptr to BOOTMENUINFO (if successful)
34;   Corrupts registers:
35;       AX, BX, CX, DX, DI
36;--------------------------------------------------------------------
37BootMenuInfo_CreateForHardDisk:
38    call    BootMenuInfo_ConvertDPTtoBX         ; ES:BX now points to new BOOTMENUINFO
39
40    ; Store Drive Name
41    push    ds                                  ; Preserve RAMVARS
42    push    si
43
44    push    es                                  ; ES copied to DS
45    pop     ds
46
47    add     si, BYTE ATA1.strModel              ; DS:SI now points drive name
48    lea     di, [bx+BOOTMENUINFO.szDrvName]     ; ES:DI now points to name destination
49    mov     cx, MAX_HARD_DISK_NAME_LENGTH / 2   ; Max number of WORDs allowed
50.CopyNextWord:
51    lodsw
52    xchg    al, ah                              ; Change endianness
53    stosw
54    loop    .CopyNextWord
55    xor     ax, ax                              ; Zero AX and clear CF
56    stosw                                       ; Terminate with NULL
57
58    pop     si
59    pop     ds
60       
61    ret
62
63
64;--------------------------------------------------------------------
65; BootMenuInfo_GetTotalSectorCount
66;   Parameters:
67;       DS:DI:      DPT Pointer
68;   Returns:
69;       BX:DX:AX:   48-bit sector count
70;   Corrupts registers:
71;       CX
72;--------------------------------------------------------------------
73BootMenuInfo_GetTotalSectorCount:
74    test    BYTE [di+DPT.bFlagsLow], FLG_DRVNHEAD_LBA
75    jnz     SHORT .ReturnFullCapacity
76    jmp     AH15h_GetSectorCountToBXDXAX
77.ReturnFullCapacity:
78    jmp     AccessDPT_GetLbaSectorCountToBXDXAX
79
80
81;--------------------------------------------------------------------
82; Returns offset to BOOTMENUINFO based on DPT pointer.
83;
84; BootMenuInfo_ConvertDPTtoBX
85;   Parameters:
86;       DS:DI:  DPT Pointer
87;   Returns:
88;       BX:     Offset to BOOTMENUINFO struct
89;   Corrupts registers:
90;       AX
91;--------------------------------------------------------------------
92BootMenuInfo_ConvertDPTtoBX:
93    mov     ax, di
94    sub     ax, BYTE RAMVARS_size                   ; subtract off base of DPTs
95    mov     bl, DPT_BOOTMENUINFO_SIZE_MULTIPLIER    ; BOOTMENUINFO's are a whole number multiple of DPT size
96    mul     bl                             
97    add     ax, BOOTVARS.rgBootNfo                  ; add base of BOOTMENUINFO
98    xchg    ax, bx
99    ret 
Note: See TracBrowser for help on using the repository browser.