source: xtideuniversalbios/trunk/Assembly_Library/Src/Time/TimerTicks.asm @ 60

Last change on this file since 60 was 60, checked in by aitotat, 13 years ago

Changes to Assembly Library:

  • Timeout count down is now stopped when any key pressed.
File size: 4.2 KB
Line 
1; File name     :   TimerTicks.asm
2; Project name  :   Assembly Library
3; Created date  :   24.7.2010
4; Last update   :   22.11.2010
5; Author        :   Tomi Tilli
6; Description   :   Functions for system timer related operations.
7
8; System timer ticks 18.2 times per second = 54.9 ms / tick
9TICKS_PER_HOUR          EQU     65520
10TICKS_PER_MINUTE        EQU     1092
11TICKS_PER_SECOND        EQU     18
12
13
14; Section containing code
15SECTION .text
16
17;--------------------------------------------------------------------
18; TimerTicks_GetHoursToAXfromTicksInDXAX
19; TimerTicks_GetMinutesToAXfromTicksInDX
20; TimerTicks_GetSecondsToAXfromTicksInDX
21;   Parameters
22;       DX(:AX):    Timer ticks to convert
23;   Returns:
24;       AX:         Hours, minutes or seconds
25;       DX:         Remainder ticks
26;   Corrupts registers:
27;       CX
28;--------------------------------------------------------------------
29ALIGN JUMP_ALIGN
30TimerTicks_GetHoursToAXfromTicksInDXAX:
31    mov     cx, TICKS_PER_HOUR
32    div     cx      ; Divide DX:AX by CX, Hours to AX, remainder ticks to DX
33    ret
34
35ALIGN JUMP_ALIGN
36TimerTicks_GetMinutesToAXfromTicksInDX:
37    xor     ax, ax
38    xchg    ax, dx  ; Ticks now in DX:AX
39    mov     cx, TICKS_PER_MINUTE
40    div     cx      ; Divide DX:AX by CX, Minutes to AX, remainder ticks to DX
41    ret
42
43ALIGN JUMP_ALIGN
44TimerTicks_GetSecondsToAXfromTicksInDX:
45    xchg    ax, dx  ; Ticks now in AX
46    mov     cl, TICKS_PER_SECOND
47    div     cl      ; Divide AX by CL, Seconds to AL, remainder ticks to AH
48    xor     dx, dx
49    xchg    dl, ah  ; Seconds in AX, remainder in DX
50    ret
51
52
53;--------------------------------------------------------------------
54; First tick might take 0...54.9 ms and remaining ticks
55; will occur at 54.9 ms intervals. Use delay of two (or more) ticks to
56; ensure at least 54.9 ms timeout.
57;
58; TimerTicks_InitializeTimeoutFromAX
59;   Parameters:
60;       AX:         Timeout ticks (54.9 ms) before timeout
61;       DS:BX:      Ptr to timeout variable WORD
62;   Returns:
63;       [DS:BX]:    Initialized for TimerTicks_SetCarryIfTimeoutFromDSBX
64;   Corrupts registers:
65;       AX
66;--------------------------------------------------------------------
67ALIGN JUMP_ALIGN
68TimerTicks_InitializeTimeoutFromAX:
69    mov     [bx], ax                    ; Store timeout ticks
70    call    TimerTicks_ReadFromBdaToAX
71    add     [bx], ax                    ; Add latest time to timeout ticks
72    ret
73
74
75;--------------------------------------------------------------------
76; TimerTicks_GetTimeoutTicksLeftToAXfromDSBX
77;   Parameters:
78;       AX:         Number of ticks left before timeout
79;       DS:BX:      Ptr to timeout variable WORD
80;   Returns:
81;       CF:         Set if timeout
82;                   Cleared if time left
83;   Corrupts registers:
84;       Nothing
85;--------------------------------------------------------------------
86ALIGN JUMP_ALIGN
87TimerTicks_GetTimeoutTicksLeftToAXfromDSBX:
88    push    dx
89    mov     dx, [bx]
90    call    TimerTicks_ReadFromBdaToAX
91    xchg    ax, dx
92    sub     ax, dx      ; AX = End time - current time
93    pop     dx
94    ret
95
96
97;--------------------------------------------------------------------
98; TimerTicks_GetElapsedToAXandResetDSBX
99;   Parameters
100;       DS:BX:      Ptr to WORD containing previous reset time
101;   Returns:
102;       AX:         54.9 ms ticks elapsed since last reset
103;       [DS:BX]:    Reset to latest time
104;   Corrupts registers:
105;       Nothing
106;--------------------------------------------------------------------
107ALIGN JUMP_ALIGN
108TimerTicks_GetElapsedToAXandResetDSBX:
109    call    TimerTicks_ReadFromBdaToAX
110    push    ax
111    sub     ax, [bx]
112    pop     WORD [bx]           ; Latest time to [DS:BX]
113    ret
114
115;--------------------------------------------------------------------
116; TimerTicks_GetElapsedToAXfromDSBX
117;   Parameters
118;       DS:BX:      Ptr to WORD containing previous update time
119;   Returns:
120;       AX:         54.9 ms ticks elapsed since initializing [DS:BX]
121;   Corrupts registers:
122;       Nothing
123;--------------------------------------------------------------------
124ALIGN JUMP_ALIGN
125TimerTicks_GetElapsedToAXfromDSBX:
126    call    TimerTicks_ReadFromBdaToAX
127    sub     ax, [bx]
128    ret
129
130
131;--------------------------------------------------------------------
132; TimerTicks_ReadFromBdaToAX
133;   Parameters
134;       Nothing
135;   Returns:
136;       AX:     System time in 54.9 ms ticks
137;   Corrupts registers:
138;       Nothing
139;--------------------------------------------------------------------
140ALIGN JUMP_ALIGN
141TimerTicks_ReadFromBdaToAX:
142    push    ds
143
144    LOAD_BDA_SEGMENT_TO ds, ax
145    mov     ax, [BDA.dwTimerTicks]  ; Read low WORD only
146
147    pop     ds
148    ret
Note: See TracBrowser for help on using the repository browser.