source: xtideuniversalbios/trunk/Assembly_Library/Src/Util/Memory.asm@ 440

Last change on this file since 440 was 440, checked in by aitotat@…, 12 years ago

Changes to Assembly Library:

  • Added function to sum bytes.
File size: 4.5 KB
Line 
1; Project name : Assembly Library
2; Description : Functions for memory access.
3
4;
5; XTIDE Universal BIOS and Associated Tools
6; Copyright (C) 2009-2010 by Tomi Tilli, 2011-2012 by XTIDE Universal BIOS Team.
7;
8; This program is free software; you can redistribute it and/or modify
9; it under the terms of the GNU General Public License as published by
10; the Free Software Foundation; either version 2 of the License, or
11; (at your option) any later version.
12;
13; This program is distributed in the hope that it will be useful,
14; but WITHOUT ANY WARRANTY; without even the implied warranty of
15; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
16; GNU General Public License for more details.
17; Visit http://www.gnu.org/licenses/old-licenses/gpl-2.0.html
18;
19
20; Section containing code
21SECTION .text
22
23;--------------------------------------------------------------------
24; OPTIMIZE_STRING_OPERATION
25; Parameters
26; %1: Repeat instruction
27; %2: String instruction without size (for example MOVS and not MOVSB or MOVSW)
28; CX: Number of BYTEs to operate
29; DS:SI: Ptr to source data
30; ES:DI: Ptr to destination
31; Returns:
32; SI, DI: Updated by number of bytes operated
33; Corrupts registers:
34; Nothing
35;--------------------------------------------------------------------
36%macro OPTIMIZE_STRING_OPERATION 2
37 push cx
38
39 shr cx, 1 ; Operate with WORDs for performance
40 jz %%HandleRemainingByte
41 %1 %2w
42%%HandleRemainingByte:
43 jnc SHORT %%OperationCompleted
44 %2b
45
46ALIGN JUMP_ALIGN
47%%OperationCompleted:
48 pop cx
49%endmacro
50
51
52;--------------------------------------------------------------------
53; Memory_CopyCXbytesFromDSSItoESDI
54; Parameters
55; CX: Number of bytes to copy
56; DS:SI: Ptr to source data
57; ES:DI: Ptr to destination buffer
58; Returns:
59; SI, DI: Updated by number of bytes copied
60; Corrupts registers:
61; Nothing
62;--------------------------------------------------------------------
63%ifndef EXCLUDE_FROM_XTIDE_UNIVERSAL_BIOS
64ALIGN JUMP_ALIGN
65Memory_CopyCXbytesFromDSSItoESDI:
66 OPTIMIZE_STRING_OPERATION rep, movs
67 ret
68%endif
69
70
71;--------------------------------------------------------------------
72; Memory_ZeroSSBPwithSizeInCX
73; Parameters
74; CX: Number of bytes to zero
75; SS:BP: Ptr to buffer to zero
76; Returns:
77; Nothing
78; Corrupts registers:
79; Nothing
80;--------------------------------------------------------------------
81ALIGN JUMP_ALIGN
82Memory_ZeroSSBPwithSizeInCX:
83 push es
84 push di
85 push ax
86 call Registers_CopySSBPtoESDI
87 call Memory_ZeroESDIwithSizeInCX
88 pop ax
89 pop di
90 pop es
91 ret
92
93;--------------------------------------------------------------------
94; Memory_ZeroESDIwithSizeInCX
95; Parameters
96; CX: Number of bytes to zero
97; ES:DI: Ptr to destination buffer
98; Returns:
99; DI: Updated by number of BYTEs stored
100; Corrupts registers:
101; AX
102;--------------------------------------------------------------------
103ALIGN JUMP_ALIGN
104Memory_ZeroESDIwithSizeInCX:
105 xor ax, ax
106 ; Fall to Memory_StoreCXbytesFromAccumToESDI
107
108;--------------------------------------------------------------------
109; Memory_StoreCXbytesFromAccumToESDI
110; Parameters
111; AX: Word to use to fill buffer
112; CX: Number of BYTEs to store
113; ES:DI: Ptr to destination buffer
114; Returns:
115; DI: Updated by number of BYTEs stored
116; Corrupts registers:
117; Nothing
118;--------------------------------------------------------------------
119ALIGN JUMP_ALIGN
120Memory_StoreCXbytesFromAccumToESDI:
121 OPTIMIZE_STRING_OPERATION rep, stos
122 ret
123
124
125;--------------------------------------------------------------------
126; Memory_ReserveCXbytesFromStackToDSSI
127; Parameters
128; CX: Number of bytes to reserve
129; Returns:
130; DS:SI: Ptr to reserved buffer
131; Corrupts registers:
132; AX
133;--------------------------------------------------------------------
134%ifndef EXCLUDE_FROM_XTIDE_UNIVERSAL_BIOS
135ALIGN JUMP_ALIGN
136Memory_ReserveCXbytesFromStackToDSSI:
137 pop ax
138 push ss
139 pop ds
140 sub sp, cx
141 mov si, sp
142 jmp ax
143%endif
144
145
146;--------------------------------------------------------------------
147; Memory_SumCXbytesFromESSItoAL
148; Parameters
149; CX: Number of bytes to sum (0=65536)
150; ES:SI: Ptr to buffer containing the bytes to sum
151; Returns:
152; AL: Sum of bytes
153; Corrupts registers:
154; CX
155;--------------------------------------------------------------------
156ALIGN JUMP_ALIGN
157Memory_SumCXbytesFromESSItoAL:
158 push si
159 xor al, al
160ALIGN JUMP_ALIGN
161.AddNextByteToAL:
162 add al, [es:si]
163 inc si
164 loop .AddNextByteToAL
165 pop si
166 ret
Note: See TracBrowser for help on using the repository browser.