source: xtideuniversalbios/trunk/Assembly_Library/Src/File/DosCritical.asm@ 601

Last change on this file since 601 was 593, checked in by Tomi Tilli, 6 years ago

Flashing now works again.
Hack to get Windows 95 to work properly (MODULE_WIN95_CMOS_HACK included for 386 builds by default).
Edited makefile to produce large 386 build.
Fixed recovery time for QDI Vision VLB-IDE controllers.
No more warnings with Nasm 2.13.xx and later.
File dialog now properly restores default drive when file selection is cancelled.
File size: 3.2 KB
Line 
1; Project name : Assembly Library
2; Description : DOS Critical Error Handler (24h) replacements.
3
4;
5; XTIDE Universal BIOS and Associated Tools
6; Copyright (C) 2009-2010 by Tomi Tilli, 2011-2013 by XTIDE Universal BIOS Team.
7;
8; This program is free software; you can redistribute it and/or modify
9; it under the terms of the GNU General Public License as published by
10; the Free Software Foundation; either version 2 of the License, or
11; (at your option) any later version.
12;
13; This program is distributed in the hope that it will be useful,
14; but WITHOUT ANY WARRANTY; without even the implied warranty of
15; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
16; GNU General Public License for more details.
17; Visit http://www.gnu.org/licenses/old-licenses/gpl-2.0.html
18;
19
20; Note! Only DOS functions 01h - 0Ch, 30h and 59h can be called from a Critical Error Handler.
21
22; DOS Critical Error Handler return values
23struc CRITICAL_ERROR_ACTION
24 .ignoreErrorAndContinueProcessingRequest resb 1
25 .retryOperation resb 1
26 .terminateProgramAsThoughInt21hAH4ChCalled resb 1
27 .failSystemCallInProgress resb 1 ; Needs DOS 3.1+
28endstruc
29
30
31; Section containing code
32SECTION .text
33
34;--------------------------------------------------------------------
35; DosCritical_InstallNewHandlerFromCSDX
36; Parameters:
37; CS:DX: New Critical Error Handler
38; Returns:
39; Nothing
40; Corrupts registers:
41; AX
42;--------------------------------------------------------------------
43ALIGN JUMP_ALIGN
44DosCritical_InstallNewHandlerFromCSDX:
45 push ds
46
47 mov al, DOS_CRITICAL_ERROR_HANDLER_24h
48 call HookInterruptVectorInALwithHandlerInCSDX
49
50 pop ds
51 ret
52
53
54;--------------------------------------------------------------------
55; DosCritical_RestoreDosHandler
56; Parameters:
57; Nothing
58; Returns:
59; Nothing
60; Corrupts registers:
61; Nothing
62;--------------------------------------------------------------------
63ALIGN JUMP_ALIGN
64DosCritical_RestoreDosHandler:
65 push ds
66 push dx
67 push ax
68
69 lds dx, [cs:PSP.fpInt24hCriticalError]
70 mov ax, (SET_INTERRUPT_VECTOR<<8) | DOS_CRITICAL_ERROR_HANDLER_24h
71 int DOS_INTERRUPT_21h
72
73 pop ax
74 pop dx
75 pop ds
76 ret
77
78
79;--------------------------------------------------------------------
80; DosCritical_CustomHandler
81; Parameters:
82; Nothing
83; Returns:
84; Nothing
85; Corrupts registers:
86; Nothing
87;--------------------------------------------------------------------
88ALIGN JUMP_ALIGN
89DosCritical_CustomHandler:
90 add sp, 6 ; Remove the INT 24h return address and flags from stack
91
92 mov ah, GET_EXTENDED_ERROR_INFORMATION ; Requires DOS 3.0+
93 xor bx, bx
94 int DOS_INTERRUPT_21h
95 mov [cs:bLastCriticalError], al
96
97 pop ax
98 pop bx
99 pop cx
100 pop dx
101 pop si
102 pop di
103 pop bp
104 pop ds
105 pop es
106 iret ; Return from the INT 21h call
107
108bLastCriticalError: db 0
109
110
111;--------------------------------------------------------------------
112; DosCritical_HandlerToIgnoreAllErrors
113; Parameters:
114; Nothing
115; Returns:
116; AL: CRITICAL_ERROR_ACTION
117; Corrupts registers:
118; Nothing
119;--------------------------------------------------------------------
120ALIGN JUMP_ALIGN
121DosCritical_HandlerToIgnoreAllErrors:
122 mov al, CRITICAL_ERROR_ACTION.ignoreErrorAndContinueProcessingRequest
123 iret
124
Note: See TracBrowser for help on using the repository browser.