source: xtideuniversalbios/trunk/XTIDE_Universal_BIOS/Src/VariablesAndDPTs/AccessDPT.asm @ 589

Last change on this file since 589 was 589, checked in by krille_n_, 8 years ago

Changes:

  • BIOS: Fixed a purely cosmetic bug from r542 where, in builds containing MODULE_EBIOS, the boot menu would display an incorrect drive size (0.4 kB with MODULE_STRINGS_COMPRESSED or 0.5 kB without) for old drives with no support for LBA.
  • Fixed a bug from r392 where Vision_DetectAndReturnIDinAXandPortInDXifControllerPresent would return the ID in AL instead of AH (if DANGEROUS_DETECTION had been defined).
  • Fixed a bug from r587 in AdvAtaInit.asm that would prevent detection of QDI Vision controllers.
  • Also changed how the QDI Vision IDs are defined (removed the need for shifting) to avoid confusion. This fixed a potential bug from r587 in AdvAtaInit.asm where some IDs were not being shifted.
  • Fixed a bug in PDC20x30.asm from r587 where GetPdcIDtoAX would not return with the IDE base port in DX so DisablePdcProgrammingMode would fail.
  • Made some changes to ModuleDependency.inc and other files so that MODULE_ADVANCED_ATA now requires USE_386. Consequently it is no longer included in the regular AT-builds, only in the 386_8k-build.
  • Moved the UNROLL_SECTORS_IN_CX_TO_xWORDS macros from IDE_8bit.inc to IdeIO.inc which means it's now possible to build a BIOS without MODULE_8BIT_IDE.
  • XTIDECFG: Added a minimum DOS version check (since it needs DOS version 2+) to allow the program to quit gracefully in the unlikely scenario where someone tries to run it under DOS version 1.
  • Made some changes to Drive.asm to improve drive enumeration. The old method using GET_DOS_DRIVE_PARAMETER_BLOCK_FOR_SPECIFIC_DRIVE worked well in Windows XP but not in Windows 98 SE (in Windows or in DOS mode). The two problems were; 1) The function call would access the drives which on single floppy drive systems would cause Windows to swap between A: and B: (throwing a blue screen asking the user to insert a disk etc). 2) Only floppy drives and FAT16 drives would be available in the list of drives, no FAT32/optical/network drives.
  • Improved code in IdeControllerMenu.asm so that the default port addresses for all IDE interfaces are now restored when (re-)selecting the (same) type of IDE device.
  • Also made it impossible to select a device type unless the required module is included in the loaded BIOS.
  • The version check done when loading a BIOS now uses the FLASH_SIGNATURE definition from Version.inc. Any changes affecting RomVars now only requires updating that definition. This means that changes to RomVars must be implemented in both the BIOS and XTIDECFG before being committed to the repository.
  • Added a compatibility fix for 3Com 3C503 cards to the ROM checksumming code in Buffers.asm (Buffers_GenerateChecksum).
  • SerDrive: Made some minor changes to file names and paths to improve compatibility with case sensitive environments.
  • BIOSDRVS: Made a minor size optimization which as a side effect also makes it compatible with all DOS versions including DOS version 1.
  • Library: Renamed the WAIT_RETRACE_IF_NECESSARY_THEN macro to CALL_WAIT_FOR_RETRACE_IF_NECESSARY_THEN and made a tail-call-optimized version of it (JMP_WAIT_FOR_RETRACE_IF_NECESSARY_THEN).
  • A speed optimization to the eRCL_IM macro for 386 and higher. This change breaks emulation in the sense that the macro will fail when given a memory operand as the first parameter.
  • Other minor optimizations and fixes.
