source: xtideuniversalbios/trunk/Assembly_Library/Src/Display/CgaSnow.asm@ 611

Last change on this file since 611 was 593, checked in by Tomi Tilli, 6 years ago

Flashing now works again.
Hack to get Windows 95 to work properly (MODULE_WIN95_CMOS_HACK included for 386 builds by default).
Edited makefile to produce large 386 build.
Fixed recovery time for QDI Vision VLB-IDE controllers.
No more warnings with Nasm 2.13.xx and later.
File dialog now properly restores default drive when file selection is cancelled.
File size: 4.3 KB
Line 
1; Project name : Assembly Library
2; Description : Functions for preventing CGA snow.
3
4;
5; XTIDE Universal BIOS and Associated Tools
6; Copyright (C) 2009-2010 by Tomi Tilli, 2011-2013 by XTIDE Universal BIOS Team.
7;
8; This program is free software; you can redistribute it and/or modify
9; it under the terms of the GNU General Public License as published by
10; the Free Software Foundation; either version 2 of the License, or
11; (at your option) any later version.
12;
13; This program is distributed in the hope that it will be useful,
14; but WITHOUT ANY WARRANTY; without even the implied warranty of
15; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
16; GNU General Public License for more details.
17; Visit http://www.gnu.org/licenses/old-licenses/gpl-2.0.html
18;
19
20; Section containing code
21SECTION .text
22
23;--------------------------------------------------------------------
24; CgaSnow_IsCgaPresent
25; Parameters:
26; DS: BDA segment (zero)
27; Returns:
28; CF: Set if CGA detected
29; Cleared if CGA not detected
30; Corrupts registers:
31; Nothing
32;--------------------------------------------------------------------
33ALIGN DISPLAY_JUMP_ALIGN
34CgaSnow_IsCgaPresent:
35 cmp WORD [BDA.wVidPort], CGA_STATUS_REGISTER - OFFSET_TO_CGA_STATUS_REGISTER
36 jne SHORT .CgaNotFound
37
38 ; All standard CGA modes use 25 rows but only EGA and later store it to BDA.
39 cmp BYTE [BDA.bVidRows], 24 ; BDA contains rows - 1
40 jae SHORT .CgaNotFound
41 ret
42ALIGN DISPLAY_JUMP_ALIGN
43.CgaNotFound:
44 clc
45 ret
46
47
48; CGA snow prevention must be kept optional to avoid unnecessary
49; overhead when building programs meant for non-CGA systems.
50%ifdef ELIMINATE_CGA_SNOW
51
52;--------------------------------------------------------------------
53; CgaSnow_Stosb
54; CgaSnow_Stosw
55; Parameters:
56; AL: Character to output
57; AH: Attribute to output (CgaSnow_StoswWithoutCgaSnow only)
58; DS: BDA segment (zero)
59; ES:DI: Ptr to video memory where to output
60; Returns:
61; DI: Incremented for next character
62; Corrupts registers:
63; AX, DX
64;--------------------------------------------------------------------
65ALIGN DISPLAY_JUMP_ALIGN
66CgaSnow_Stosb:
67 call LoadCgaStatusRegisterAddressToDXifCgaPresent
68 jz SHORT .StosbWithoutWaitSinceUnknownPort
69
70 mov ah, al
71 cli ; Interrupt request would mess up timing
72 WAIT_UNTIL_SAFE_CGA_WRITE
73 mov al, ah
74.StosbWithoutWaitSinceUnknownPort:
75 stosb
76 sti
77 ret
78
79ALIGN DISPLAY_JUMP_ALIGN
80CgaSnow_Stosw:
81 push bx
82 call LoadCgaStatusRegisterAddressToDXifCgaPresent
83 jz SHORT .StoswWithoutWaitSinceUnknownPort
84
85 xchg bx, ax
86 cli ; Interrupt request would mess up timing
87 WAIT_UNTIL_SAFE_CGA_WRITE
88 xchg ax, bx
89.StoswWithoutWaitSinceUnknownPort:
90 stosw
91 sti
92 pop bx
93 ret
94
95
96;--------------------------------------------------------------------
97; CgaSnow_RepMovsb
98; Parameters:
99; CX: Number of characters to copy
100; DS: BDA segment (zero)
101; ES:SI: Ptr to video memory where to read from
102; ES:DI: Ptr to video memory where to write to
103; Returns:
104; SI, DI: Updated for next character
105; Corrupts registers:
106; AX, CX, DX
107;--------------------------------------------------------------------
108%ifdef EXCLUDE_FROM_XUB
109 %ifdef MODULE_STRINGS_COMPRESSED
110 %define EXCLUDE
111 %endif
112 %ifdef MODULE_BOOT_MENU
113 %undef EXCLUDE
114 %endif
115%endif
116
117%ifndef EXCLUDE
118ALIGN DISPLAY_JUMP_ALIGN
119CgaSnow_RepMovsb:
120 call LoadCgaStatusRegisterAddressToDXifCgaPresent
121 jz SHORT .RepMovsbWithoutWaitSinceUnknownPort
122
123.MovsbNextByte:
124 cli ; Interrupt request would mess up timing
125 WAIT_UNTIL_SAFE_CGA_WRITE
126 es movsb
127 sti
128 loop .MovsbNextByte
129 ret
130.RepMovsbWithoutWaitSinceUnknownPort:
131 eSEG_STR rep, es, movsb
132 ret
133%endif
134%undef EXCLUDE
135
136
137;--------------------------------------------------------------------
138; LoadCgaStatusRegisterAddressToDXifCgaPresent
139; Parameters:
140; DS: BDA segment (zero)
141; Returns:
142; DX: CGA Status Register Address
143; ZF: Set if CGA not present
144; Cleared if CGA present
145; Corrupts registers:
146; Nothing
147;--------------------------------------------------------------------
148ALIGN DISPLAY_JUMP_ALIGN
149LoadCgaStatusRegisterAddressToDXifCgaPresent:
150 test BYTE [VIDEO_BDA.displayContext+DISPLAY_CONTEXT.bFlags], FLG_CONTEXT_CGA
151 jz SHORT .NoCgaDetected
152 mov dx, CGA_STATUS_REGISTER
153ALIGN DISPLAY_JUMP_ALIGN, ret
154.NoCgaDetected:
155 ret
156
157
158%endif ; ELIMINATE_CGA_SNOW
Note: See TracBrowser for help on using the repository browser.