source: xtideuniversalbios/trunk/Assembly_Library/Src/String/String.asm @ 621

Last change on this file since 621 was 621, checked in by krille_n_, 9 months ago

Changes:

  • Fixed three different bugs all causing the boot menu to show drives using IRQs even though the BIOS had been built without MODULE_IRQ.
  • Fixed two bugs in XTIDECFG where loading a BIOS from file and then loading the old settings from EEPROM would
    • overwrite ROMVARS.wFlags in the loaded BIOS file (in RAM). The possibly resulting mismatch of module flags could make it impossible to change settings for modules included in the BIOS or allow changing settings for modules not included in the BIOS.
    • not copy the color theme over to the loaded BIOS.
  • Also fixed two very minor bugs in XTIDECFG in BiosFile_LoadFileFromDSSItoRamBuffer and BiosFile_SaveRamBufferToFileInDSSI where the error handling in these routines would close whatever file handle that happened to match the error code returned by DOS in AX.
  • Made significant changes to the new flash ROM programming routines to reduce the size. Also fixed a minor bug that would cause the second verification to be skipped and return success when programming a 64 KB block of data.
  • Changed the custom BIOS build file names to the 8.3 format.
  • Changed some help strings in XTIDECFG to clarify things.
  • Other minor optimizations and fixes.
File size: 3.4 KB
Line 
1; Project name  :   Assembly Library
2; Description   :   Functions for handling characters.
3
4;
5; XTIDE Universal BIOS and Associated Tools
6; Copyright (C) 2009-2010 by Tomi Tilli, 2011-2013 by XTIDE Universal BIOS Team.
7;
8; This program is free software; you can redistribute it and/or modify
9; it under the terms of the GNU General Public License as published by
10; the Free Software Foundation; either version 2 of the License, or
11; (at your option) any later version.
12;
13; This program is distributed in the hope that it will be useful,
14; but WITHOUT ANY WARRANTY; without even the implied warranty of
15; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
16; GNU General Public License for more details.
17; Visit http://www.gnu.org/licenses/old-licenses/gpl-2.0.html
18;
19
20; Section containing code
21SECTION .text
22
23;--------------------------------------------------------------------
24; String_ConvertDSSItoLowerCase
25;   Parameters:
26;       DS:SI:  Ptr to string to convert
27;   Returns:
28;       CX:     Number of characters processed
29;   Corrupts registers:
30;       Nothing
31;--------------------------------------------------------------------
32ALIGN STRING_JUMP_ALIGN
33String_ConvertDSSItoLowerCase:
34    push    dx
35    push    ax
36
37    mov     dx, StringProcess_ConvertToLowerCase
38    call    StringProcess_DSSIwithFunctionInDX
39
40    pop     ax
41    pop     dx
42    ret
43
44
45;--------------------------------------------------------------------
46; String_ConvertWordToAXfromStringInDSSIwithBaseInBX
47;   Parameters:
48;       BX:     Numeric base (10 or 16)
49;       DS:SI:  Ptr to string to convert
50;   Returns:
51;       AX:     Word converted from string
52;       CX:     Number of characters processed
53;       CF:     Cleared if successful
54;               Set if error during conversion
55;   Corrupts registers:
56;       Nothing
57;--------------------------------------------------------------------
58ALIGN STRING_JUMP_ALIGN
59String_ConvertWordToAXfromStringInDSSIwithBaseInBX:
60    push    di
61    push    dx
62
63    xor     di, di
64    mov     dx, StringProcess_ConvertToWordInDIWithBaseInBX
65    call    StringProcess_DSSIwithFunctionInDX
66    xchg    ax, di
67
68    pop     dx
69    pop     di
70    ret
71
72
73;--------------------------------------------------------------------
74; String_CopyDSSItoESDIandGetLengthToCX
75;   Parameters:
76;       DS:SI:  Ptr to source NULL terminated string
77;       ES:DI:  Ptr to destination buffer
78;   Returns:
79;       CX:     Number of characters copied
80;       SI,DI:  Updated by CX characters
81;       CF:     Cleared
82;   Corrupts registers:
83;       Nothing
84;--------------------------------------------------------------------
85ALIGN STRING_JUMP_ALIGN
86String_CopyDSSItoESDIandGetLengthToCX:
87    push    ax
88
89    xor     cx, cx
90ALIGN STRING_JUMP_ALIGN
91.CopyNextCharacter:
92    lodsb                       ; Load from DS:SI to AL
93    test    al, al              ; NULL to end string? (Clears CF)
94    jz      SHORT PopAXandReturn
95    stosb                       ; Store from AL to ES:DI
96    inc     cx                  ; Increment number of characters written
97    jmp     SHORT .CopyNextCharacter
98
99
100;--------------------------------------------------------------------
101; String_GetLengthFromDSSItoCX
102;   Parameters:
103;       DS:SI:  Ptr to NULL terminated string
104;   Returns:
105;       CX:     String length in characters
106;   Corrupts registers:
107;       Nothing
108;--------------------------------------------------------------------
109ALIGN STRING_JUMP_ALIGN
110String_GetLengthFromDSSItoCX:
111    push    ax
112    push    si
113
114    call    Registers_ExchangeDSSIwithESDI
115    xor     ax, ax      ; Find NULL
116    mov     cx, -1      ; Full segment if necessary
117    repne scasb
118    mov     cx, di
119    call    Registers_ExchangeDSSIwithESDI
120
121    pop     si
122    stc
123    sbb     cx, si      ; Subtract NULL
124PopAXandReturn:
125    pop     ax
126    ret
Note: See TracBrowser for help on using the repository browser.