File size: 4.8 KB
Line 
1; Project name  :   XTIDE Universal BIOS
2; Description   :   Functions for accessing DPT data.
3
4;
5; XTIDE Universal BIOS and Associated Tools
6; Copyright (C) 2009-2010 by Tomi Tilli, 2011-2013 by XTIDE Universal BIOS Team.
7;
8; This program is free software; you can redistribute it and/or modify
9; it under the terms of the GNU General Public License as published by
10; the Free Software Foundation; either version 2 of the License, or
11; (at your option) any later version.
12;
13; This program is distributed in the hope that it will be useful,
14; but WITHOUT ANY WARRANTY; without even the implied warranty of
15; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
16; GNU General Public License for more details.
17; Visit http://www.gnu.org/licenses/old-licenses/gpl-2.0.html
18;
19
20; Section containing code
21SECTION .text
22
23;--------------------------------------------------------------------
24; AccessDPT_GetDriveSelectByteToAL
25;   Parameters:
26;       DS:DI:  Ptr to Disk Parameter Table
27;   Returns:
28;       AL:     Drive Select Byte
29;   Corrupts registers:
30;       Nothing
31;--------------------------------------------------------------------
32ALIGN JUMP_ALIGN
33AccessDPT_GetDriveSelectByteToAL:
34    mov     al, [di+DPT.bFlagsLow]
35    and     al, FLGL_DPT_SLAVE | FLGL_DPT_LBA
36    or      al, MASK_DRVNHEAD_SET   ; Bits set to 1 for old drives
37    ret
38
39
40;--------------------------------------------------------------------
41; AccessDPT_GetDeviceControlByteToAL
42;   Parameters:
43;       DS:DI:  Ptr to Disk Parameter Table
44;   Returns:
45;       AL:     Device Control Byte
46;   Corrupts registers:
47;       Nothing
48;--------------------------------------------------------------------
49ALIGN JUMP_ALIGN
50AccessDPT_GetDeviceControlByteToAL:
51%ifdef MODULE_IRQ
52
53%ifndef USE_UNDOC_INTEL
54    xor     al, al
55%endif
56
57    test    BYTE [di+DPT.bFlagsLow], FLGL_DPT_ENABLE_IRQ    ; Clears CF
58
59%ifdef USE_UNDOC_INTEL
60    salc    ; Clears AL using CF while preserving flags
61%endif
62
63    jnz     SHORT .EnableDeviceIrq
64    mov     al, FLG_DEVCONTROL_nIEN ; Disable IRQ
65.EnableDeviceIrq:
66%else
67    mov     al, FLG_DEVCONTROL_nIEN ; Disable IRQ
68%endif ; MODULE_IRQ
69    ret
70
71
72;--------------------------------------------------------------------
73; AccessDPT_GetLCHStoAXBLBH
74;   Parameters:
75;       DS:DI:  Ptr to Disk Parameter Table
76;   Returns:
77;       AX:     Number of L-CHS cylinders
78;       BL:     Number of L-CHS heads
79;       BH:     Number of L-CHS sectors per track
80;   Corrupts registers:
81;       Nothing
82;--------------------------------------------------------------------
83AccessDPT_GetLCHStoAXBLBH:
84    mov     ax, [di+DPT.wLchsCylinders]
85    mov     bx, [di+DPT.wLchsHeadsAndSectors]
86    ret
87
88
89%ifdef MODULE_8BIT_IDE_ADVANCED
90;--------------------------------------------------------------------
91; AccessDPT_IsThisDeviceXTCF
92;   Parameters:
93;       DS:DI:  Ptr to Disk Parameter Table
94;   Returns:
95;       AH:     Device Type
96;       CF:     Cleared if XTCF
97;               Set if some other device
98;   Corrupts registers:
99;       Nothing
100;--------------------------------------------------------------------
101AccessDPT_IsThisDeviceXTCF:
102    mov     ah, [di+DPT_ATA.bDevice]
103    cmp     ah, FIRST_XTCF_DEVICE
104    jb      SHORT .DeviceIsNotXTCF
105    cmp     ah, LAST_XTCF_DEVICE+1
106    cmc
107.DeviceIsNotXTCF:
108    ret
109%endif ; MODULE_8BIT_IDE_ADVANCED
110
111
112%ifdef MODULE_EBIOS
113;--------------------------------------------------------------------
114; AccessDPT_GetLbaSectorCountToBXDXAX
115;   Parameters:
116;       DS:DI:  Ptr to Disk Parameter Table
117;   Returns:
118;       BX:DX:AX:   48-bit sector count
119;   Corrupts registers:
120;       Nothing
121;--------------------------------------------------------------------
122AccessDPT_GetLbaSectorCountToBXDXAX:
123    mov     ax, [di+DPT.twLbaSectors]
124    mov     dx, [di+DPT.twLbaSectors+2]
125    mov     bx, [di+DPT.twLbaSectors+4]
126    ret
127%endif ; MODULE_EBIOS
128
129
130;--------------------------------------------------------------------
131; Returns pointer to DRVPARAMS for master or slave drive.
132;
133; AccessDPT_GetPointerToDRVPARAMStoCSBX
134;   Parameters:
135;       DS:DI:  Ptr to Disk Parameter Table
136;   Returns:
137;       CS:BX:  Ptr to DRVPARAMS
138;   Corrupts registers:
139;       Nothing
140;--------------------------------------------------------------------
141AccessDPT_GetPointerToDRVPARAMStoCSBX:
142    call    AccessDPT_GetIdevarsToCSBX
143    add     bx, BYTE IDEVARS.drvParamsMaster    ; CS:BX points to Master Drive DRVPARAMS
144    test    BYTE [di+DPT.bFlagsLow], FLGL_DPT_SLAVE
145    jz      SHORT .ReturnPointerToDRVPARAMS
146    add     bx, BYTE DRVPARAMS_size             ; CS:BX points to Slave Drive DRVPARAMS
147.ReturnPointerToDRVPARAMS:
148    ret
149
150
151;--------------------------------------------------------------------
152; Needed many times during initialization so it is better to
153; make it as a function to save bytes.
154;
155; AccessDPT_GetIdevarsToCSBX
156;   Parameters:
157;       DS:DI:  Ptr to Disk Parameter Table
158;   Returns:
159;       CS:BX:  Ptr to IDEVARS for the drive
160;   Corrupts registers:
161;       Nothing
162;--------------------------------------------------------------------
163AccessDPT_GetIdevarsToCSBX:
164    eMOVZX  bx, [di+DPT.bIdevarsOffset]
165    ret
166
Note: See TracBrowser for help on using the repository browser.