source: xtideuniversalbios/trunk/XTIDE_Universal_BIOS_Configurator_v2/Src/EEPROM.asm @ 589

Last change on this file since 589 was 589, checked in by krille_n_, 8 years ago

Changes:

  • BIOS: Fixed a purely cosmetic bug from r542 where, in builds containing MODULE_EBIOS, the boot menu would display an incorrect drive size (0.4 kB with MODULE_STRINGS_COMPRESSED or 0.5 kB without) for old drives with no support for LBA.
  • Fixed a bug from r392 where Vision_DetectAndReturnIDinAXandPortInDXifControllerPresent would return the ID in AL instead of AH (if DANGEROUS_DETECTION had been defined).
  • Fixed a bug from r587 in AdvAtaInit.asm that would prevent detection of QDI Vision controllers.
  • Also changed how the QDI Vision IDs are defined (removed the need for shifting) to avoid confusion. This fixed a potential bug from r587 in AdvAtaInit.asm where some IDs were not being shifted.
  • Fixed a bug in PDC20x30.asm from r587 where GetPdcIDtoAX would not return with the IDE base port in DX so DisablePdcProgrammingMode would fail.
  • Made some changes to ModuleDependency.inc and other files so that MODULE_ADVANCED_ATA now requires USE_386. Consequently it is no longer included in the regular AT-builds, only in the 386_8k-build.
  • Moved the UNROLL_SECTORS_IN_CX_TO_xWORDS macros from IDE_8bit.inc to IdeIO.inc which means it's now possible to build a BIOS without MODULE_8BIT_IDE.
  • XTIDECFG: Added a minimum DOS version check (since it needs DOS version 2+) to allow the program to quit gracefully in the unlikely scenario where someone tries to run it under DOS version 1.
  • Made some changes to Drive.asm to improve drive enumeration. The old method using GET_DOS_DRIVE_PARAMETER_BLOCK_FOR_SPECIFIC_DRIVE worked well in Windows XP but not in Windows 98 SE (in Windows or in DOS mode). The two problems were; 1) The function call would access the drives which on single floppy drive systems would cause Windows to swap between A: and B: (throwing a blue screen asking the user to insert a disk etc). 2) Only floppy drives and FAT16 drives would be available in the list of drives, no FAT32/optical/network drives.
  • Improved code in IdeControllerMenu.asm so that the default port addresses for all IDE interfaces are now restored when (re-)selecting the (same) type of IDE device.
  • Also made it impossible to select a device type unless the required module is included in the loaded BIOS.
  • The version check done when loading a BIOS now uses the FLASH_SIGNATURE definition from Version.inc. Any changes affecting RomVars now only requires updating that definition. This means that changes to RomVars must be implemented in both the BIOS and XTIDECFG before being committed to the repository.
  • Added a compatibility fix for 3Com 3C503 cards to the ROM checksumming code in Buffers.asm (Buffers_GenerateChecksum).
  • SerDrive: Made some minor changes to file names and paths to improve compatibility with case sensitive environments.
  • BIOSDRVS: Made a minor size optimization which as a side effect also makes it compatible with all DOS versions including DOS version 1.
  • Library: Renamed the WAIT_RETRACE_IF_NECESSARY_THEN macro to CALL_WAIT_FOR_RETRACE_IF_NECESSARY_THEN and made a tail-call-optimized version of it (JMP_WAIT_FOR_RETRACE_IF_NECESSARY_THEN).
  • A speed optimization to the eRCL_IM macro for 386 and higher. This change breaks emulation in the sense that the macro will fail when given a memory operand as the first parameter.
  • Other minor optimizations and fixes.
