1 | ; Project name : XTIDE Universal BIOS |
---|
2 | ; Description : Functions for printing drive detection strings. |
---|
3 | |
---|
4 | ; Section containing code |
---|
5 | SECTION .text |
---|
6 | |
---|
7 | ;-------------------------------------------------------------------- |
---|
8 | ; Prints BIOS name and segment address where it is found. |
---|
9 | ; |
---|
10 | ; DetectPrint_RomFoundAtSegment |
---|
11 | ; Parameters: |
---|
12 | ; Nothing |
---|
13 | ; Returns: |
---|
14 | ; Nothing |
---|
15 | ; Corrupts registers: |
---|
16 | ; AX, SI, DI |
---|
17 | ;-------------------------------------------------------------------- |
---|
18 | DetectPrint_RomFoundAtSegment: |
---|
19 | push bp |
---|
20 | mov bp, sp |
---|
21 | mov si, g_szRomAt |
---|
22 | ePUSH_T ax, ROMVARS.szTitle ; Bios title string |
---|
23 | push cs ; BIOS segment |
---|
24 | |
---|
25 | DetectPrint_BootMenuPrint_FormatCSSIfromParamsInSSBP_Relay: |
---|
26 | jmp BootMenuPrint_FormatCSSIfromParamsInSSBP |
---|
27 | |
---|
28 | |
---|
29 | ;-------------------------------------------------------------------- |
---|
30 | ; DetectPrint_StartDetectWithMasterOrSlaveStringInCXandIdeVarsInCSBP |
---|
31 | ; Parameters: |
---|
32 | ; CS:CX: Ptr to "Master" or "Slave" string |
---|
33 | ; CS:BP: Ptr to IDEVARS |
---|
34 | ; SI: Ptr to template string |
---|
35 | ; Returns: |
---|
36 | ; Nothing |
---|
37 | ; Corrupts registers: |
---|
38 | ; AX, SI, DI, CX |
---|
39 | ;-------------------------------------------------------------------- |
---|
40 | DetectPrint_StartDetectWithMasterOrSlaveStringInCXandIdeVarsInCSBP: |
---|
41 | mov ax, [cs:bp+IDEVARS.wPort] ; for IDE: AX=port address, DH=.bDevice |
---|
42 | mov dx, [cs:bp+IDEVARS.bDevice-1] ; for Serial: AL=port address>>2, AH=baud rate |
---|
43 | ; DL=COM number character, DH=.bDevice |
---|
44 | %ifdef MODULE_JRIDE |
---|
45 | cmp dh, DEVICE_JRIDE_ISA |
---|
46 | eCMOVE ax, cs ; Use segment address for JR-IDE/ISA |
---|
47 | %endif |
---|
48 | |
---|
49 | push bp ; setup stack for call to |
---|
50 | mov bp, sp ; BootMenuPrint_FormatCSSIfromParamsInSSBP |
---|
51 | |
---|
52 | push cx ; Push "Master" or "Slave" |
---|
53 | |
---|
54 | mov cl, (g_szDetectPort-$$) & 0xff ; Setup print string for standard IDE |
---|
55 | ; Note that we modify only the low order bits of CX a lot here, |
---|
56 | ; saving code space rather than reloading CX completely. |
---|
57 | ; This optimization requires that all the g_szDetect* strings are |
---|
58 | ; on the same 256 byte page, which is checked in strings.asm. |
---|
59 | |
---|
60 | %ifdef MODULE_SERIAL |
---|
61 | cmp dh, DEVICE_SERIAL_PORT ; Check if this is a serial device |
---|
62 | |
---|
63 | jnz .pushAndPrint ; CX = string to print, AX = port address, DX won't be used |
---|
64 | |
---|
65 | mov cl, (g_szDetectCOM-$$) & 0xff ; Setup print string for COM ports |
---|
66 | push cx ; And push now. We use the fact that format strings can contain |
---|
67 | ; themselves format strings. |
---|
68 | |
---|
69 | push dx ; Push COM number character |
---|
70 | ; If the string is going to be "Auto", we will push a NULL (zero) |
---|
71 | ; here for the COM port number, which will be eaten by the |
---|
72 | ; print routine (DisplayPrint_CharacterFromAL), resulting in |
---|
73 | ; just "COM" being printed without a character after it. |
---|
74 | |
---|
75 | mov cl, (g_szDetectCOMAuto-$$) & 0xff ; Setup secondary print string for "Auto" |
---|
76 | |
---|
77 | test dl, dl ; Check if serial port "Auto" |
---|
78 | jz .pushAndPrintSerial ; CX = string to print, AX and DX won't be used |
---|
79 | |
---|
80 | mov cl, (g_szDetectCOMLarge-$$) & 0xff ; Setup secondary print string for "COMn/xx.yK" |
---|
81 | |
---|
82 | mov al,ah ; baud rate divisor to AL |
---|
83 | cbw ; clear AH, AL will always be less than 128 |
---|
84 | xchg si,ax ; move AX to SI for divide |
---|
85 | mov ax,1152 ; baud rate to display is 115200/divisor, the "00" is handled |
---|
86 | ; in the print strings |
---|
87 | cwd ; clear top 16-bits of dividend |
---|
88 | div si ; and divide... Now AX = baud rate/100, DX = 0 (always a clean divide) |
---|
89 | |
---|
90 | mov si,10 ; Now separate the whole portion from the fractional for "K" display |
---|
91 | div si ; and divide... Now AX = baud rate/1000, DX = low order digit |
---|
92 | |
---|
93 | cmp ax,si ; < 10: "2400", "9600", etc.; >= 10: "19.2K", "38.4K", etc. |
---|
94 | jae .pushAndPrintSerial |
---|
95 | |
---|
96 | mov cl, (g_szDetectCOMSmall-$$) & 0xff ; Setup secondary print string for "COMn/XXy00" |
---|
97 | |
---|
98 | .pushAndPrintSerial: |
---|
99 | .pushAndPrint: |
---|
100 | %endif |
---|
101 | |
---|
102 | push cx ; Push print string |
---|
103 | push ax ; Push high order digits, or port address, or N/A |
---|
104 | push dx ; Push low order digit, or N/A |
---|
105 | |
---|
106 | mov si, g_szDetectOuter ; Load SI with default wrapper string "IDE %s at %s: " |
---|
107 | |
---|
108 | jmp short DetectPrint_BootMenuPrint_FormatCSSIfromParamsInSSBP_Relay |
---|
109 | |
---|
110 | |
---|
111 | ;-------------------------------------------------------------------- |
---|
112 | ; DetectPrint_DriveNameFromBootnfoInESBX |
---|
113 | ; Parameters: |
---|
114 | ; ES:BX: Ptr to BOOTMENUINFO (if drive found) |
---|
115 | ; Returns: |
---|
116 | ; Nothing |
---|
117 | ; Corrupts registers: |
---|
118 | ; AX, SI |
---|
119 | ;-------------------------------------------------------------------- |
---|
120 | DetectPrint_DriveNameFromBootnfoInESBX: |
---|
121 | push di |
---|
122 | push bx |
---|
123 | |
---|
124 | lea si, [bx+BOOTMENUINFO.szDrvName] |
---|
125 | mov bx, es |
---|
126 | CALL_DISPLAY_LIBRARY PrintNullTerminatedStringFromBXSI |
---|
127 | CALL_DISPLAY_LIBRARY PrintNewlineCharacters |
---|
128 | |
---|
129 | pop bx |
---|
130 | pop di |
---|
131 | ret |
---|