1 | ; Project name : Assembly Library |
---|
2 | ; Description : Menu loop for waiting keystrokes. |
---|
3 | |
---|
4 | ; Section containing code |
---|
5 | SECTION .text |
---|
6 | |
---|
7 | ;-------------------------------------------------------------------- |
---|
8 | ; MenuLoop_Enter |
---|
9 | ; Parameters |
---|
10 | ; SS:BP: Ptr to MENU |
---|
11 | ; Returns: |
---|
12 | ; Nothing |
---|
13 | ; Corrupts registers: |
---|
14 | ; AX, BX, CX, DX, SI, DI |
---|
15 | ;-------------------------------------------------------------------- |
---|
16 | ALIGN JUMP_ALIGN |
---|
17 | MenuLoop_Enter: |
---|
18 | call KeystrokeProcessing |
---|
19 | call TimeoutProcessing |
---|
20 | call MenuEvent_IdleProcessing ; User idle processing |
---|
21 | test BYTE [bp+MENU.bFlags], FLG_MENU_EXIT |
---|
22 | jz SHORT MenuLoop_Enter |
---|
23 | ret |
---|
24 | |
---|
25 | |
---|
26 | ;-------------------------------------------------------------------- |
---|
27 | ; KeystrokeProcessing |
---|
28 | ; TimeoutProcessing |
---|
29 | ; Parameters |
---|
30 | ; SS:BP: Ptr to MENU |
---|
31 | ; Returns: |
---|
32 | ; Nothing |
---|
33 | ; Corrupts registers: |
---|
34 | ; All, except SS:BP |
---|
35 | ;-------------------------------------------------------------------- |
---|
36 | ALIGN JUMP_ALIGN |
---|
37 | KeystrokeProcessing: |
---|
38 | call Keyboard_GetKeystrokeToAX |
---|
39 | jnz SHORT ProcessKeystrokeFromAX |
---|
40 | NoKeystrokeToProcess: |
---|
41 | ret |
---|
42 | |
---|
43 | ALIGN JUMP_ALIGN |
---|
44 | TimeoutProcessing: |
---|
45 | call MenuTime_UpdateSelectionTimeout |
---|
46 | jnc NoKeystrokeToProcess |
---|
47 | mov al, CR ; Fake ENTER to select item |
---|
48 | ; Fall to ProcessKeystrokeFromAX |
---|
49 | |
---|
50 | |
---|
51 | ;-------------------------------------------------------------------- |
---|
52 | ; ProcessKeystrokeFromAX |
---|
53 | ; Parameters |
---|
54 | ; AL: ASCII character |
---|
55 | ; AH: BIOS scan code |
---|
56 | ; SS:BP: Ptr to MENU |
---|
57 | ; Returns: |
---|
58 | ; Nothing |
---|
59 | ; Corrupts registers: |
---|
60 | ; AX, BX, CX, DX, SI, DI |
---|
61 | ;-------------------------------------------------------------------- |
---|
62 | ALIGN JUMP_ALIGN |
---|
63 | ProcessKeystrokeFromAX: |
---|
64 | xchg cx, ax |
---|
65 | call MenuTime_StopSelectionTimeout |
---|
66 | xchg ax, cx |
---|
67 | call .ProcessMenuSystemKeystrokeFromAX |
---|
68 | jc SHORT NoKeystrokeToProcess |
---|
69 | jmp MenuEvent_KeyStrokeInAX |
---|
70 | |
---|
71 | ;-------------------------------------------------------------------- |
---|
72 | ; .ProcessMenuSystemKeystrokeFromAX |
---|
73 | ; Parameters |
---|
74 | ; AL: ASCII character |
---|
75 | ; AH: BIOS scan code |
---|
76 | ; SS:BP: Ptr to MENU |
---|
77 | ; Returns: |
---|
78 | ; CF: Set if keystroke processed |
---|
79 | ; Cleared if keystroke not processed |
---|
80 | ; AL: ASCII character (if CF cleared) |
---|
81 | ; AH: BIOS scan code (if CF cleared) |
---|
82 | ; Corrupts registers: |
---|
83 | ; BX, CX, DX, SI, DI |
---|
84 | ;-------------------------------------------------------------------- |
---|
85 | ALIGN JUMP_ALIGN |
---|
86 | .ProcessMenuSystemKeystrokeFromAX: |
---|
87 | cmp al, ESC |
---|
88 | je SHORT .LeaveMenuWithoutSelectingItem |
---|
89 | cmp al, CR |
---|
90 | je SHORT .SelectItem |
---|
91 | |
---|
92 | test BYTE [bp+MENU.bFlags], FLG_MENU_USER_HANDLES_SCROLLING |
---|
93 | jz SHORT MenuLoop_ProcessScrollingKeysFromAX |
---|
94 | ret ; Return with CF cleared since keystroke not processed |
---|
95 | |
---|
96 | ALIGN JUMP_ALIGN |
---|
97 | .LeaveMenuWithoutSelectingItem: |
---|
98 | call MenuEvent_ExitMenu |
---|
99 | jnc SHORT .CancelMenuExit |
---|
100 | call MenuInit_CloseMenuWindow |
---|
101 | mov WORD [bp+MENUINIT.wHighlightedItem], NO_ITEM_HIGHLIGHTED |
---|
102 | .CancelMenuExit: |
---|
103 | stc |
---|
104 | ret |
---|
105 | |
---|
106 | ALIGN JUMP_ALIGN |
---|
107 | .SelectItem: |
---|
108 | mov cx, [bp+MENUINIT.wHighlightedItem] |
---|
109 | call MenuEvent_ItemSelectedFromCX |
---|
110 | stc |
---|
111 | ret |
---|
112 | |
---|
113 | |
---|
114 | ;-------------------------------------------------------------------- |
---|
115 | ; MenuLoop_ProcessScrollingKeysFromAX |
---|
116 | ; Parameters |
---|
117 | ; AL: ASCII character |
---|
118 | ; AH: BIOS scan code |
---|
119 | ; SS:BP: Ptr to MENU |
---|
120 | ; Returns: |
---|
121 | ; CF: Set if keystroke processed |
---|
122 | ; Cleared if keystroke not processed |
---|
123 | ; AL: ASCII character (if CF cleared) |
---|
124 | ; AH: BIOS scan code (if CF cleared) |
---|
125 | ; Corrupts registers: |
---|
126 | ; BX, CX, DX, SI, DI |
---|
127 | ;-------------------------------------------------------------------- |
---|
128 | ALIGN JUMP_ALIGN |
---|
129 | MenuLoop_ProcessScrollingKeysFromAX: |
---|
130 | xchg ah, al |
---|
131 | cmp al, MENU_KEY_PGUP |
---|
132 | je SHORT .ChangeToPreviousPage |
---|
133 | cmp al, MENU_KEY_PGDN |
---|
134 | je SHORT .ChangeToNextPage |
---|
135 | cmp al, MENU_KEY_HOME |
---|
136 | je SHORT .SelectFirstItem |
---|
137 | cmp al, MENU_KEY_END |
---|
138 | je SHORT .SelectLastItem |
---|
139 | |
---|
140 | cmp al, MENU_KEY_UP |
---|
141 | je SHORT .DecrementSelectedItem |
---|
142 | cmp al, MENU_KEY_DOWN |
---|
143 | je SHORT .IncrementSelectedItem |
---|
144 | clc ; Clear CF since keystroke not processed |
---|
145 | xchg ah, al |
---|
146 | ret |
---|
147 | |
---|
148 | ALIGN JUMP_ALIGN |
---|
149 | .ChangeToPreviousPage: |
---|
150 | call MenuScrollbars_GetMaxVisibleItemsOnPageToCX |
---|
151 | xchg ax, cx |
---|
152 | neg ax |
---|
153 | mov cx, [bp+MENUINIT.wHighlightedItem] |
---|
154 | add cx, ax |
---|
155 | jge SHORT .MoveHighlightedItemByAX ; No rotation for PgUp |
---|
156 | ; Fall to .SelectFirstItem |
---|
157 | ALIGN JUMP_ALIGN |
---|
158 | .SelectFirstItem: |
---|
159 | mov ax, [bp+MENUINIT.wHighlightedItem] |
---|
160 | neg ax |
---|
161 | jmp SHORT .MoveHighlightedItemByAX |
---|
162 | |
---|
163 | ALIGN JUMP_ALIGN |
---|
164 | .ChangeToNextPage: |
---|
165 | call MenuScrollbars_GetMaxVisibleItemsOnPageToCX |
---|
166 | xchg ax, cx |
---|
167 | mov cx, [bp+MENUINIT.wHighlightedItem] |
---|
168 | add cx, ax |
---|
169 | cmp cx, [bp+MENUINIT.wItems] |
---|
170 | jb SHORT .MoveHighlightedItemByAX ; No rotation for PgDn |
---|
171 | ; Fall to .SelectLastItem |
---|
172 | ALIGN JUMP_ALIGN |
---|
173 | .SelectLastItem: |
---|
174 | stc |
---|
175 | mov ax, [bp+MENUINIT.wItems] |
---|
176 | sbb ax, [bp+MENUINIT.wHighlightedItem] |
---|
177 | jmp SHORT .MoveHighlightedItemByAX |
---|
178 | |
---|
179 | ALIGN JUMP_ALIGN |
---|
180 | .DecrementSelectedItem: |
---|
181 | mov ax, -1 |
---|
182 | SKIP2B cx ; mov cx, <next instruction> |
---|
183 | .IncrementSelectedItem: |
---|
184 | mov al, 1 ; AH is already 0 |
---|
185 | ALIGN JUMP_ALIGN |
---|
186 | .MoveHighlightedItemByAX: |
---|
187 | call MenuScrollbars_MoveHighlightedItemByAX |
---|
188 | stc |
---|
189 | ret |
---|