File size: 5.3 KB
Line 
1; Project name  :   XTIDE Univeral BIOS Configurator v2
2; Description   :   Functions for managing EEPROM contents.
3
4;
5; XTIDE Universal BIOS and Associated Tools
6; Copyright (C) 2009-2010 by Tomi Tilli, 2011-2013 by XTIDE Universal BIOS Team.
7;
8; This program is free software; you can redistribute it and/or modify
9; it under the terms of the GNU General Public License as published by
10; the Free Software Foundation; either version 2 of the License, or
11; (at your option) any later version.
12;
13; This program is distributed in the hope that it will be useful,
14; but WITHOUT ANY WARRANTY; without even the implied warranty of
15; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
16; GNU General Public License for more details.
17; Visit http://www.gnu.org/licenses/old-licenses/gpl-2.0.html
18;
19
20; Section containing initialized data
21SECTION .data
22
23ALIGN WORD_ALIGN
24g_rgwEepromTypeToSizeInWords:
25    dw      (2<<10) / 2     ; EEPROM_TYPE.2816_2kiB
26    dw      (8<<10) / 2
27    dw      (8<<10) / 2     ; EEPROM_TYPE.2864_8kiB_MOD
28    dw      (32<<10) / 2
29    dw      (64<<10) / 2
30
31g_rgwEepromPageToSizeInBytes:
32    dw      1               ; EEPROM_PAGE.1_byte
33    dw      2
34    dw      4
35    dw      8
36    dw      16
37    dw      32
38    dw      64
39
40
41
42; Section containing code
43SECTION .text
44
45;--------------------------------------------------------------------
46; EEPROM_LoadXtideUniversalBiosFromRomToRamBufferAndReturnSizeInDXCX
47;   Parameters:
48;       Nothing
49;   Returns:
50;       DX:CX:  BIOS size in bytes
51;   Corrupts registers:
52;       AX, BX, SI, DI
53;--------------------------------------------------------------------
54ALIGN JUMP_ALIGN
55EEPROM_LoadXtideUniversalBiosFromRomToRamBufferAndReturnSizeInDXCX:
56    push    es
57
58    call    EEPROM_FindXtideUniversalBiosROMtoESDI
59    call    EEPROM_GetXtideUniversalBiosSizeFromESDItoDXCX
60    xor     si, si              ; Load from beginning of ROM
61    call    LoadBytesFromRomToRamBuffer
62
63    call    EEPROM_GetXtideUniversalBiosSizeFromESDItoDXCX
64    pop     es
65    ret
66
67
68;--------------------------------------------------------------------
69; EEPROM_GetXtideUniversalBiosSizeFromESDItoDXCX
70;   Parameters:
71;       ES:DI:  Ptr to XTIDE Universal BIOS
72;   Returns:
73;       DX:CX:  Bios size in bytes
74;   Corrupts registers:
75;       Nothing
76;--------------------------------------------------------------------
77ALIGN JUMP_ALIGN
78EEPROM_GetXtideUniversalBiosSizeFromESDItoDXCX:
79    xor     dx, dx
80    mov     ch, [es:di+ROMVARS.bRomSize]
81    mov     cl, dl
82    eSHL_IM ch, 1
83    eRCL_IM dl, 1
84    ret
85
86
87;--------------------------------------------------------------------
88; EEPROM_LoadOldSettingsFromRomToRamBuffer
89;   Parameters:
90;       Nothing
91;   Returns:
92;       CF:     Set if EEPROM was found
93;               Cleared if EEPROM not found
94;   Corrupts registers:
95;       AX, BX, CX, SI, DI
96;--------------------------------------------------------------------
97ALIGN JUMP_ALIGN
98EEPROM_LoadOldSettingsFromRomToRamBuffer:
99    mov     cx, ROMVARS_size - ROMVARS.wFlags   ; Number of bytes to load
100    mov     si, ROMVARS.wFlags                  ; Offset where to start loading
101    ; Fall to LoadBytesFromRomToRamBuffer
102
103;--------------------------------------------------------------------
104; LoadBytesFromRomToRamBuffer
105;   Parameters:
106;       CX:     Number of bytes to load from ROM
107;       SI:     Offset to first byte to load
108;   Returns:
109;       CF:     Set if EEPROM was found
110;               Cleared if EEPROM not found
111;   Corrupts registers:
112;       AX, BX, CX, SI
113;--------------------------------------------------------------------
114ALIGN JUMP_ALIGN
115LoadBytesFromRomToRamBuffer:
116    push    es
117    push    ds
118    push    di
119
120    call    EEPROM_FindXtideUniversalBiosROMtoESDI
121    jnc     SHORT .XtideUniversalBiosNotFound
122    push    es
123    pop     ds                                          ; DS:SI points to ROM
124
125    call    Buffers_GetFileBufferToESDI
126    mov     di, si                                      ; ES:DI points to RAM buffer
127
128    cld
129    call    Memory_CopyCXbytesFromDSSItoESDI
130    stc
131
132.XtideUniversalBiosNotFound:
133    pop     di
134    pop     ds
135    pop     es
136    ret
137
138
139;--------------------------------------------------------------------
140; EEPROM_FindXtideUniversalBiosROMtoESDI
141;   Parameters:
142;       Nothing
143;   Returns:
144;       ES:DI:  EEPROM segment
145;       CF:     Set if EEPROM was found
146;               Cleared if EEPROM not found
147;   Corrupts registers:
148;       AX, BX
149;--------------------------------------------------------------------
150ALIGN JUMP_ALIGN
151EEPROM_FindXtideUniversalBiosROMtoESDI:
152    push    si
153    push    cx
154
155    xor     di, di                  ; Zero DI (offset)
156    mov     bx, 0C000h              ; First possible ROM segment
157ALIGN JUMP_ALIGN
158.SegmentLoop:
159    mov     es, bx                  ; Possible ROM segment to ES
160    call    Buffers_IsXtideUniversalBiosSignatureInESDI
161    je      SHORT .RomFound
162    add     bx, 80h                 ; Increment by 2kB (minimum possible distance from the beginning of one option ROM to the next)
163    jnc     SHORT .SegmentLoop      ; Loop until segment overflows
164    clc
165    jmp     SHORT .ReturnWithoutUpdatingCF
166ALIGN JUMP_ALIGN
167.RomFound:
168    stc
169.ReturnWithoutUpdatingCF:
170    pop     cx
171    pop     si
172    ret
173
174
175;--------------------------------------------------------------------
176; EEPROM_LoadFromRomToRamComparisonBuffer
177;   Parameters:
178;       Nothing
179;   Returns:
180;       Nothing
181;   Corrupts registers:
182;       BX, CX, SI, DI
183;--------------------------------------------------------------------
184ALIGN JUMP_ALIGN
185EEPROM_LoadFromRomToRamComparisonBuffer:
186    push    es
187    push    ds
188
189    mov     ds, [cs:g_cfgVars+CFGVARS.wEepromSegment]
190    xor     si, si
191    call    Buffers_GetFlashComparisonBufferToESDI
192    eMOVZX  bx, [cs:g_cfgVars+CFGVARS.bEepromType]
193    mov     cx, [cs:bx+g_rgwEepromTypeToSizeInWords]
194    cld
195    rep movsw
196
197    pop     ds
198    pop     es
199    ret
Note: See TracBrowser for help on using the repository browser.