source: xtideuniversalbios/trunk/XTIDE_Universal_BIOS/Inc/IDE_8bit.inc@ 590

Last change on this file since 590 was 589, checked in by Krister Nordvall, 8 years ago

Changes:

  • BIOS: Fixed a purely cosmetic bug from r542 where, in builds containing MODULE_EBIOS, the boot menu would display an incorrect drive size (0.4 kB with MODULE_STRINGS_COMPRESSED or 0.5 kB without) for old drives with no support for LBA.
  • Fixed a bug from r392 where Vision_DetectAndReturnIDinAXandPortInDXifControllerPresent would return the ID in AL instead of AH (if DANGEROUS_DETECTION had been defined).
  • Fixed a bug from r587 in AdvAtaInit.asm that would prevent detection of QDI Vision controllers.
  • Also changed how the QDI Vision IDs are defined (removed the need for shifting) to avoid confusion. This fixed a potential bug from r587 in AdvAtaInit.asm where some IDs were not being shifted.
  • Fixed a bug in PDC20x30.asm from r587 where GetPdcIDtoAX would not return with the IDE base port in DX so DisablePdcProgrammingMode would fail.
  • Made some changes to ModuleDependency.inc and other files so that MODULE_ADVANCED_ATA now requires USE_386. Consequently it is no longer included in the regular AT-builds, only in the 386_8k-build.
  • Moved the UNROLL_SECTORS_IN_CX_TO_xWORDS macros from IDE_8bit.inc to IdeIO.inc which means it's now possible to build a BIOS without MODULE_8BIT_IDE.
  • XTIDECFG: Added a minimum DOS version check (since it needs DOS version 2+) to allow the program to quit gracefully in the unlikely scenario where someone tries to run it under DOS version 1.
  • Made some changes to Drive.asm to improve drive enumeration. The old method using GET_DOS_DRIVE_PARAMETER_BLOCK_FOR_SPECIFIC_DRIVE worked well in Windows XP but not in Windows 98 SE (in Windows or in DOS mode). The two problems were; 1) The function call would access the drives which on single floppy drive systems would cause Windows to swap between A: and B: (throwing a blue screen asking the user to insert a disk etc). 2) Only floppy drives and FAT16 drives would be available in the list of drives, no FAT32/optical/network drives.
  • Improved code in IdeControllerMenu.asm so that the default port addresses for all IDE interfaces are now restored when (re-)selecting the (same) type of IDE device.
  • Also made it impossible to select a device type unless the required module is included in the loaded BIOS.
  • The version check done when loading a BIOS now uses the FLASH_SIGNATURE definition from Version.inc. Any changes affecting RomVars now only requires updating that definition. This means that changes to RomVars must be implemented in both the BIOS and XTIDECFG before being committed to the repository.
  • Added a compatibility fix for 3Com 3C503 cards to the ROM checksumming code in Buffers.asm (Buffers_GenerateChecksum).
  • SerDrive: Made some minor changes to file names and paths to improve compatibility with case sensitive environments.
  • BIOSDRVS: Made a minor size optimization which as a side effect also makes it compatible with all DOS versions including DOS version 1.
  • Library: Renamed the WAIT_RETRACE_IF_NECESSARY_THEN macro to CALL_WAIT_FOR_RETRACE_IF_NECESSARY_THEN and made a tail-call-optimized version of it (JMP_WAIT_FOR_RETRACE_IF_NECESSARY_THEN).
  • A speed optimization to the eRCL_IM macro for 386 and higher. This change breaks emulation in the sense that the macro will fail when given a memory operand as the first parameter.
  • Other minor optimizations and fixes.
