source: xtideuniversalbios/trunk/XTIDE_Universal_BIOS/Src/Initialization/DetectDrives.asm @ 558

Last change on this file since 558 was 558, checked in by krille_n_@…, 11 years ago

Changes:

  • Building the BIOS Drive Information Tool now works again.
  • Moved all XT-CF related code to MODULE_8BIT_IDE_ADVANCED. I don't see how an XT-CF card could work without *_ADVANCED anyway but if I'm wrong, feel free to undo this. Note! The autodetection code in XTIDECFG has NOT been changed to reflect this (still relies on MODULE_8BIT_IDE).
  • Optimizations and fixes in general.
File size: 8.5 KB
Line 
1; Project name  :   XTIDE Universal BIOS
2; Description   :   Functions for detecting drive for the BIOS.
3
4;
5; XTIDE Universal BIOS and Associated Tools
6; Copyright (C) 2009-2010 by Tomi Tilli, 2011-2013 by XTIDE Universal BIOS Team.
7;
8; This program is free software; you can redistribute it and/or modify
9; it under the terms of the GNU General Public License as published by
10; the Free Software Foundation; either version 2 of the License, or
11; (at your option) any later version.
12;
13; This program is distributed in the hope that it will be useful,
14; but WITHOUT ANY WARRANTY; without even the implied warranty of
15; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
16; GNU General Public License for more details.
17; Visit http://www.gnu.org/licenses/old-licenses/gpl-2.0.html
18;
19
20; Section containing code
21SECTION .text
22
23;--------------------------------------------------------------------
24; Detects all IDE hard disks to be controlled by this BIOS.
25;
26; DetectDrives_FromAllIDEControllers
27;   Parameters:
28;       DS:     RAMVARS segment
29;       ES:     BDA segment (zero)
30;   Returns:
31;       Nothing
32;   Corrupts registers:
33;       All (not segments)
34;--------------------------------------------------------------------
35DetectDrives_FromAllIDEControllers:
36    call    RamVars_GetIdeControllerCountToCX
37    mov     bp, ROMVARS.ideVars0            ; CS:BP now points to first IDEVARS
38
39.DriveDetectLoop:                           ; Loop through IDEVARS
40    push    cx
41
42    mov     cx, g_szDetectMaster
43    mov     bh, MASK_DRVNHEAD_SET                               ; Select Master drive
44    call    StartDetectionWithDriveSelectByteInBHandStringInCX  ; Detect and create DPT + BOOTNFO
45
46    mov     cx, g_szDetectSlave
47    mov     bh, MASK_DRVNHEAD_SET | FLG_DRVNHEAD_DRV
48    call    StartDetectionWithDriveSelectByteInBHandStringInCX
49
50    pop     cx
51
52    add     bp, BYTE IDEVARS_size           ; Point to next IDEVARS
53
54%ifdef MODULE_SERIAL
55    jcxz    .AddHardDisks                   ; Set to zero on .ideVarsSerialAuto iteration (if any)
56%endif
57    loop    .DriveDetectLoop
58
59%ifdef MODULE_SERIAL
60;----------------------------------------------------------------------
61;
62; if serial drive detected, do not scan (avoids duplicate drives and isn't needed - we already have a connection)
63;
64    call    FindDPT_ToDSDIforSerialDevice   ; does not modify AX
65    jnc     .AddHardDisks
66
67    mov     bp, ROMVARS.ideVarsSerialAuto   ; Point to our special IDEVARS structure, just for serial scans
68
69%ifdef MODULE_HOTKEYS
70    cmp     al, COM_DETECT_HOTKEY_SCANCODE  ; Set by last call to HotkeyBar_UpdateDuringDriveDetection above
71    je      .DriveDetectLoop
72%endif
73
74    mov     al,[cs:ROMVARS.wFlags]          ; Configurator set to always scan?
75    or      al,[es:BDA.bKBFlgs1]            ; Or, did the user hold down the ALT key?
76    and     al,8                            ; 8 = alt key depressed, same as FLG_ROMVARS_SERIAL_ALWAYSDETECT
77    jnz     .DriveDetectLoop
78%endif
79
80.AddHardDisks:
81;----------------------------------------------------------------------
82;
83; Add in hard disks to BDA, finalize our Count and First variables
84;
85; Note that we perform the add to bHDCount and store bFirstDrv even if the count is zero.
86; This is done because we use the value of .bFirstDrv to know how many drives were in the system
87; at the time of boot, and to return that number on int13h/8h calls.  Because the count is zero,
88; FindDPT_ForDriveNumber will not find any drives that are ours.
89;
90    mov     cx, [RAMVARS.wDrvCntAndFlopCnt]     ; Our count of hard disks
91
92    mov     al, [es:BDA.bHDCount]
93    add     cl, al                      ; Add our drives to the system count
94    mov     [es:BDA.bHDCount], cl
95    or      al, 80h                     ; Or in hard disk flag
96    mov     [RAMVARS.bFirstDrv], al     ; Store first drive number
97
98.AddFloppies:
99%ifdef MODULE_SERIAL_FLOPPY
100;----------------------------------------------------------------------
101;
102; Add in any emulated serial floppy drives, finalize our packed Count and First variables
103;
104    dec     ch
105    mov     al, ch
106    js      .NoFloppies                     ; if no drives are present, we store 0ffh
107
108    call    FloppyDrive_GetCountFromBIOS_or_BDA
109
110    push    ax
111
112    add     al, ch                          ; Add our drives to existing drive count
113    cmp     al, 3                           ; For BDA, max out at 4 drives (ours is zero based)
114    jb      .MaxBDAFloppiesExceeded
115    mov     al, 3
116.MaxBDAFloppiesExceeded:
117    eROR_IM al, 2                           ; move to bits 6-7
118    inc     ax                              ; low order bit, indicating floppy drive exists
119
120    mov     ah, [es:BDA.wEquipment]         ; Load Equipment WORD low byte
121    and     ah, 03eh                        ; Mask off drive number and drives present bit
122    or      al, ah                          ; Or in new values
123    mov     [es:BDA.wEquipment], al         ; and store
124
125    mov     al, 1eh                         ; BDA pointer to Floppy DPT
126    mov     si, AH8h_FloppyDPT
127    call    Interrupts_InstallHandlerToVectorInALFromCSSI
128
129    pop     ax
130
131    shr     ch, 1                           ; number of drives, 1 or 2 only, to CF flag (clear=1, set=2)
132    rcl     al, 1                           ; starting drive number in upper 7 bits, number of drives in low bit
133.NoFloppies:
134    mov     [RAMVARS.xlateVars+XLATEVARS.bFlopCntAndFirst], al
135%endif
136
137%ifdef MODULE_8BIT_IDE_ADVANCED
138NoSlaveDriveAvailable:
139%endif
140    ret
141
142%ifndef CHECK_FOR_UNUSED_ENTRYPOINTS
143    %if FLG_ROMVARS_SERIAL_SCANDETECT != 8
144        %error "DetectDrives is currently coded to assume that FLG_ROMVARS_SERIAL_SCANDETECT is the same bit as the ALT key code in the BDA.  Changes in the code will be needed if these values are no longer the same."
145    %endif
146%endif
147
148
149;--------------------------------------------------------------------
150; StartDetectionWithDriveSelectByteInBHandStringInCX
151;   Parameters:
152;       BH:     Drive Select byte for Drive and Head Register
153;       CX:     Offset to "Master" or "Slave" string
154;       CS:BP:  Ptr to IDEVARS for the drive
155;       DS:     RAMVARS segment
156;       ES:     Zero (BDA segment)
157;   Returns:
158;       Nothing
159;   Corrupts registers:
160;       AX, BL, CX, DX, SI, DI
161;--------------------------------------------------------------------
162StartDetectionWithDriveSelectByteInBHandStringInCX:
163%ifdef MODULE_8BIT_IDE_ADVANCED
164    mov     al, [cs:bp+IDEVARS.bDevice]
165    cmp     al, DEVICE_8BIT_XTCF_PIO8
166    jb      SHORT .DoNotSkipSlaveDriveDetection
167    cmp     al, DEVICE_8BIT_XTCF_DMA
168    ja      SHORT .DoNotSkipSlaveDriveDetection
169
170    ; XT-CF do not support slave drives so skip detection
171    test    bh, FLG_DRVNHEAD_DRV
172    jnz     SHORT NoSlaveDriveAvailable
173.DoNotSkipSlaveDriveDetection:
174%endif ; MODULE_8BIT_IDE_ADVANCED
175
176    call    DetectPrint_StartDetectWithMasterOrSlaveStringInCXandIdeVarsInCSBP
177
178%ifdef MODULE_HOTKEYS
179    call    HotkeyBar_UpdateDuringDriveDetection
180%endif
181    ; Fall to .ReadAtaInfoFromHardDisk
182
183
184;--------------------------------------------------------------------
185; .ReadAtaInfoFromHardDisk
186;   Parameters:
187;       BH:     Drive Select byte for Drive and Head Register
188;       DX:     Autodetected port (for devices that support autodetection)
189;       CS:BP:  Ptr to IDEVARS for the drive
190;       DS:     RAMVARS segment
191;       ES:     Zero (BDA segment)
192;   Returns:
193;       CF:     Cleared if ATA-information read successfully
194;               Set if any error
195;   Corrupts registers:
196;       AX, BL, CX, DX, SI, DI
197;--------------------------------------------------------------------
198.ReadAtaInfoFromHardDisk:
199    mov     si, BOOTVARS.rgbAtaInfo     ; ES:SI now points to ATA info location
200    push    es
201    push    si
202    push    dx
203    push    bx
204    call    Device_IdentifyToBufferInESSIwithDriveSelectByteInBH
205    pop     bx
206    pop     dx
207    pop     si
208    pop     es
209    jnc     SHORT CreateBiosTablesForHardDisk
210    ; Fall to .ReadAtapiInfoFromDrive
211
212.ReadAtapiInfoFromDrive:                ; Not yet implemented
213    ;call   ReadAtapiInfoFromDrive      ; Assume CD-ROM
214    ;jnc    SHORT _CreateBiosTablesForCDROM
215
216    ;jmp    short DetectDrives_DriveNotFound
217;;; fall-through instead of previous jmp instruction
218;--------------------------------------------------------------------
219; DetectDrives_DriveNotFound
220;   Parameters:
221;       Nothing
222;   Returns:
223;       CF:     Set (from DetectPrint_NullTerminatedStringFromCSSIandSetCF)
224;   Corrupts registers:
225;       AX, SI
226;--------------------------------------------------------------------
227DetectDrives_DriveNotFound:
228    mov     si, g_szNotFound
229    jmp     DetectPrint_NullTerminatedStringFromCSSIandSetCF
230
231
232;--------------------------------------------------------------------
233; CreateBiosTablesForHardDisk
234;   Parameters:
235;       BH:     Drive Select byte for Drive and Head Register
236;       DX:     Autodetected port (for devices that support autodetection)
237;       CS:BP:  Ptr to IDEVARS for the drive
238;       ES:SI   Ptr to ATA information for the drive
239;       DS:     RAMVARS segment
240;       ES:     BDA segment
241;   Returns:
242;       Nothing
243;   Corrupts registers:
244;       AX, BX, CX, DX, SI, DI
245;--------------------------------------------------------------------
246CreateBiosTablesForHardDisk:
247    push    bx
248    call    AtaID_VerifyFromESSI
249    pop     bx
250    jc      SHORT DetectDrives_DriveNotFound
251    call    CreateDPT_FromAtaInformation
252    jc      SHORT DetectDrives_DriveNotFound
253    call    DriveDetectInfo_CreateForHardDisk
254    jmp     SHORT DetectPrint_DriveNameFromDrvDetectInfoInESBX
Note: See TracBrowser for help on using the repository browser.