source: xtideuniversalbios/trunk/XTIDE_Universal_BIOS/Src/Menus/DriveXlate.asm @ 526

Last change on this file since 526 was 526, checked in by krille_n_@…, 11 years ago

Changes:

  • Update of the copyright notices to include the year 2013.
File size: 5.2 KB
Line 
1; Project name  :   XTIDE Universal BIOS
2; Description   :   Functions for swapping drive letters.
3
4;
5; XTIDE Universal BIOS and Associated Tools
6; Copyright (C) 2009-2010 by Tomi Tilli, 2011-2013 by XTIDE Universal BIOS Team.
7;
8; This program is free software; you can redistribute it and/or modify
9; it under the terms of the GNU General Public License as published by
10; the Free Software Foundation; either version 2 of the License, or
11; (at your option) any later version.
12;
13; This program is distributed in the hope that it will be useful,
14; but WITHOUT ANY WARRANTY; without even the implied warranty of
15; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
16; GNU General Public License for more details.
17; Visit http://www.gnu.org/licenses/old-licenses/gpl-2.0.html
18;
19
20; Section containing code
21SECTION .text
22
23;--------------------------------------------------------------------
24; DriveXlate_ConvertDriveLetterInDLtoDriveNumber
25;   Parameters:
26;       DS:     RAMVARS segment
27;       DL:     Drive letter ('A'...)
28;   Returns:
29;       DL:     Drive number (0xh for Floppy Drives, 8xh for Hard Drives)
30;   Corrupts registers:
31;       AX
32;--------------------------------------------------------------------
33DriveXlate_ConvertDriveLetterInDLtoDriveNumber:
34    call    DriveXlate_GetLetterForFirstHardDriveToAX
35    cmp     dl, al
36    jb      SHORT .ConvertLetterInDLtoFloppyDriveNumber
37
38    ; Convert letter in DL to Hard Drive number
39    sub     dl, al
40    or      dl, 80h
41    ret
42
43.ConvertLetterInDLtoFloppyDriveNumber:
44    sub     dl, DEFAULT_FLOPPY_DRIVE_LETTER
45    ret
46
47%ifdef MODULE_HOTKEY
48%if HotkeyBar_FallThroughTo_DriveXlate_ConvertDriveLetterInDLtoDriveNumber <> DriveXlate_ConvertDriveLetterInDLtoDriveNumber
49    %error "DriveXlate_ConvertDriveLetterInDLtoDriveNumber must be at the top of DriveXlate.asm, and that file must immediately follow HotKeys.asm"
50%endif
51%endif
52
53;--------------------------------------------------------------------
54; DriveXlate_ConvertDriveNumberFromDLtoDriveLetter
55;   Parameters:
56;       DL:     Drive number (0xh for Floppy Drives, 8xh for Hard Drives)
57;       DS:     RAMVARS Segment
58;   Returns:
59;       DL:     Drive letter ('A'...)
60;       CF:     Set if Hard Drive
61;               Clear if Floppy Drive
62;   Corrupts registers:
63;       AX
64;--------------------------------------------------------------------
65DriveXlate_ConvertDriveNumberFromDLtoDriveLetter:
66    xor     dl, 80h
67    js      SHORT .GetDefaultFloppyDrive
68
69    ; Store default hard drive to boot from
70    call    DriveXlate_GetLetterForFirstHardDriveToAX
71    add     dl, al
72    stc
73    ret
74
75.GetDefaultFloppyDrive:
76    sub     dl, 80h - DEFAULT_FLOPPY_DRIVE_LETTER   ; Clears CF
77    ret
78
79
80;--------------------------------------------------------------------
81; Returns letter for first hard disk. Usually it will be 'C' but it
82; can be higher if more than two floppy drives are found.
83;
84; DriveXlate_GetLetterForFirstHardDriveToAX
85;   Parameters:
86;       DS:     RAMVARS segment
87;   Returns:
88;       AX:     Upper case letter for first hard disk
89;   Corrupts registers:
90;       Nothing
91;--------------------------------------------------------------------
92DriveXlate_GetLetterForFirstHardDriveToAX:
93    call    FloppyDrive_GetCountToAX
94    add     al, DEFAULT_FLOPPY_DRIVE_LETTER
95    MAX_U   al, DEFAULT_HARD_DRIVE_LETTER
96    ret
97
98
99;--------------------------------------------------------------------
100; DriveXlate_ToOrBack
101;   Parameters:
102;       DL:     Drive number to be possibly translated
103;       DS:     RAMVARS segment
104;   Returns:
105;       DL:     Translated drive number
106;   Corrupts registers:
107;       DI
108;--------------------------------------------------------------------
109ALIGN JUMP_ALIGN
110DriveXlate_ToOrBack:
111    xchg    di, ax                  ; Backup AX
112
113    mov     ah, 80h                 ; Assume hard disk
114    mov     al, [RAMVARS.xlateVars+XLATEVARS.bHDSwap]
115    test    dl, ah                  ; Hard disk?
116    jnz     SHORT .SwapDrive        ; If so, jump to swap
117    mov     al, [RAMVARS.xlateVars+XLATEVARS.bFDSwap]
118    cbw
119
120ALIGN JUMP_ALIGN
121.SwapDrive:
122    cmp     ah, dl                  ; Swap DL from 00h/80h to xxh?
123    je      SHORT .SwapToXXhInAL
124    cmp     al, dl                  ; Swap DL from xxh to 00h/80h?
125    jne     SHORT .RestoreAXandReturn
126    mov     al, ah
127ALIGN JUMP_ALIGN
128.SwapToXXhInAL:
129    mov     dl, al
130ALIGN JUMP_ALIGN
131.RestoreAXandReturn:
132    xchg    ax, di                  ; Restore AX
133    ret
134
135
136;--------------------------------------------------------------------
137; Resets drive swapping variables to defaults (no swapping).
138;
139; DriveXlate_Reset
140;   Parameters:
141;       DS:     RAMVARS segment
142;   Returns:
143;       Nothing
144;   Corrupts registers:
145;       AX, DI, DL
146;--------------------------------------------------------------------
147DriveXlate_Reset:
148    xor     dl, dl              ; no translation for a floppy
149    ;; fall through to DriveXlate_SetDriveToSwap
150
151;--------------------------------------------------------------------
152; Stores drive to be swapped.
153;
154; DriveXlate_SetDriveToSwap
155;   Parameters:
156;       DL:     Drive to swap to 00h or 80h
157;       DS:     RAMVARS segment
158;   Returns:
159;       Nothing
160;   Corrupts registers:
161;       AX, DI
162;--------------------------------------------------------------------
163DriveXlate_SetDriveToSwap:
164    mov     ax, 8000h           ; Default mapping (no translation)
165    test    dl, dl              ; Floppy drive?
166    js      SHORT .SetHardDriveToSwap
167    mov     al, dl              ; Store floppy translation
168    SKIP2B  di
169.SetHardDriveToSwap:
170    mov     ah, dl              ; Store HD translation
171    mov     WORD [RAMVARS.xlateVars+XLATEVARS.wFDandHDswap], ax
172    ret
Note: See TracBrowser for help on using the repository browser.