File size: 4.0 KB
Line 
1; Project name : XTIDE Universal BIOS
2; Description : Macros for accessing data port(s) on 8-bit
3; IDE controllers.
4
5;
6; XTIDE Universal BIOS and Associated Tools
7; Copyright (C) 2009-2010 by Tomi Tilli, 2011-2013 by XTIDE Universal BIOS Team.
8;
9; This program is free software; you can redistribute it and/or modify
10; it under the terms of the GNU General Public License as published by
11; the Free Software Foundation; either version 2 of the License, or
12; (at your option) any later version.
13;
14; This program is distributed in the hope that it will be useful,
15; but WITHOUT ANY WARRANTY; without even the implied warranty of
16; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
17; GNU General Public License for more details.
18; Visit http://www.gnu.org/licenses/old-licenses/gpl-2.0.html
19;
20
21%ifndef IDE_8BIT_INC
22%define IDE_8BIT_INC
23
24;--------------------------------------------------------------------
25; Emulates INSW for XTIDE.
26;
27; XTIDE_INSW
28; Parameters:
29; BL: Bit mask for toggling XTIDE data low/high reg
30; DX: XTIDE Data Low Register address
31; ES:DI: Ptr to destination buffer
32; Returns:
33; ES:DI: Incremented/decremented for next word
34; Corrupts registers:
35; AL, FLAGS
36;--------------------------------------------------------------------
37%macro XTIDE_INSW 0
38%ifdef USE_186 ; INS instruction available
39 insb ; Load low byte from port DX to [ES:DI]
40 xor dl, bl ; IDE Data Reg to XTIDE Data High Reg
41 insb ; Load high byte from port DX to [ES:DI]
42 xor dl, bl ; Restore to IDE Data Register
43%else ; If 8088/8086
44 in al, dx ; Load low byte from port
45 xor dl, bl ; IDE Data Reg to XTIDE Data High Reg
46 stosb ; Store byte to [ES:DI]
47 in al, dx ; Load high byte from port
48 xor dl, bl ; Restore to IDE Data Register
49 stosb ; Store byte to [ES:DI]
50%endif
51%endmacro
52
53
54;--------------------------------------------------------------------
55; Emulates OUTSW for XTIDE.
56;
57; XTIDE_OUTSW
58; Parameters:
59; BL: Bit mask for toggling XTIDE data low/high reg
60; DX: XTIDE Data Low Register address
61; DS:SI: Ptr to source buffer
62; Returns:
63; SI: Incremented/decremented for next word
64; Corrupts registers:
65; AX, FLAGS
66;--------------------------------------------------------------------
67%macro XTIDE_OUTSW 0
68%ifdef USE_186 ; OUTS instruction available
69 lodsb ; Load low byte from [DS:SI] to AL
70 xor dl, bl ; IDE Data Reg to XTIDE Data High Reg
71 outsb ; Output high byte from [DS:SI]
72 xor dl, bl ; XTIDE Data High Reg to Data Low Reg
73 out dx, al ; Output low byte from AL
74%else ; If 8088/8086
75 lodsw ; Load word from [DS:SI]
76 xor dl, bl ; IDE Data Reg to XTIDE Data High Reg
77 xchg al, ah ; => AL=high byte, AH=low byte
78 out dx, al ; Output high byte
79 xor dl, bl ; XTIDE Data High Reg to Data Low Reg
80 mov al, ah ; Copy low byte to AL
81 out dx, al ; Output low byte
82%endif
83%endmacro
84
85
86;--------------------------------------------------------------------
87; Emulates OUTSW for modified XTIDE.
88;
89; XTIDE_MOD_OUTSW
90; Parameters:
91; DX: XTIDE Data Low Register address
92; DS:SI: Ptr to source buffer
93; Returns:
94; SI: Incremented/decremented for next word
95; Corrupts registers:
96; AX, FLAGS
97;--------------------------------------------------------------------
98%macro XTIDE_MOD_OUTSW 0
99%ifdef USE_186 ; OUTS instruction available
100 lodsb ; Load low byte from [DS:SI] to AL
101 inc dx ; IDE Data Reg to XTIDE MOD Data High Reg
102 outsb ; Output high byte from [DS:SI]
103 dec dx ; XTIDE Data High Reg to Data Low Reg
104 out dx, al ; Output low byte from AL
105%else ; If 8088/8086
106 lodsw ; Load word from [DS:SI]
107 inc dx ; IDE Data Reg to XTIDE MOD Data High Reg
108 xchg al, ah ; => AL=high byte, AH=low byte
109 out dx, al ; Output high byte
110 dec dx ; XTIDE Data High Reg to Data Low Reg
111 mov al, ah ; Copy low byte to AL
112 out dx, al ; Output low byte
113%endif
114%endmacro
115
116
117%endif ; IDE_8BIT_INC
Note: See TracBrowser for help on using the repository browser.